matita/matita/contribs/lambdadelta/basic_2/computation/fpbs_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredstaralt_8.ma".
  16 include "basic_2/computation/llpxs_cpxs.ma".
  17 include "basic_2/computation/fpbs_fpbs.ma".
  18
  19 (* "BIG TREE" PARALLEL COMPUTATION FOR CLOSURES *****************************)
  20
  21 (* Note: alternative definition of fpbs *)
  22 definition fpbsa: ∀h. sd h → tri_relation genv lenv term ≝
  23                   λh,g,G1,L1,T1,G2,L2,T2.
  24                   ∃∃L,T. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] T &
  25                          ⦃G1, L1, T⦄ ⊃* ⦃G2, L, T2⦄ &
  26                          ⦃G2, L⦄ ⊢ ➡*[h, g, T2, 0] L2.
  27
  28 interpretation "'big tree' parallel computation (closure) alternative"
  29    'BTPRedStarAlt h g G1 L1 T1 G2 L2 T2 = (fpbsa h g G1 L1 T1 G2 L2 T2).
  30
  31 (* Basic properties *********************************************************)
  32
  33 lemma fpb_fpbsa_trans: ∀h,g,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ≽[h, g] ⦃G, L, T⦄ →
  34                        ∀G2,L2,T2. ⦃G, L, T⦄ ≥≥[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥≥[h, g] ⦃G2, L2, T2⦄.
  35 #h #g #G1 #G #L1 #L #T1 #T * -G -L -T [ #G #L #T #HG1 | #T #HT1 | #L #HL1 ]
  36 #G2 #L2 #T2 * #L0 #T0 #HT0 #HG2 #HL02
  37 [ elim (fquq_cpxs_trans … HT0 … HG1) -T
  38   /3 width=7 by fqus_strap2, ex3_2_intro/
  39 | /3 width=5 by cpxs_strap2, ex3_2_intro/
  40 | lapply (cpxs_llpx_trans … HT0 … HL1) -HT0 #HT10
  41   lapply (cpxs_llpx_conf … HT10 … HL1) -HL1 #HL1
  42   elim (llpx_fqus_trans … HG2 … HL1) -L
  43   /3 width=7 by llpxs_strap2, cpxs_trans, ex3_2_intro/
  44 ]
  45 qed-.
  46
  47 (* Main properties **********************************************************)
  48
  49 theorem fpbs_fpbsa: ∀h,g,G1,G2,L1,L2,T1,T2.
  50                     ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥≥[h, g] ⦃G2, L2, T2⦄.
  51 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind_dx … H) -G1 -L1 -T1
  52 /2 width=5 by fpb_fpbsa_trans, ex3_2_intro/
  53 qed.
  54
  55 (* Main inversion lemmas ****************************************************)
  56
  57 theorem fpbsa_inv_fpbs: ∀h,g,G1,G2,L1,L2,T1,T2.
  58                         ⦃G1, L1, T1⦄ ≥≥[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄.
  59 #h #g #G1 #G2 #L1 #L2 #T1 #T2 *
  60 /4 width=5 by fpbs_trans, fqus_fpbs, cpxs_fpbs, llpxs_fpbs/
  61 qed-.