matita/matita/contribs/lambdadelta/basic_2/computation/fsb_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btsnalt_5.ma".
  16 include "basic_2/computation/fpbg_alt.ma".
  17 include "basic_2/computation/fsb.ma".
  18
  19 (* "BIG TREE" STRONGLY NORMALIZING TERMS ************************************)
  20
  21 (* Note: alternative definition of fsb *)
  22 inductive fsba (h) (g): relation3 genv lenv term ≝
  23 | fsba_intro: ∀G1,L1,T1. (
  24                  ∀G2,L2,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄ → fsba h g G2 L2 T2
  25               ) → fsba h g G1 L1 T1.
  26
  27 interpretation
  28    "'big tree' strong normalization (closure) alternative"
  29    'BTSNAlt h g G L T = (fsba h g G L T).
  30
  31 (* Basic eliminators ********************************************************)
  32
  33 theorem fsba_ind_alt: ∀h,g. ∀R: relation3 …. (
  34                          ∀G1,L1,T1. ⦃G1, L1⦄ ⊢ ⦥⦥[h,g] T1 → (
  35                             ∀G2,L2,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄ → R G2 L2 T2
  36                          ) → R G1 L1 T1
  37                       ) →
  38                       ∀G,L,T. ⦃G, L⦄ ⊢ ⦥⦥[h, g] T → R G L T.
  39 #h #g #R #IH #G #L #T #H elim H -G -L -T
  40 /4 width=1 by fsba_intro/
  41 qed-.
  42
  43 (* Main inversion lemmas ****************************************************)
  44
  45 theorem fsba_inv_fsb: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ ⦥⦥[h, g] T → ⦃G, L⦄ ⊢ ⦥[h, g] T.
  46 #h #g #G #L #T #H @(fsba_ind_alt … H) -G -L -T
  47 /4 width=1 by fsb_intro, fpbc_fpbg/
  48 qed-.