matita/matita/contribs/lambdadelta/basic_2/computation/lpxs_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lleq_ext.ma".
  16 include "basic_2/computation/lpxs_ldrop.ma".
  17 include "basic_2/computation/lpxs_cpxs.ma".
  18
  19 (* SN EXTENDED PARALLEL COMPUTATION FOR LOCAL ENVIRONMENTS ******************)
  20
  21 (* Advanced properties ******************************************************)
  22
  23 axiom lleq_lpxs_trans: ∀h,g,G,L1,L2,T,d. L1 ⋕[T, d] L2 → ∀K2. ⦃G, L2⦄ ⊢ ➡*[h, g] K2 →
  24                        ∃∃K1. ⦃G, L1⦄ ⊢ ➡*[h, g] K1 & K1 ⋕[T, d] K2.
  25 (*
  26 #h #g #G #L1 #L2 #T #d #H @(lleq_ind_alt … H) -L1 -L2 -T -d
  27 [
  28 |
  29 |
  30 |
  31 |
  32 | #a #I #L1 #L2 #V #T #d #_ #_ #IHV #IHT #K2 #HLK2
  33   elim (IHV … HLK2) -IHV #KV #HLKV #HV
  34   elim (IHT (K2.ⓑ{I}V)) -IHT /2 width=1 by lpxs_pair_refl/ -HLK2 #Y #H #HT
  35   elim (lpxs_inv_pair1 … H) -H #KT #VT #HLKT #_ #H destruct
  36
  37 #h #g #G #L1 #L2 #T #d * #HL12 #IH #K2 #HLK2
  38 *)
  39
  40 (* Properties on lazy equivalence for local environments ********************)
  41
  42 lemma lpxs_lleq_fqu_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
  43                            ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[T1, 0] L1 →
  44                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[T2, 0] L2.
  45 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  46 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpxs_inv_pair2 … H1) -H1
  47   #K0 #V0 #H1KL1 #_ #H destruct
  48   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
  49   #I1 #K1 #H #H2KL1 lapply (ldrop_inv_O2 … H) -H #H destruct
  50   /2 width=4 by fqu_lref_O, ex3_intro/
  51 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
  52   [ elim (lleq_inv_bind … H)
  53   | elim (lleq_inv_flat … H)
  54   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
  55 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
  56   /3 width=4 by lpxs_pair, fqu_bind_dx, ex3_intro/
  57 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
  58   /2 width=4 by fqu_flat_dx, ex3_intro/
  59 | #G1 #L1 #L #T1 #U1 #e #HL1 #HTU1 #K1 #H1KL1 #H2KL1
  60   elim (ldrop_O1_le (e+1) K1)
  61   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
  62     #H2KL elim (lpxs_ldrop_trans_O1 … H1KL1 … HL1) -L1
  63     #K0 #HK10 #H1KL lapply (ldrop_mono … HK10 … HK1) -HK10 #H destruct
  64     /3 width=4 by fqu_drop, ex3_intro/
  65   | lapply (ldrop_fwd_length_le2 … HL1) -L -T1 -g
  66     lapply (lleq_fwd_length … H2KL1) //
  67   ]
  68 ]
  69 qed-.
  70
  71 lemma lpxs_lleq_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  72                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[T1, 0] L1 →
  73                             ∃∃K2. ⦃G1, K1, T1⦄ ⊃⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[T2, 0] L2.
  74 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  75 elim (fquq_inv_gen … H) -H
  76 [ #H elim (lpxs_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  77   /3 width=4 by fqu_fquq, ex3_intro/
  78 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  79 ]
  80 qed-.
  81
  82 lemma lpxs_lleq_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
  83                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[T1, 0] L1 →
  84                             ∃∃K2. ⦃G1, K1, T1⦄ ⊃+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[T2, 0] L2.
  85 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  86 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpxs_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  87   /3 width=4 by fqu_fqup, ex3_intro/
  88 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
  89   #K #HT1 #H1KL #H2KL elim (lpxs_lleq_fqu_trans … HT2 … H1KL H2KL) -L
  90   /3 width=5 by fqup_strap1, ex3_intro/
  91 ]
  92 qed-.
  93
  94 lemma lpxs_lleq_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
  95                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[T1, 0] L1 →
  96                             ∃∃K2. ⦃G1, K1, T1⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[T2, 0] L2.
  97 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  98 elim (fqus_inv_gen … H) -H
  99 [ #H elim (lpxs_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
 100   /3 width=4 by fqup_fqus, ex3_intro/
 101 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
 102 ]
 103 qed-.