matita/matita/contribs/lambdadelta/basic_2/computation/lpxs_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lleq_lleq.ma".
  16 include "basic_2/computation/lpxs_ldrop.ma".
  17 include "basic_2/computation/lpxs_cpxs.ma".
  18
  19 (* SN EXTENDED PARALLEL COMPUTATION FOR LOCAL ENVIRONMENTS ******************)
  20
  21 (* Advanced properties ******************************************************)
  22
  23 axiom lleq_lpxs_trans_nlleq: ∀h,g,G,L1s,L1d,T,d. L1s ⋕[d, T] L1d →
  24                              ∀L2d. ⦃G, L1d⦄ ⊢ ➡*[h, g] L2d → (L1d ⋕[d, T] L2d → ⊥) →
  25                              ∃∃L2s. ⦃G, L1s⦄ ⊢ ➡*[h, g] L2s & L2s ⋕[d, T] L2d & L1s ⋕[d, T] L2s → ⊥.
  26
  27 (* Advanced inversion lemmas ************************************************)
  28
  29 axiom lpxs_inv_cpxs_nlleq: ∀h,g,G,L1,L2,T1. ⦃G, L1⦄ ⊢ ➡*[h,g] L2 → (L1 ⋕[O, T1] L2 → ⊥) →
  30                            ∃∃T2. ⦃G, L1⦄ ⊢ T1 ➡*[h, g] T2 & T1 = T2 → ⊥ & ⦃G, L2⦄ ⊢ T1 ➡[h, g] T2.
  31
  32 (* Properties on lazy equivalence for local environments ********************)
  33
  34 lemma lpxs_lleq_fqu_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
  35                            ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[0, T1] L1 →
  36                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[0, T2] L2.
  37 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  38 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpxs_inv_pair2 … H1) -H1
  39   #K0 #V0 #H1KL1 #_ #H destruct
  40   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
  41   #K1 #H #H2KL1 lapply (ldrop_inv_O2 … H) -H #H destruct
  42   /2 width=4 by fqu_lref_O, ex3_intro/
  43 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
  44   [ elim (lleq_inv_bind … H)
  45   | elim (lleq_inv_flat … H)
  46   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
  47 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
  48   /3 width=4 by lpxs_pair, fqu_bind_dx, ex3_intro/
  49 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
  50   /2 width=4 by fqu_flat_dx, ex3_intro/
  51 | #G1 #L1 #L #T1 #U1 #e #HL1 #HTU1 #K1 #H1KL1 #H2KL1
  52   elim (ldrop_O1_le (e+1) K1)
  53   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
  54     #H2KL elim (lpxs_ldrop_trans_O1 … H1KL1 … HL1) -L1
  55     #K0 #HK10 #H1KL lapply (ldrop_mono … HK10 … HK1) -HK10 #H destruct
  56     /3 width=4 by fqu_drop, ex3_intro/
  57   | lapply (ldrop_fwd_length_le2 … HL1) -L -T1 -g
  58     lapply (lleq_fwd_length … H2KL1) //
  59   ]
  60 ]
  61 qed-.
  62
  63 lemma lpxs_lleq_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  64                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[0, T1] L1 →
  65                             ∃∃K2. ⦃G1, K1, T1⦄ ⊃⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[0, T2] L2.
  66 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  67 elim (fquq_inv_gen … H) -H
  68 [ #H elim (lpxs_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  69   /3 width=4 by fqu_fquq, ex3_intro/
  70 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  71 ]
  72 qed-.
  73
  74 lemma lpxs_lleq_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
  75                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[0, T1] L1 →
  76                             ∃∃K2. ⦃G1, K1, T1⦄ ⊃+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[0, T2] L2.
  77 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  78 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpxs_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  79   /3 width=4 by fqu_fqup, ex3_intro/
  80 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
  81   #K #HT1 #H1KL #H2KL elim (lpxs_lleq_fqu_trans … HT2 … H1KL H2KL) -L
  82   /3 width=5 by fqup_strap1, ex3_intro/
  83 ]
  84 qed-.
  85
  86 lemma lpxs_lleq_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
  87                             ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 → K1 ⋕[0, T1] L1 →
  88                             ∃∃K2. ⦃G1, K1, T1⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2 & K2 ⋕[0, T2] L2.
  89 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  90 elim (fqus_inv_gen … H) -H
  91 [ #H elim (lpxs_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
  92   /3 width=4 by fqup_fqus, ex3_intro/
  93 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  94 ]
  95 qed-.