matita/matita/contribs/lambdadelta/basic_2/computation/ygt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unwind/sstas.ma".
  16 include "basic_2/reducibility/ysc.ma".
  17 include "basic_2/computation/cprs.ma".
  18
  19 (* "BIG TREE" ORDER FOR CLOSURES ********************************************)
  20
  21 definition ygt: ∀h. sd h → bi_relation lenv term ≝
  22                 λh,g. bi_TC … (ysc h g).
  23
  24 interpretation "'big tree' order (closure)"
  25    'BTGreaterThan h g L1 T1 L2 T2 = (ygt h g L1 T1 L2 T2).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 lemma ygt_ind: ∀h,g,L1,T1. ∀R:relation2 lenv term.
  30                (∀L2,T2. h ⊢ ⦃L1, T1⦄ ≻[g] ⦃L2, T2⦄ → R L2 T2) →
  31                (∀L,T,L2,T2. h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≻[g] ⦃L2, T2⦄ → R L T → R L2 T2) →
  32                ∀L2,T2. h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄ → R L2 T2.
  33 #h #g #L1 #T1 #R #IH1 #IH2 #L2 #T2 #H
  34 @(bi_TC_ind  … IH1 IH2 L2 T2 H)
  35 qed-. (**) (* /3 width=6 by bi_TC_ind/ fails *)
  36
  37 lemma ygt_ind_dx: ∀h,g,L2,T2. ∀R:relation2 lenv term.
  38                   (∀L1,T1. h ⊢ ⦃L1, T1⦄ ≻[g] ⦃L2, T2⦄ → R L1 T1) →
  39                   (∀L1,L,T1,T. h ⊢ ⦃L1, T1⦄ ≻[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ >[g] ⦃L2, T2⦄ → R L T → R L1 T1) →
  40                   ∀L1,T1. h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄ → R L1 T1.
  41 /3 width=6 by bi_TC_ind_dx/ qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 lemma ygt_strap1: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T⦄ →
  46                   h ⊢ ⦃L, T⦄ ≻[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  47 /2 width=4/ qed-.
  48
  49 lemma ygt_strap2: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≻[g] ⦃L, T⦄ →
  50                   h ⊢ ⦃L, T⦄ >[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  51 /2 width=4/ qed-.
  52
  53 lemma ygt_cprs_trans: ∀h,g,L1,L,T1,T. h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T⦄ →
  54                       ∀T2. L ⊢ T ➡* T2 → h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T2⦄.
  55 #h #g #L1 #L #T1 #T #HLT1 #T2 #H @(cprs_ind … H) -T2 //
  56 #T0 #T2 #_ #HT02 #IHT0 -HLT1
  57 elim (term_eq_dec T0 T2) #HT02 destruct //
  58 @(ygt_strap1 … IHT0) /3 width=1/
  59 qed-.
  60
  61 lemma ygt_sstas_trans: ∀h,g,L1,L,T1,T. h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T⦄ →
  62                        ∀T2. ⦃h, L⦄ ⊢ T •*[g] T2 → h ⊢ ⦃L1, T1⦄ >[g] ⦃L, T2⦄.
  63 #h #g #L1 #L #T1 #T #HLT1 #T2 #H @(sstas_ind … H) -T2 //
  64 #T0 #T2 #l #_ #HT02 #IHT0 -HLT1
  65 @(ygt_strap1 … IHT0) -IHT0 /2 width=2/
  66 qed-.
  67
  68 lemma cprs_ygt_trans: ∀h,g,L,T1,T. L ⊢ T1 ➡* T →
  69                       ∀L2,T2. h ⊢ ⦃L, T⦄ >[g] ⦃L2, T2⦄ → h ⊢ ⦃L, T1⦄ >[g] ⦃L2, T2⦄.
  70 #h #g #L #T1 #T #H @(cprs_ind … H) -T //
  71 #T0 #T #_ #HT0 #IHT10 #L2 #T2 #HLT2
  72 elim (term_eq_dec T0 T) #HT0 destruct /2 width=1/
  73 @IHT10 -IHT10 @(ygt_strap2 … HLT2) /3 width=1/
  74 qed-.
  75
  76 lemma sstas_ygt_trans: ∀h,g,L,T1,T.  ⦃h, L⦄ ⊢ T1 •*[g] T →
  77                        ∀L2,T2. h ⊢ ⦃L, T⦄ >[g] ⦃L2, T2⦄ → h ⊢ ⦃L, T1⦄ >[g] ⦃L2, T2⦄.
  78 #h #g #L #T1 #T #H @(sstas_ind … H) -T //
  79 #T0 #T #l #_ #HT0 #IHT10 #L2 #T2 #HLT2
  80 @IHT10 -IHT10 @(ygt_strap2 … HLT2) /2 width=2/
  81 qed-.
  82
  83 lemma fw_ygt: ∀h,g,L1,L2,T1,T2. ♯{L2, T2} < ♯{L1, T1} → h ⊢ ⦃L1, T1⦄ >[g] ⦃L2, T2⦄.
  84 /3 width=1/ qed.
  85
  86 lemma cprs_ygt: ∀h,g,L,T1,T2. L ⊢ T1 ➡* T2 → (T1 = T2 → ⊥) → h ⊢ ⦃L, T1⦄ >[g] ⦃L, T2⦄.
  87 #h #g #L #T1 #T2 #H @(cprs_ind … H) -T2
  88 [ #H elim H -H //
  89 | #T #T2 #_ #HT2 #IHT1 #H
  90   elim (term_eq_dec T1 T) #HT1 destruct
  91   [ -IHT1 /4 width=1 by ysc_cpr, bi_inj/ (**) (* auto too slow without trace *)
  92   | -H /4 width=3 by inj, ygt_cprs_trans/
  93   ]
  94 ]
  95 qed.