matita/matita/contribs/lambdadelta/basic_2/dynamic/yprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/fsupp.ma".
  16 include "basic_2/computation/lprs.ma".
  17 include "basic_2/dynamic/ypr.ma".
  18
  19 (* "BIG TREE" PARALLEL COMPUTATION FOR CLOSURES *****************************)
  20
  21 definition yprs: ∀h. sd h → bi_relation lenv term ≝
  22                  λh,g. bi_TC … (ypr h g).
  23
  24 interpretation "'big tree' parallel computation (closure)"
  25    'BTPRedStar h g L1 T1 L2 T2 = (yprs h g L1 T1 L2 T2).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 lemma yprs_ind: ∀h,g,L1,T1. ∀R:relation2 lenv term. R L1 T1 →
  30                 (∀L,L2,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → R L T → R L2 T2) →
  31                 ∀L2,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L2 T2.
  32 /3 width=7 by bi_TC_star_ind/ qed-.
  33
  34 lemma yprs_ind_dx: ∀h,g,L2,T2. ∀R:relation2 lenv term. R L2 T2 →
  35                    (∀L1,L,T1,T. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → R L T → R L1 T1) →
  36                    ∀L1,T1. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L1 T1.
  37 /3 width=7 by bi_TC_star_ind_dx/ qed-.
  38
  39 (* Basic properties *********************************************************)
  40
  41 lemma yprs_refl: ∀h,g. bi_reflexive … (yprs h g).
  42 /2 width=1/ qed.
  43
  44 lemma ypr_yprs: ∀h,g,L1,L2,T1,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L2, T2⦄ →
  45                 h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  46 /2 width=1/ qed.
  47
  48 lemma yprs_strap1: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ →
  49                    h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  50 /2 width=4/ qed-.
  51
  52 lemma yprs_strap2: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ →
  53                    h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  54 /2 width=4/ qed-.
  55
  56 (* Note: this is a general property of bi_TC *)
  57 lemma fsupp_yprs: ∀h,g,L1,L2,T1,T2. ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄ →
  58                   h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  59 #h #g #L1 #L2 #T1 #T2 #H @(fsupp_ind … L2 T2 H) -L2 -T2 /3 width=1/ /3 width=4/
  60 qed.
  61
  62 lemma cprs_yprs: ∀h,g,L,T1,T2. L ⊢ T1 ➡* T2 → h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  63 #h #g #L #T1 #T2 #H @(cprs_ind … H) -T2 // /3 width=4 by ypr_cpr, yprs_strap1/
  64 qed.
  65
  66 lemma lprs_yprs: ∀h,g,L1,L2,T. L1 ⊢ ➡* L2 → h ⊢ ⦃L1, T⦄ ≥[g] ⦃L2, T⦄.
  67 #h #g #L1 #L2 #T #H @(lprs_ind … H) -L2 // /3 width=4 by ypr_lpr, yprs_strap1/
  68 qed.
  69
  70 lemma sstas_yprs: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 •*[g] T2 →
  71                   h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  72 #h #g #L #T1 #T2 #H @(sstas_ind … H) -T2 // /3 width=4 by ypr_ssta, yprs_strap1/
  73 qed.
  74
  75 lemma lsubsv_yprs: ∀h,g,L1,L2,T. h ⊢ L2 ¡⊑[g] L1 → h ⊢ ⦃L1, T⦄ ≥[g] ⦃L2, T⦄.
  76 /3 width=1/ qed.
  77
  78 lemma cprs_lpr_yprs: ∀h,g,L1,L2,T1,T2. L1 ⊢ T1 ➡* T2 → L1 ⊢ ➡ L2 →
  79                      h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  80 /3 width=4 by yprs_strap1, ypr_lpr, cprs_yprs/
  81 qed.