matita/matita/contribs/lambdadelta/basic_2/dynamic/yprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/lprs.ma".
  16 include "basic_2/dynamic/ypr.ma".
  17
  18 (* "BIG TREE" PARALLEL COMPUTATION FOR CLOSURES *****************************)
  19
  20 definition yprs: ∀h. sd h → bi_relation lenv term ≝
  21                  λh,g. bi_TC … (ypr h g).
  22
  23 interpretation "'big tree' parallel computation (closure)"
  24    'BTPRedStar h g L1 T1 L2 T2 = (yprs h g L1 T1 L2 T2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma yprs_ind: ∀h,g,L1,T1. ∀R:relation2 lenv term. R L1 T1 →
  29                 (∀L,L2,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → R L T → R L2 T2) →
  30                 ∀L2,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L2 T2.
  31 /3 width=7 by bi_TC_star_ind/ qed-.
  32
  33 lemma yprs_ind_dx: ∀h,g,L2,T2. ∀R:relation2 lenv term. R L2 T2 →
  34                    (∀L1,L,T1,T. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → R L T → R L1 T1) →
  35                    ∀L1,T1. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L1 T1.
  36 /3 width=7 by bi_TC_star_ind_dx/ qed-.
  37
  38 (* Basic properties *********************************************************)
  39
  40 lemma yprs_refl: ∀h,g. bi_reflexive … (yprs h g).
  41 /2 width=1/ qed.
  42
  43 lemma ypr_yprs: ∀h,g,L1,L2,T1,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L2, T2⦄ →
  44                 h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  45 /2 width=1/ qed.
  46
  47 lemma yprs_strap1: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ →
  48                    h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  49 /2 width=4/ qed-.
  50
  51 lemma yprs_strap2: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ →
  52                    h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  53 /2 width=4/ qed-.
  54
  55 lemma fw_yprs: ∀h,g,L1,L2,T1,T2. ♯{L2, T2} < ♯{L1, T1} →
  56                h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  57 /3 width=1/ qed.
  58
  59 lemma cprs_yprs: ∀h,g,L,T1,T2. L ⊢ T1 ➡* T2 → h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  60 #h #g #L #T1 #T2 #H @(cprs_ind … H) -T2 // /3 width=4 by ypr_cpr, yprs_strap1/
  61 qed.
  62
  63 lemma lprs_yprs: ∀h,g,L1,L2,T. L1 ⊢ ➡* L2 → h ⊢ ⦃L1, T⦄ ≥[g] ⦃L2, T⦄.
  64 #h #g #L1 #L2 #T #H @(lprs_ind … H) -L2 // /3 width=4 by ypr_lpr, yprs_strap1/
  65 qed.
  66
  67 lemma sstas_yprs: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 •*[g] T2 →
  68                   h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  69 #h #g #L #T1 #T2 #H @(sstas_ind … H) -T2 // /3 width=4 by ypr_ssta, yprs_strap1/
  70 qed.
  71
  72 lemma lsubsv_yprs: ∀h,g,L1,L2,T. h ⊢ L2 ¡⊑[g] L1 → h ⊢ ⦃L1, T⦄ ≥[g] ⦃L2, T⦄.
  73 /3 width=1/ qed.
  74
  75 lemma cprs_lpr_yprs: ∀h,g,L1,L2,T1,T2. L1 ⊢ T1 ➡* T2 → L1 ⊢ ➡ L2 →
  76                      h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  77 /3 width=4 by yprs_strap1, ypr_lpr, cprs_yprs/
  78 qed.