matita/matita/contribs/lambdadelta/basic_2/equivalence/fpcs_cpcs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/fprs_cprs.ma".
  16 include "basic_2/equivalence/cpcs_cpcs.ma".
  17 include "basic_2/equivalence/fpcs_fpcs.ma".
  18
  19 (* CONTEXT-FREE PARALLEL EQUIVALENCE ON CLOSURES ****************************)
  20
  21 (* Advanced properties ******************************************************)
  22
  23 lemma fpcs_shift: ∀I,L1,L2,V1,V2,T1,T2. ⦃L1, -ⓑ{I}V1.T1⦄ ⬌* ⦃L2, -ⓑ{I}V2.T2⦄ →
  24                   ⦃L1.ⓑ{I}V1, T1⦄ ⬌* ⦃L2.ⓑ{I}V2, T2⦄.
  25 #I #L1 #L2 #V1 #V2 #T1 #T2 #H12
  26 elim (fpcs_inv_fprs … H12) -H12 #L #T #H1 #H2
  27 elim (fprs_bind2_minus … H1) -H1 #W1 #U1 #HTU1 #H destruct
  28 elim (fprs_bind2_minus … H2) -H2 #W2 #U2 #HTU2 #H destruct /2 width=4/
  29 qed.
  30
  31 (* Advanced inversion lemmas ************************************************)
  32
  33 lemma fpcs_inv_shift: ∀I,L1,L2,V1,V2,T1,T2. ⦃L1.ⓑ{I}V1, T1⦄ ⬌* ⦃L2.ⓑ{I}V2, T2⦄ →
  34                          ⦃L1, -ⓑ{I}V1.T1⦄ ⬌* ⦃L2, -ⓑ{I}V2.T2⦄.
  35 #I #L1 #L2 #V1 #V2 #T1 #T2 #H12
  36 elim (fpcs_inv_fprs … H12) -H12 #L #T #H1 #H2
  37 elim (fprs_inv_pair1 … H1) -H1 #K1 #U1 #_ #HTU1 #H destruct
  38 elim (fprs_inv_pair1 … H2) -H2 #K2 #U2 #_ #HTU2 #H destruct /2 width=4/
  39 qed-.
  40
  41 (* Advanced forward lemmas **************************************************)
  42
  43 lemma fpcs_fwd_bind_minus: ∀I,L1,L2,V1,V2,T1,T2. ⦃L1, -ⓑ{I}V1.T1⦄ ⬌* ⦃L2, -ⓑ{I}V2.T2⦄ →
  44                            ∀b. ⦃L1, ⓑ{b,I}V1.T1⦄ ⬌* ⦃L2, ⓑ{b,I}V2.T2⦄.
  45 #I #L1 #L2 #V1 #V2 #T1 #T2 #H12 #b
  46 elim (fpcs_inv_fprs … H12) -H12 #L #T #H1 #H2
  47 elim (fprs_fwd_bind2_minus … H1 b) -H1 #W1 #U1 #HTU1 #H destruct
  48 elim (fprs_fwd_bind2_minus … H2 b) -H2 #W2 #U2 #HTU2 #H destruct /2 width=4/
  49 qed-.
  50
  51 lemma fpcs_fwd_shift: ∀I,L1,L2,V1,V2,T1,T2. ⦃L1.ⓑ{I}V1, T1⦄ ⬌* ⦃L2.ⓑ{I}V2, T2⦄ →
  52                       ∀b. ⦃L1, ⓑ{b,I}V1.T1⦄ ⬌* ⦃L2, ⓑ{b,I}V2.T2⦄.
  53 /3 width=1 by fpcs_inv_shift, fpcs_fwd_bind_minus/ qed-.
  54
  55 lemma fpcs_fwd_abst24: ∀a,L1,L2,V1,V2,T1,T2. ⦃L1, ⓛ{a}V1.T1⦄ ⬌* ⦃L2, ⓛ{a}V2.T2⦄ →
  56                        ∀b,I,W. ⦃L1, ⓑ{b,I}W.T1⦄ ⬌* ⦃L2, ⓑ{b,I}W.T2⦄.
  57 #a #L1 #L2 #V1 #V2 #T1 #T2 #H12 #b #I #W
  58 elim (fpcs_inv_fprs … H12) -H12 #L #U #H1 #H2
  59 elim (fprs_fwd_abst2 … H1 b I W) -H1 #W1 #U1 #HTU1 #H destruct
  60 elim (fprs_fwd_abst2 … H2 b I W) -H2 #W2 #U2 #HTU2 #H destruct /2 width=4/
  61 qed-.
  62
  63 lemma fpcs_fwd_abst13: ∀L1,L2,V1,V2,T1,T2. ⦃L1.ⓛV1, T1⦄ ⬌* ⦃L2.ⓛV2, T2⦄ →
  64                        ∀I,W. ⦃L1.ⓑ{I}W, T1⦄ ⬌* ⦃L2.ⓑ{I}W, T2⦄.
  65 /4 width=4 by fpcs_fwd_shift, fpcs_fwd_abst24, fpcs_shift/ qed-.
  66
  67 (* Properties on context-sensitive parallel equivalence for terms ***********)
  68
  69 lemma cpcs_fpcs: ∀L,T1,T2. L ⊢ T1 ⬌* T2 → ⦃L, T1⦄ ⬌* ⦃L, T2⦄.
  70 #L #T1 #T2 #H
  71 elim (cpcs_inv_cprs … H) -H /3 width=4 by fprs_div, cprs_fprs/ (**) (* too slow without trace *)
  72 qed.
  73
  74 (* Inversion lemmas on context-sensitive parallel equivalence for terms *****)
  75
  76 lemma fpcs_inv_cpcs: ∀L,T1,T2. ⦃L, T1⦄ ⬌* ⦃L, T2⦄ → L ⊢ T1 ⬌* T2.
  77 #L #T1 #T2 #H
  78 elim (fpcs_inv_fprs … H) -H /3 width=4 by cprs_div, fprs_fwd_cprs/
  79 qed-.