matita/matita/contribs/lambdadelta/basic_2/etc/cpys/cpys_lift.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/ldrop_ldrop.ma".
  16 include "basic_2/substitution/fqus_alt.ma".
  17 include "basic_2/substitution/cpys.ma".
  18
  19 (* CONTEXT-SENSITIVE EXTENDED MULTIPLE SUBSTITUTION FOR TERMS ***************)
  20
  21 (* Relocation properties ****************************************************)
  22
  23 lemma cpys_lift: ∀G. l_liftable (cpys G).
  24 #G #K #T1 #T2 #H elim H -G -K -T1 -T2
  25 [ #I #G #K #L #d #e #_ #U1 #H1 #U2 #H2
  26   >(lift_mono … H1 … H2) -H1 -H2 //
  27 | #I #G #K #KV #V #V2 #W2 #i #HKV #HV2 #HVW2 #IHV2 #L #d #e #HLK #U1 #H #U2 #HWU2
  28   elim (lift_inv_lref1 … H) * #Hid #H destruct
  29   [ elim (lift_trans_ge … HVW2 … HWU2) -W2 // <minus_plus #W2 #HVW2 #HWU2
  30     elim (ldrop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  31     elim (ldrop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hid #K #Y #HKV #HVY #H destruct /3 width=9 by cpys_delta/
  32   | lapply (lift_trans_be … HVW2 … HWU2 ? ?) -W2 /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  33     lapply (ldrop_trans_ge_comm … HLK … HKV ?) -K /3 width=7 by cpys_delta/
  34   ]
  35 | #a #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #d #e #HLK #U1 #H1 #U2 #H2
  36   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  37   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /4 width=5 by cpys_bind, ldrop_skip/
  38 | #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #d #e #HLK #U1 #H1 #U2 #H2
  39   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  40   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /3 width=6 by cpys_flat/
  41 ]
  42 qed.
  43
  44 lemma cpys_inv_lift1: ∀G. l_deliftable_sn (cpys G).
  45 #G #L #U1 #U2 #H elim H -G -L -U1 -U2
  46 [ * #G #L #i #K #d #e #_ #T1 #H
  47   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by cpys_atom, lift_sort, ex2_intro/
  48   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by cpys_atom, lift_lref_ge_minus, lift_lref_lt, ex2_intro/
  49   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by cpys_atom, lift_gref, ex2_intro/
  50   ]
  51 | #I #G #L #LV #V #V2 #W2 #i #HLV #HV2 #HVW2 #IHV2 #K #d #e #HLK #T1 #H
  52   elim (lift_inv_lref2 … H) -H * #Hid #H destruct
  53   [ elim (ldrop_conf_lt … HLK … HLV) -L // #L #U #HKL #HLV #HUV
  54     elim (IHV2 … HLV … HUV) -V #U2 #HUV2 #HU2
  55     elim (lift_trans_le … HUV2 … HVW2) -V2 // >minus_plus <plus_minus_m_m /3 width=9 by cpys_delta, ex2_intro/
  56   | elim (le_inv_plus_l … Hid) #Hdie #Hei
  57     lapply (ldrop_conf_ge … HLK … HLV ?) -L // #HKLV
  58     elim (lift_split … HVW2 d (i - e + 1)) -HVW2 /3 width=1 by le_S, le_S_S/ -Hid -Hdie
  59     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O /3 width=9 by cpys_delta, ex2_intro/
  60   ]
  61 | #a #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H
  62   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
  63   elim (IHV12 … HLK … HWV1) -IHV12 #W2 #HW12 #HWV2
  64   elim (IHU12 … HTU1) -IHU12 -HTU1 /3 width=5 by cpys_bind, ldrop_skip, lift_bind, ex2_intro/
  65 | #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H
  66   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
  67   elim (IHV12 … HLK … HWV1) -V1
  68   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=5 by cpys_flat, lift_flat, ex2_intro/
  69 ]
  70 qed-.
  71
  72 (* Properties on supclosure *************************************************)
  73
  74 lemma fqu_cpys_trans: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
  75                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 →
  76                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & ⦃G1, L1, U1⦄ ⊃ ⦃G2, L2, U2⦄.
  77 #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  78 /3 width=3 by fqu_pair_sn, fqu_bind_dx, fqu_flat_dx, cpys_pair_sn, cpys_bind, cpys_flat, ex2_intro/
  79 [ #I #G #L #V2 #U2 #HVU2
  80   elim (lift_total U2 0 1)
  81   /4 width=7 by fqu_drop, cpys_delta, ldrop_pair, ldrop_ldrop, ex2_intro/
  82 | #G #L #K #T1 #U1 #e #HLK1 #HTU1 #T2 #HTU2
  83   elim (lift_total T2 0 (e+1))
  84   /3 width=11 by cpys_lift, fqu_drop, ex2_intro/
  85 ]
  86 qed-.
  87
  88 lemma fquq_cpys_trans: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  89                        ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 →
  90                        ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & ⦃G1, L1, U1⦄ ⊃⸮ ⦃G2, L2, U2⦄.
  91 #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fquq_inv_gen … H) -H
  92 [ #HT12 elim (fqu_cpys_trans … HT12 … HTU2) /3 width=3 by fqu_fquq, ex2_intro/
  93 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
  94 ]
  95 qed-.
  96
  97 lemma fqup_cpys_trans: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
  98                        ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 →
  99                        ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & ⦃G1, L1, U1⦄ ⊃+ ⦃G2, L2, U2⦄.
 100 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
 101 [ #G2 #L2 #T2 #H12 #U2 #HTU2 elim (fqu_cpys_trans … H12 … HTU2) -T2
 102   /3 width=3 by fqu_fqup, ex2_intro/
 103 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #U2 #HTU2
 104   elim (fqu_cpys_trans … HT2 … HTU2) -T2 #T2 #HT2 #HTU2
 105   elim (IHT1 … HT2) -T /3 width=7 by fqup_strap1, ex2_intro/
 106 ]
 107 qed-.
 108
 109 lemma fqus_cpys_trans: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
 110                        ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 →
 111                        ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & ⦃G1, L1, U1⦄ ⊃* ⦃G2, L2, U2⦄.
 112 #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fqus_inv_gen … H) -H
 113 [ #HT12 elim (fqup_cpys_trans … HT12 … HTU2) /3 width=3 by fqup_fqus, ex2_intro/
 114 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
 115 ]
 116 qed-.
 117
 118 lemma fqu_cpys_trans_neq: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
 119                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 → (T2 = U2 → ⊥) →
 120                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃ ⦃G2, L2, U2⦄.
 121 #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 122 [ #I #G #L #V1 #V2 #HV12 #_ elim (lift_total V2 0 1)
 123   #U2 #HVU2 @(ex3_intro … U2)
 124   [1,3: /3 width=7 by fqu_drop, cpys_delta, ldrop_pair, ldrop_ldrop/
 125   | #H destruct /2 width=7 by lift_inv_lref2_be/
 126   ]
 127 | #I #G #L #V1 #T #V2 #HV12 #H @(ex3_intro … (②{I}V2.T))
 128   [1,3: /2 width=4 by fqu_pair_sn, cpys_pair_sn/
 129   | #H0 destruct /2 width=1 by/
 130   ]
 131 | #a #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓑ{a,I}V.T2))
 132   [1,3: /2 width=4 by fqu_bind_dx, cpys_bind/
 133   | #H0 destruct /2 width=1 by/
 134   ]
 135 | #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓕ{I}V.T2))
 136   [1,3: /2 width=4 by fqu_flat_dx, cpys_flat/
 137   | #H0 destruct /2 width=1 by/
 138   ]
 139 | #G #L #K #T1 #U1 #e #HLK #HTU1 #T2 #HT12 #H elim (lift_total T2 0 (e+1))
 140   #U2 #HTU2 @(ex3_intro … U2)
 141   [1,3: /2 width=9 by cpys_lift, fqu_drop/
 142   | #H0 destruct /3 width=5 by lift_inj/
 143 ]
 144 qed-.
 145
 146 lemma fquq_cpys_trans_neq: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
 147                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 → (T2 = U2 → ⊥) →
 148                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃⸮ ⦃G2, L2, U2⦄.
 149 #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fquq_inv_gen … H12) -H12
 150 [ #H12 elim (fqu_cpys_trans_neq … H12 … HTU2 H) -T2
 151   /3 width=4 by fqu_fquq, ex3_intro/
 152 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 153 ]
 154 qed-.
 155
 156 lemma fqup_cpys_trans_neq: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
 157                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 → (T2 = U2 → ⊥) →
 158                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃+ ⦃G2, L2, U2⦄.
 159 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1
 160 [ #G1 #L1 #T1 #H12 #U2 #HTU2 #H elim (fqu_cpys_trans_neq … H12 … HTU2 H) -T2
 161   /3 width=4 by fqu_fqup, ex3_intro/
 162 | #G #G1 #L #L1 #T #T1 #H1 #_ #IH12 #U2 #HTU2 #H elim (IH12 … HTU2 H) -T2
 163   #U1 #HTU1 #H #H12 elim (fqu_cpys_trans_neq … H1 … HTU1 H) -T1
 164   /3 width=8 by fqup_strap2, ex3_intro/
 165 ]
 166 qed-.
 167
 168 lemma fqus_cpys_trans_neq: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
 169                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ▶*× U2 → (T2 = U2 → ⊥) →
 170                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ▶*× U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃* ⦃G2, L2, U2⦄.
 171 #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fqus_inv_gen … H12) -H12
 172 [ #H12 elim (fqup_cpys_trans_neq … H12 … HTU2 H) -T2
 173   /3 width=4 by fqup_fqus, ex3_intro/
 174 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 175 ]
 176 qed-.