matita/matita/contribs/lambdadelta/basic_2/etc/llpx_sn/llpx_sn_alt.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lift_neg.ma".
  16 include "basic_2/relocation/ldrop_ldrop.ma".
  17 include "basic_2/relocation/llpx_sn.ma".
  18
  19 (* LAZY SN POINTWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS ****)
  20
  21 (* alternative definition of llpx_sn_alt *)
  22 inductive llpx_sn_alt (R:relation3 lenv term term): relation4 ynat term lenv lenv ≝
  23 | llpx_sn_alt_intro: ∀L1,L2,T,d.
  24                      (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
  25                        ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 → I1 = I2 ∧ R K1 V1 V2
  26                      ) →
  27                      (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
  28                        ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 → llpx_sn_alt R 0 V1 K1 K2
  29                      ) → |L1| = |L2| → llpx_sn_alt R d T L1 L2
  30 .
  31
  32 (* Basic forward lemmas ******************************************************)
  33
  34 lemma llpx_sn_alt_fwd_gen: ∀R,L1,L2,T,d. llpx_sn_alt R d T L1 L2 →
  35                            |L1| = |L2| ∧
  36                            ∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
  37                            ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
  38                            ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn_alt R 0 V1 K1 K2.
  39 #R #L1 #L2 #T #d * -L1 -L2 -T -d
  40 #L1 #L2 #T #d #IH1 #IH2 #HL12 @conj //
  41 #I1 #I2 #K1 #K2 #HLK1 #HLK2 #i #Hid #HnT #HLK1 #HLK2
  42 elim (IH1 … HnT HLK1 HLK2) -IH1 /4 width=8 by and3_intro/
  43 qed-.
  44
  45 lemma llpx_sn_alt_fwd_length: ∀R,L1,L2,T,d. llpx_sn_alt R d T L1 L2 → |L1| = |L2|.
  46 #R #L1 #L2 #T #d * -L1 -L2 -T -d //
  47 qed-.
  48
  49 fact llpx_sn_alt_fwd_lref_aux: ∀R,L1,L2,X,d. llpx_sn_alt R d X L1 L2 → ∀i. X = #i →
  50                                ∨∨ |L1| ≤ i ∧ |L2| ≤ i
  51                                 | yinj i < d
  52                                 | ∃∃I,K1,K2,V1,V2. ⇩[i] L1 ≡ K1.ⓑ{I}V1 &
  53                                                    ⇩[i] L2 ≡ K2.ⓑ{I}V2 &
  54                                                    llpx_sn_alt R (yinj 0) V1 K1 K2 &
  55                                                    R K1 V1 V2 & d ≤ yinj i.
  56 #R #L1 #L2 #X #d * -L1 -L2 -X -d
  57 #L1 #L2 #X #d #H1X #H2X #HL12 #i #H destruct
  58 elim (lt_or_ge i (|L1|)) /3 width=1 by or3_intro0, conj/
  59 elim (ylt_split i d) /3 width=1 by or3_intro1/
  60 #Hdi #HL1 elim (ldrop_O1_lt … HL1) #I1 #K1 #V1 #HLK1
  61 elim (ldrop_O1_lt L2 i) // #I2 #K2 #V2 #HLK2
  62 elim (H1X … HLK1 HLK2) -H1X /2 width=3 by nlift_lref_be_SO/ #H #HV12 destruct
  63 lapply (H2X … HLK1 HLK2) -H2X /2 width=3 by nlift_lref_be_SO/
  64 /3 width=9 by or3_intro2, ex5_5_intro/
  65 qed-.
  66
  67 lemma llpx_sn_alt_fwd_lref: ∀R,L1,L2,d,i. llpx_sn_alt R d (#i) L1 L2 →
  68                             ∨∨ |L1| ≤ i ∧ |L2| ≤ i
  69                              | yinj i < d
  70                              | ∃∃I,K1,K2,V1,V2. ⇩[i] L1 ≡ K1.ⓑ{I}V1 &
  71                                                 ⇩[i] L2 ≡ K2.ⓑ{I}V2 &
  72                                                 llpx_sn_alt R (yinj 0) V1 K1 K2 &
  73                                                 R K1 V1 V2 & d ≤ yinj i.
  74 /2 width=3 by llpx_sn_alt_fwd_lref_aux/ qed-.
  75
  76 (* Basic inversion lemmas ****************************************************)
  77
  78 fact llpx_sn_alt_inv_flat_aux: ∀R,L1,L2,X,d. llpx_sn_alt R d X L1 L2 →
  79                                ∀I,V,T. X = ⓕ{I}V.T →
  80                                llpx_sn_alt R d V L1 L2 ∧ llpx_sn_alt R d T L1 L2.
  81 #R #L1 #L2 #X #d * -L1 -L2 -X -d
  82 #L1 #L2 #X #d #H1X #H2X #HL12
  83 #I #V #T #H destruct
  84 @conj @llpx_sn_alt_intro // -HL12
  85 /4 width=8 by nlift_flat_sn, nlift_flat_dx/
  86 qed-.
  87
  88 lemma llpx_sn_alt_inv_flat: ∀R,I,L1,L2,V,T,d. llpx_sn_alt R d (ⓕ{I}V.T) L1 L2 →
  89                             llpx_sn_alt R d V L1 L2 ∧ llpx_sn_alt R d T L1 L2.
  90 /2 width=4 by llpx_sn_alt_inv_flat_aux/ qed-.
  91
  92 fact llpx_sn_alt_inv_bind_aux: ∀R,L1,L2,X,d. llpx_sn_alt R d X L1 L2 →
  93                                ∀a,I,V,T. X = ⓑ{a,I}V.T →
  94                                llpx_sn_alt R d V L1 L2 ∧ llpx_sn_alt R (⫯d) T (L1.ⓑ{I}V) (L2.ⓑ{I}V).
  95 #R #L1 #L2 #X #d * -L1 -L2 -X -d
  96 #L1 #L2 #X #d #H1X #H2X #HL12
  97 #a #I #V #T #H destruct
  98 @conj @llpx_sn_alt_intro [3,6: normalize /2 width=1 by eq_f2/ ] -HL12
  99 #I1 #I2 #K1 #K2 #W1 #W2 #i #Hdi #H #HLK1 #HLK2
 100 [1,2: /4 width=9 by nlift_bind_sn/ ]
 101 lapply (yle_inv_succ1 … Hdi) -Hdi * #Hdi #Hi
 102 lapply (ldrop_inv_drop1_lt … HLK1 ?) -HLK1 /2 width=1 by ylt_O/ #HLK1
 103 lapply (ldrop_inv_drop1_lt … HLK2 ?) -HLK2 /2 width=1 by ylt_O/ #HLK2
 104 [ @(H1X … HLK1 HLK2) | @(H2X … HLK1 HLK2) ] // -I1 -I2 -L1 -L2 -K1 -K2 -W1 -W2
 105 @nlift_bind_dx <plus_minus_m_m /2 width=2 by ylt_O/
 106 qed-.
 107
 108 lemma llpx_sn_alt_inv_bind: ∀R,a,I,L1,L2,V,T,d. llpx_sn_alt R d (ⓑ{a,I}V.T) L1 L2 →
 109                             llpx_sn_alt R d V L1 L2 ∧ llpx_sn_alt R (⫯d) T (L1.ⓑ{I}V) (L2.ⓑ{I}V).
 110 /2 width=4 by llpx_sn_alt_inv_bind_aux/ qed-.
 111
 112 (* Basic properties **********************************************************)
 113
 114 lemma llpx_sn_alt_intro_alt: ∀R,L1,L2,T,d. |L1| = |L2| →
 115                              (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
 116                                 ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
 117                                 ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn_alt R 0 V1 K1 K2
 118                              ) → llpx_sn_alt R d T L1 L2.
 119 #R #L1 #L2 #T #d #HL12 #IH @llpx_sn_alt_intro // -HL12
 120 #I1 #I2 #K1 #K2 #HLK1 #HLK2 #i #Hid #HnT #HLK1 #HLK2
 121 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /2 width=1 by conj/
 122 qed.
 123
 124 lemma llpx_sn_alt_sort: ∀R,L1,L2,d,k. |L1| = |L2| → llpx_sn_alt R d (⋆k) L1 L2.
 125 #R #L1 #L2 #d #k #HL12 @llpx_sn_alt_intro // -HL12
 126 #I1 #I2 #K1 #K2 #V1 #V2 #i #_ #H elim (H (⋆k)) //
 127 qed.
 128
 129 lemma llpx_sn_alt_gref: ∀R,L1,L2,d,p. |L1| = |L2| → llpx_sn_alt R d (§p) L1 L2.
 130 #R #L1 #L2 #d #p #HL12 @llpx_sn_alt_intro // -HL12
 131 #I1 #I2 #K1 #K2 #V1 #V2 #i #_ #H elim (H (§p)) //
 132 qed.
 133
 134 lemma llpx_sn_alt_skip: ∀R,L1,L2,d,i. |L1| = |L2| → yinj i < d → llpx_sn_alt R d (#i) L1 L2.
 135 #R #L1 #L2 #d #i #HL12 #Hid @llpx_sn_alt_intro // -HL12
 136 #I1 #I2 #K1 #K2 #V1 #V2 #j #Hdj #H elim (H (#i)) -H
 137 /4 width=3 by lift_lref_lt, ylt_yle_trans, ylt_inv_inj/
 138 qed.
 139
 140 lemma llpx_sn_alt_free: ∀R,L1,L2,d,i. |L1| ≤ i → |L2| ≤ i → |L1| = |L2| →
 141                         llpx_sn_alt R d (#i) L1 L2.
 142 #R #L1 #L2 #d #i #HL1 #_ #HL12 @llpx_sn_alt_intro // -HL12
 143 #I1 #I2 #K1 #K2 #V1 #V2 #j #_ #H #HLK1 elim (H (#(i-1))) -H
 144 lapply (ldrop_fwd_length_lt2 … HLK1) -HLK1
 145 /3 width=3 by lift_lref_ge_minus, lt_to_le_to_lt/
 146 qed.
 147
 148 lemma llpx_sn_alt_lref: ∀R,I,L1,L2,K1,K2,V1,V2,d,i. d ≤ yinj i →
 149                         ⇩[i] L1 ≡ K1.ⓑ{I}V1 → ⇩[i] L2 ≡ K2.ⓑ{I}V2 →
 150                         llpx_sn_alt R 0 V1 K1 K2 → R K1 V1 V2 →
 151                         llpx_sn_alt R d (#i) L1 L2.
 152 #R #I #L1 #L2 #K1 #K2 #V1 #V2 #d #i #Hdi #HLK1 #HLK2 #HK12 #HV12 @llpx_sn_alt_intro
 153 [1,2: #Z1 #Z2 #Y1 #Y2 #X1 #X2 #j #Hdj #H #HLY1 #HLY2
 154   elim (lt_or_eq_or_gt i j) #Hij destruct
 155   [1,4: elim (H (#i)) -H /2 width=1 by lift_lref_lt/
 156   |2,5: lapply (ldrop_mono … HLY1 … HLK1) -HLY1 -HLK1 #H destruct
 157     lapply (ldrop_mono … HLY2 … HLK2) -HLY2 -HLK2 #H destruct /2 width=1 by conj/
 158   |3,6: elim (H (#(i-1))) -H /2 width=1 by lift_lref_ge_minus/
 159   ]
 160 | lapply (llpx_sn_alt_fwd_length … HK12) -HK12 #HK12
 161   @(ldrop_fwd_length_eq2 … HLK1 HLK2) normalize /2 width=1 by eq_f2/
 162 ]
 163 qed.
 164
 165 fact llpx_sn_alt_flat_aux: ∀R,I,L1,L2,V,d. llpx_sn_alt R d V L1 L2 →
 166                            ∀Y1,Y2,T,m. llpx_sn_alt R m T Y1 Y2 →
 167                            Y1 = L1 → Y2 = L2 → m = d →
 168                            llpx_sn_alt R d (ⓕ{I}V.T) L1 L2.
 169 #R #I #L1 #L2 #V #d * -L1 -L2 -V -d #L1 #L2 #V #d #H1V #H2V #HL12
 170 #Y1 #Y2 #T #m * -Y1 -Y2 -T -m #Y1 #Y2 #T #m #H1T #H2T #_
 171 #HT1 #HY2 #Hm destruct
 172 @llpx_sn_alt_intro // -HL12
 173 #J1 #J2 #K1 #K2 #W1 #W2 #i #Hdi #HnVT #HLK1 #HLK2
 174 elim (nlift_inv_flat … HnVT) -HnVT /3 width=8 by/
 175 qed-.
 176
 177 lemma llpx_sn_alt_flat: ∀R,I,L1,L2,V,T,d.
 178                         llpx_sn_alt R d V L1 L2 → llpx_sn_alt R d T L1 L2 →
 179                         llpx_sn_alt R d (ⓕ{I}V.T) L1 L2.
 180 /2 width=7 by llpx_sn_alt_flat_aux/ qed.
 181
 182 fact llpx_sn_alt_bind_aux: ∀R,a,I,L1,L2,V,d. llpx_sn_alt R d V L1 L2 →
 183                            ∀Y1,Y2,T,m. llpx_sn_alt R m T Y1 Y2 →
 184                            Y1 = L1.ⓑ{I}V → Y2 = L2.ⓑ{I}V → m = ⫯d →
 185                            llpx_sn_alt R d (ⓑ{a,I}V.T) L1 L2.
 186 #R #a #I #L1 #L2 #V #d * -L1 -L2 -V -d #L1 #L2 #V #d #H1V #H2V #HL12
 187 #Y1 #Y2 #T #m * -Y1 -Y2 -T -m #Y1 #Y2 #T #m #H1T #H2T #_
 188 #HT1 #HY2 #Hm destruct
 189 @llpx_sn_alt_intro // -HL12
 190 #J1 #J2 #K1 #K2 #W1 #W2 #i #Hdi #HnVT #HLK1 #HLK2
 191 elim (nlift_inv_bind … HnVT) -HnVT /3 width=8 by ldrop_drop, yle_succ/
 192 qed-.
 193
 194 lemma llpx_sn_alt_bind: ∀R,a,I,L1,L2,V,T,d.
 195                         llpx_sn_alt R d V L1 L2 →
 196                         llpx_sn_alt R (⫯d) T (L1.ⓑ{I}V) (L2.ⓑ{I}V) →
 197                         llpx_sn_alt R d (ⓑ{a,I}V.T) L1 L2.
 198 /2 width=7 by llpx_sn_alt_bind_aux/ qed.
 199
 200 (* Main properties **********************************************************)
 201
 202 theorem llpx_sn_lpx_sn_alt: ∀R,L1,L2,T,d. llpx_sn R d T L1 L2 → llpx_sn_alt R d T L1 L2.
 203 #R #L1 #L2 #T #d #H elim H -L1 -L2 -T -d
 204 /2 width=9 by llpx_sn_alt_sort, llpx_sn_alt_gref, llpx_sn_alt_skip, llpx_sn_alt_free, llpx_sn_alt_lref, llpx_sn_alt_flat, llpx_sn_alt_bind/
 205 qed.
 206
 207 (* Main inversion lemmas ****************************************************)
 208
 209 theorem llpx_sn_alt_inv_lpx_sn: ∀R,T,L1,L2,d. llpx_sn_alt R d T L1 L2 → llpx_sn R d T L1 L2.
 210 #R #T #L1 @(f2_ind … rfw … L1 T) -L1 -T #n #IH #L1 * *
 211 [1,3: /3 width=4 by llpx_sn_alt_fwd_length, llpx_sn_gref, llpx_sn_sort/
 212 | #i #Hn #L2 #d #H lapply (llpx_sn_alt_fwd_length … H)
 213   #HL12 elim (llpx_sn_alt_fwd_lref … H) -H
 214   [ * /2 width=1 by llpx_sn_free/
 215   | /2 width=1 by llpx_sn_skip/
 216   | * /4 width=9 by llpx_sn_lref, ldrop_fwd_rfw/
 217   ]
 218 | #a #I #V #T #Hn #L2 #d #H elim (llpx_sn_alt_inv_bind … H) -H
 219   /3 width=1 by llpx_sn_bind/
 220 | #I #V #T #Hn #L2 #d #H elim (llpx_sn_alt_inv_flat … H) -H
 221   /3 width=1 by llpx_sn_flat/
 222 ]
 223 qed-.
 224
 225 (* Advanced properties ******************************************************)
 226
 227 lemma llpx_sn_intro_alt: ∀R,L1,L2,T,d. |L1| = |L2| →
 228                          (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
 229                             ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
 230                             ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn R 0 V1 K1 K2
 231                          ) → llpx_sn R d T L1 L2.
 232 #R #L1 #L2 #T #d #HL12 #IH @llpx_sn_alt_inv_lpx_sn
 233 @llpx_sn_alt_intro_alt // -HL12
 234 #I1 #I2 #K1 #K2 #HLK1 #HLK2 #i #Hid #HnT #HLK1 #HLK2
 235 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /3 width=1 by llpx_sn_lpx_sn_alt, and3_intro/
 236 qed.
 237
 238 (* Advanced forward lemmas lemmas *******************************************)
 239
 240 lemma llpx_sn_fwd_alt: ∀R,L1,L2,T,d. llpx_sn R d T L1 L2 →
 241                        |L1| = |L2| ∧
 242                        ∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
 243                        ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
 244                        ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn R 0 V1 K1 K2.
 245 #R #L1 #L2 #T #d #H lapply (llpx_sn_lpx_sn_alt … H) -H
 246 #H elim (llpx_sn_alt_fwd_gen … H) -H
 247 #HL12 #IH @conj //
 248 #I1 #I2 #K1 #K2 #HLK1 #HLK2 #i #Hid #HnT #HLK1 #HLK2
 249 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /3 width=1 by llpx_sn_alt_inv_lpx_sn, and3_intro/
 250 qed-.