matita/matita/contribs/lambdadelta/basic_2/etc/referred/lfpx_aaa.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/aaa_drops.ma".
  16 include "basic_2/static/lsuba_aaa.ma".
  17 include "basic_2/rt_transition/lfpx_fqup.ma".
  18
  19 (* UNBOUND PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *******)
  20
  21 (* Properties with atomic arity assignment for terms ************************)
  22
  23 lemma cpx_aaa_conf_lfpx: ∀h,G,L1,T1,A. ⦃G, L1⦄ ⊢ T1 ⁝ A →
  24                          ∀T2. ⦃G, L1⦄ ⊢ T1 ⬈[h] T2 →
  25                          ∀L2. ⦃G, L1⦄ ⊢ ⬈[h, T1] L2 → ⦃G, L2⦄ ⊢ T2 ⁝ A.
  26 #h #G #L1 #T1 #A #H elim H -G -L1 -T1 -A
  27 [ #G #L1 #s #X2 #HX
  28   elim (cpx_inv_sort1 … HX) -HX //
  29 | #I #G #L1 #V1 #B #_ #IH #X2 #HX #Y #HY
  30   elim (lfpx_inv_zero_pair_sn … HY) -HY #L2 #V2 #HL12 #HV12 #H destruct
  31   elim (cpx_inv_zero1_pair … HX) -HX
  32   [ #H destruct /3 width=1 by aaa_zero/
  33   | -HV12 * /4 width=7 by aaa_lifts, drops_refl, drops_drop/
  34   ]
  35 | #I #G #L1 #B #i #_ #IH #X2 #HX #Y #HY
  36   elim (lfpx_inv_lref_bind_sn … HY) -HY #I2 #L2 #HL12 #H destruct
  37   elim (cpx_inv_lref1_bind … HX) -HX
  38   [ #H destruct /3 width=1 by aaa_lref/
  39   | * /4 width=7 by aaa_lifts, drops_refl, drops_drop/
  40   ]
  41 | #p #G #L1 #V1 #T1 #B #A #_ #_ #IHV #IHT #X2 #HX #L2 #HL12
  42   elim (lfpx_inv_bind … HL12) -HL12 #HV #HT
  43   elim (cpx_inv_abbr1 … HX) -HX *
  44   [ #V2 #T2 #HV12 #HT12 #H destruct
  45     /5 width=2 by lfpx_bind_repl_dx, aaa_abbr, ext2_pair/
  46   | #T2 #HT12 #HXT2 #H destruct -IHV
  47     /4 width=7 by aaa_inv_lifts, drops_drop, drops_refl/
  48   ]
  49 | #p #G #L1 #V1 #T1 #B #A #_ #_ #IHV #IHT #X2 #H #L2 #HL12
  50   elim (lfpx_inv_bind … HL12) -HL12 #HV #HT
  51   elim (cpx_inv_abst1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
  52   /5 width=2 by lfpx_bind_repl_dx, aaa_abst, ext2_pair/
  53 | #G #L1 #V1 #T1 #B #A #_ #_ #IHV #IHT #X2 #H #L2 #HL12
  54   elim (lfpx_inv_flat … HL12) -HL12 #HV #HT
  55   elim (cpx_inv_appl1 … H) -H *
  56   [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=3 by aaa_appl/
  57   | #q #V2 #W1 #W2 #U1 #U2 #HV12 #HW12 #HU12 #H1 #H2 destruct
  58     lapply (IHV … HV12 … HV) -IHV -HV12 -HV #HV2
  59     lapply (IHT (ⓛ{q}W2.U2) … HT) -IHT -HT /2 width=1 by cpx_bind/ -L1 #H
  60     elim (aaa_inv_abst … H) -H #B0 #A0 #HW1 #HU2 #H destruct
  61     /5 width=6 by lsuba_aaa_trans, lsuba_beta, aaa_abbr, aaa_cast/
  62   | #q #V #V2 #W1 #W2 #U1 #U2 #HV1 #HV2 #HW12 #HU12 #H1 #H2 destruct
  63     lapply (aaa_lifts G L2 … B … (L2.ⓓW2) … HV2) -HV2 /3 width=2 by drops_drop, drops_refl/ #HV2
  64     lapply (IHT (ⓓ{q}W2.U2) … HT) -IHT -HT /2 width=1 by cpx_bind/ -L1 #H
  65     elim (aaa_inv_abbr … H) -H /3 width=3 by aaa_abbr, aaa_appl/
  66   ]
  67 | #G #L1 #V1 #T1 #A #_ #_ #IHV #IHT #X2 #HX #L2 #HL12
  68   elim (lfpx_inv_flat … HL12) -HL12 #HV #HT
  69   elim (cpx_inv_cast1 … HX) -HX
  70   [ * #V2 #T2 #HV12 #HT12 #H destruct ] /3 width=1 by aaa_cast/
  71 ]
  72 qed-.
  73
  74 lemma lfpx_aaa_conf: ∀h,G,T. Conf3 … (λL. aaa G L T) (lfpx h G T).
  75 /2 width=6 by cpx_aaa_conf_lfpx/ qed-.