matita/matita/contribs/lambdadelta/basic_2/etc/referred/lfpx_fquq.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/lfpx_drops.ma".
  16 include "basic_2/rt_transition/lfpx_fsle.ma".
  17 include "basic_2/s_transition/fquq.ma".
  18
  19 (* UNBOUND PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *******)
  20
  21 (* Properties with extended structural successor for closures ***************)
  22
  23 lemma lfpx_fqu_trans: ∀h,b,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐[b] ⦃G2, L2, T2⦄ →
  24                       ∀K1. ⦃G1, K1⦄ ⊢ ⬈[h, T1] L1 →
  25                       ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ⬈[h] T & ⦃G1, K1, T⦄ ⊐[b] ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ⬈[h, T2] L2.
  26 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  27 [ #I #G #K #V #K1 #H
  28   elim (lfpx_inv_zero_pair_dx … H) -H #K0 #V0 #HK0 #HV0 #H destruct
  29   elim (lifts_total V (𝐔❴1❵)) #T #HVT
  30   /3 width=7 by lfpx_cpx_conf, cpx_delta, fqu_drop, ex3_2_intro/
  31 | /3 width=7 by lfpx_fwd_pair_sn, cpx_pair_sn, fqu_pair_sn, ex3_2_intro/
  32 | /3 width=6 by lfpx_fwd_bind_dx, cpx_pair_sn, fqu_bind_dx, ex3_2_intro/
  33 | /3 width=8 by lfpx_fwd_bind_dx_void, cpx_pair_sn, fqu_clear, ex3_2_intro/
  34 | /3 width=7 by lfpx_fwd_flat_dx, cpx_pair_sn, fqu_flat_dx, ex3_2_intro/
  35 | #I #G #K #T #U #HTU #K1 #H
  36   elim (lfpx_drops_trans … H (Ⓣ) … HTU) -H
  37   [|*: /3 width=2 by drops_refl, drops_drop/ ] -I #K0 #HK10 #HK0
  38   elim (drops_inv_succ … HK10) -HK10 #I #Y #HY #H destruct
  39   lapply (drops_fwd_isid … HY ?) -HY // #H destruct
  40   /3 width=5 by fqu_drop, ex3_2_intro/
  41 ]
  42 qed-.
  43
  44 (* Properties with extended optional structural successor for closures ******)
  45
  46 lemma lfpx_fquq_trans: ∀h,b,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮[b] ⦃G2, L2, T2⦄ →
  47                        ∀K1. ⦃G1, K1⦄ ⊢ ⬈[h, T1] L1 →
  48                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ⬈[h] T & ⦃G1, K1, T⦄ ⊐⸮[b] ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ⬈[h, T2] L2.
  49 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #HKL1 cases H -H
  50 [ #H12 elim (lfpx_fqu_trans … H12 … HKL1) -L1 /3 width=5 by fqu_fquq, ex3_2_intro/
  51 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  52 ]
  53 qed-.