matita/matita/contribs/lambdadelta/basic_2/etc/ssta/ssta_lift.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/ldrop_ldrop.ma".
  16 include "basic_2/static/ssta.ma".
  17
  18 (* STRATIFIED STATIC TYPE ASSIGNMENT ON TERMS *******************************)
  19
  20 (* Properties on relocation *************************************************)
  21
  22 lemma ssta_lift: ∀h,g,G,L1,T1,U1,l. ⦃G, L1⦄ ⊢ T1 •[h, g] ⦃l, U1⦄ →
  23                  ∀L2,d,e. ⇩[d, e] L2 ≡ L1 → ∀T2. ⇧[d, e] T1 ≡ T2 →
  24                  ∀U2. ⇧[d, e] U1 ≡ U2 → ⦃G, L2⦄ ⊢ T2 •[h, g] ⦃l, U2⦄.
  25 #h #g #G #L1 #T1 #U1 #l #H elim H -G -L1 -T1 -U1 -l
  26 [ #G #L1 #k #l #Hkl #L2 #d #e #HL21 #X1 #H1 #X2 #H2
  27   >(lift_inv_sort1 … H1) -X1
  28   >(lift_inv_sort1 … H2) -X2 /2 width=1/
  29 | #G #L1 #K1 #V1 #W1 #W #i #l #HLK1 #_ #HW1 #IHVW1 #L2 #d #e #HL21 #X #H #U2 #HWU2
  30   elim (lift_inv_lref1 … H) * #Hid #H destruct
  31   [ elim (lift_trans_ge … HW1 … HWU2 ?) -W // #W2 #HW12 #HWU2
  32     elim (ldrop_trans_le … HL21 … HLK1 ?) -L1 /2 width=2/ #X #HLK2 #H
  33     elim (ldrop_inv_skip2 … H ?) -H /2 width=1/ -Hid #K2 #V2 #HK21 #HV12 #H destruct
  34     /3 width=8/
  35   | lapply (lift_trans_be … HW1 … HWU2 ? ?) -W // /2 width=1/ #HW1U2
  36     lapply (ldrop_trans_ge … HL21 … HLK1 ?) -L1 // -Hid /3 width=8/
  37   ]
  38 | #G #L1 #K1 #W1 #V1 #W #i #l #HLK1 #_ #HW1 #IHWV1 #L2 #d #e #HL21 #X #H #U2 #HWU2
  39   elim (lift_inv_lref1 … H) * #Hid #H destruct
  40   [ elim (lift_trans_ge … HW1 … HWU2 ?) -W // <minus_plus #W #HW1 #HWU2
  41     elim (ldrop_trans_le … HL21 … HLK1 ?) -L1 /2 width=2/ #X #HLK2 #H
  42     elim (ldrop_inv_skip2 … H ?) -H /2 width=1/ -Hid #K2 #W2 #HK21 #HW12 #H destruct
  43     lapply (lift_mono … HW1 … HW12) -HW1 #H destruct
  44     elim (lift_total V1 (d-i-1) e) /3 width=8/
  45   | lapply (lift_trans_be … HW1 … HWU2 ? ?) -W // /2 width=1/ #HW1U2
  46     lapply (ldrop_trans_ge … HL21 … HLK1 ?) -L1 // -Hid /3 width=8/
  47   ]
  48 | #a #I #G #L1 #V1 #T1 #U1 #l #_ #IHTU1 #L2 #d #e #HL21 #X1 #H1 #X2 #H2
  49   elim (lift_inv_bind1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H destruct
  50   elim (lift_inv_bind1 … H2) -H2 #X #U2 #H1 #HU12 #H2 destruct
  51   lapply (lift_mono … H1 … HV12) -H1 #H destruct /4 width=5/
  52 | #G #L1 #V1 #T1 #U1 #l #_ #IHTU1 #L2 #d #e #HL21 #X1 #H1 #X2 #H2
  53   elim (lift_inv_flat1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H destruct
  54   elim (lift_inv_flat1 … H2) -H2 #X #U2 #H1 #HU12 #H2 destruct
  55   lapply (lift_mono … H1 … HV12) -H1 #H destruct /4 width=5/
  56 | #G #L1 #W1 #T1 #U1 #l #_ #IHTU1 #L2 #d #e #HL21 #X #H #U2 #HU12
  57   elim (lift_inv_flat1 … H) -H #W2 #T2 #HW12 #HT12 #H destruct /3 width=5/
  58 ]
  59 qed.
  60
  61 lemma ssta_inv_lift1: ∀h,g,G,L2,T2,U2,l. ⦃G, L2⦄ ⊢ T2 •[h, g] ⦃l, U2⦄ →
  62                       ∀L1,d,e. ⇩[d, e] L2 ≡ L1 → ∀T1. ⇧[d, e] T1 ≡ T2 →
  63                       ∃∃U1. ⦃G, L1⦄ ⊢ T1 •[h, g] ⦃l, U1⦄ & ⇧[d, e] U1 ≡ U2.
  64 #h #g #G #L2 #T2 #U2 #l #H elim H -G -L2 -T2 -U2 -l
  65 [ #G #L2 #k #l #Hkl #L1 #d #e #_ #X #H
  66   >(lift_inv_sort2 … H) -X /3 width=3/
  67 | #G #L2 #K2 #V2 #W2 #W #i #l #HLK2 #HVW2 #HW2 #IHVW2 #L1 #d #e #HL21 #X #H
  68   elim (lift_inv_lref2 … H) * #Hid #H destruct [ -HVW2 | -IHVW2 ]
  69   [ elim (ldrop_conf_lt … HL21 … HLK2 ?) -L2 // #K1 #V1 #HLK1 #HK21 #HV12
  70     elim (IHVW2 … HK21 … HV12) -K2 -V2 #W1 #HVW1 #HW12
  71     elim (lift_trans_le … HW12 … HW2 ?) -W2 // >minus_plus <plus_minus_m_m // -Hid /3 width=6/
  72   | lapply (ldrop_conf_ge … HL21 … HLK2 ?) -L2 // #HL1K2
  73     elim (le_inv_plus_l … Hid) -Hid #Hdie #ei
  74     elim (lift_split … HW2 d (i-e+1) ? ? ?) -HW2 // [3: /2 width=1/ ]
  75     [ #W0 #HW20 <le_plus_minus_comm // >minus_minus_m_m /2 width=1/ /3 width=6/
  76     | <le_plus_minus_comm //
  77     ]
  78   ]
  79 | #G #L2 #K2 #W2 #V2 #W #i #l #HLK2 #HWV2 #HW2 #IHWV2 #L1 #d #e #HL21 #X #H
  80   elim (lift_inv_lref2 … H) * #Hid #H destruct [ -HWV2 | -IHWV2 ]
  81   [ elim (ldrop_conf_lt … HL21 … HLK2 ?) -L2 // #K1 #W1 #HLK1 #HK21 #HW12
  82     elim (IHWV2 … HK21 … HW12) -K2 #V1 #HWV1 #_
  83     elim (lift_trans_le … HW12 … HW2 ?) -W2 // >minus_plus <plus_minus_m_m // -Hid /3 width=6/
  84   | lapply (ldrop_conf_ge … HL21 … HLK2 ?) -L2 // #HL1K2
  85     elim (le_inv_plus_l … Hid) -Hid #Hdie #ei
  86     elim (lift_split … HW2 d (i-e+1) ? ? ?) -HW2 // [3: /2 width=1/ ]
  87     [ #W0 #HW20 <le_plus_minus_comm // >minus_minus_m_m /2 width=1/ /3 width=6/
  88     | <le_plus_minus_comm //
  89     ]
  90   ]
  91 | #a #I #G #L2 #V2 #T2 #U2 #l #_ #IHTU2 #L1 #d #e #HL21 #X #H
  92   elim (lift_inv_bind2 … H) -H #V1 #T1 #HV12 #HT12 #H destruct
  93   elim (IHTU2 (L1.ⓑ{I}V1) … HT12) -IHTU2 -HT12 /2 width=1/ -HL21 /3 width=5/
  94 | #G #L2 #V2 #T2 #U2 #l #_ #IHTU2 #L1 #d #e #HL21 #X #H
  95   elim (lift_inv_flat2 … H) -H #V1 #T1 #HV12 #HT12 #H destruct
  96   elim (IHTU2 … HL21 … HT12) -L2 -HT12 /3 width=5/
  97 | #G #L2 #W2 #T2 #U2 #l #_ #IHTU2 #L1 #d #e #HL21 #X #H
  98   elim (lift_inv_flat2 … H) -H #W1 #T1 #HW12 #HT12 #H destruct
  99   elim (IHTU2 … HL21 … HT12) -L2 -HT12 /3 width=3/
 100 ]
 101 qed-.
 102
 103 (* Advanced forvard lemmas **************************************************)
 104
 105 lemma ssta_fwd_correct: ∀h,g,G,L,T,U,l. ⦃G, L⦄ ⊢ T •[h, g] ⦃l, U⦄ →
 106                         ∃T0. ⦃G, L⦄ ⊢ U •[h, g] ⦃l-1, T0⦄.
 107 #h #g #G #L #T #U #l #H elim H -G -L -T -U -l
 108 [ /4 width=2/
 109 | #G #L #K #V #W #W0 #i #l #HLK #_ #HW0 * #V0 #HWV0
 110   lapply (ldrop_fwd_ldrop2 … HLK) -HLK #HLK
 111   elim (lift_total V0 0 (i+1)) /3 width=10/
 112 | #G #L #K #W #V #V0 #i #l #HLK #HWV #HWV0 #_
 113   lapply (ldrop_fwd_ldrop2 … HLK) -HLK #HLK
 114   elim (lift_total V 0 (i+1)) /3 width=10/
 115 | #a #I #G #L #V #T #U #l #_ * /3 width=2/
 116 | #G #L #V #T #U #l #_ * #T0 #HUT0 /3 width=2/
 117 | #G #L #W #T #U #l #_ * /2 width=2/
 118 ]
 119 qed-.