matita/matita/contribs/lambdadelta/basic_2/reducibility/fpr_cpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reducibility/cfpr_cpr.ma".
  16
  17 (* CONTEXT-FREE PARALLEL REDUCTION ON CLOSURES ******************************)
  18
  19 (* Properties on context-sensitive parallel reduction for terms *************)
  20
  21 lemma cpr_fpr: ∀L,T1,T2. L ⊢ T1 ➡ T2 → ⦃L, T1⦄ ➡ ⦃L, T2⦄.
  22 /2 width=4/ qed.
  23
  24 (* Advanced properties ******************************************************)
  25
  26 lemma fpr_bind_sn: ∀L1,L2,V1,V2. ⦃L1, V1⦄ ➡ ⦃L2, V2⦄ → ∀T1,T2. T1 ➡ T2 →
  27                    ∀a,I. ⦃L1, ⓑ{a,I}V1.T1⦄ ➡ ⦃L2, ⓑ{a,I}V2.T2⦄.
  28 #L1 #L2 #V1 #V2 #H #T1 #T2 #HT12 #a #I
  29 elim (fpr_inv_all … H) /3 width=4/
  30 qed.
  31
  32 (* Advanced forward lemmas **************************************************)
  33
  34 lemma fpr_fwd_bind2_minus: ∀I,L1,L,V1,T1,T. ⦃L1, -ⓑ{I}V1.T1⦄ ➡ ⦃L, T⦄ → ∀b.
  35                            ∃∃V2,T2. ⦃L1, ⓑ{b,I}V1.T1⦄ ➡ ⦃L, ⓑ{b,I}V2.T2⦄ &
  36                                     T = -ⓑ{I}V2.T2.
  37 #I #L1 #L #V1 #T1 #T #H1 #b
  38 elim (fpr_inv_all … H1) -H1 #L0 #HL10 #HT1 #HL0
  39 elim (cpr_fwd_bind1_minus … HT1 b) -HT1 /3 width=4/
  40 qed-.
  41
  42 lemma fpr_fwd_shift_bind_minus: ∀I1,I2,L1,L2,V1,V2,T1,T2.
  43                                 ⦃L1, -ⓑ{I1}V1.T1⦄ ➡ ⦃L2, -ⓑ{I2}V2.T2⦄ →
  44                                 ⦃L1, V1⦄ ➡ ⦃L2, V2⦄ ∧ I1 = I2.
  45 * #I2 #L1 #L2 #V1 #V2 #T1 #T2 #H
  46 elim (fpr_inv_all … H) -H #L #HL1 #H #HL2
  47 [ elim (cpr_inv_abbr1 … H) -H *
  48   [ #V #V0 #T #HV1 #HV0 #_ #H destruct /4 width=4/
  49   | #T #_ #_ #H destruct
  50   ]
  51 | elim (cpr_inv_abst1 … H Abst V2) -H
  52   #V #T #HV1 #_ #H destruct /3 width=4/
  53 ]
  54 qed-.
  55
  56 (* Advanced inversion lemmas ************************************************)
  57
  58 lemma fpr_inv_pair1: ∀I,K1,L2,V1,T1,T2. ⦃K1.ⓑ{I}V1, T1⦄ ➡ ⦃L2, T2⦄ →
  59                      ∃∃K2,V2. ⦃K1, V1⦄  ➡ ⦃K2, V2⦄ &
  60                               ⦃K1, -ⓑ{I}V1.T1⦄ ➡ ⦃K2, -ⓑ{I}V2.T2⦄ &
  61                               L2 = K2.ⓑ{I}V2.
  62 #I1 #K1 #X #V1 #T1 #T2 #H
  63 elim (fpr_fwd_pair1 … H) -H #I2 #K2 #V2 #HT12 #H destruct
  64 elim (fpr_fwd_shift_bind_minus … HT12) #HV12 #H destruct /2 width=5/
  65 qed-.
  66
  67 lemma fpr_inv_pair3: ∀I,L1,K2,V2,T1,T2. ⦃L1, T1⦄ ➡ ⦃K2.ⓑ{I}V2, T2⦄ →
  68                      ∃∃K1,V1. ⦃K1, V1⦄  ➡ ⦃K2, V2⦄ &
  69                               ⦃K1, -ⓑ{I}V1.T1⦄ ➡ ⦃K2, -ⓑ{I}V2.T2⦄ &
  70                               L1 = K1.ⓑ{I}V1.
  71 #I2 #X #K2 #V2 #T1 #T2 #H
  72 elim (fpr_fwd_pair3 … H) -H #I1 #K1 #V1 #HT12 #H destruct
  73 elim (fpr_fwd_shift_bind_minus … HT12) #HV12 #H destruct /2 width=5/
  74 qed-.
  75
  76 (* More advanced forward lemmas *********************************************)
  77
  78 lemma fpr_fwd_pair1_full: ∀I,K1,L2,V1,T1,T2. ⦃K1.ⓑ{I}V1, T1⦄ ➡ ⦃L2, T2⦄ →
  79                           ∀b. ∃∃K2,V2. ⦃K1, V1⦄  ➡ ⦃K2, V2⦄ &
  80                                        ⦃K1, ⓑ{b,I}V1.T1⦄ ➡ ⦃K2, ⓑ{b,I}V2.T2⦄ &
  81                                        L2 = K2.ⓑ{I}V2.
  82 #I #K1 #L2 #V1 #T1 #T2 #H #b
  83 elim (fpr_inv_pair1 … H) -H #K2 #V2 #HV12 #HT12 #H destruct
  84 elim (fpr_fwd_bind2_minus … HT12 b) -HT12 #W1 #U1 #HTU1 #H destruct /2 width=5/
  85 qed-.