matita/matita/contribs/lambdadelta/basic_2/reduction/cpx_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lleq_leq.ma".
  16 include "basic_2/relocation/lleq_ldrop.ma".
  17 include "basic_2/reduction/cpx.ma".
  18
  19 (* CONTEXT-SENSITIVE EXTENDED PARALLEL REDUCTION FOR TERMS ******************)
  20
  21 (* Properties on lazy equivalence for local environments ********************)
  22
  23 lemma lleq_cpx_trans: ∀h,g,G,L2,T1,T2. ⦃G, L2⦄ ⊢ T1 ➡[h, g] T2 →
  24                       ∀L1. L1 ⋕[T1, 0] L2 → ⦃G, L1⦄ ⊢ T1 ➡[h, g] T2.
  25 #h #g #G #L2 #T1 #T2 #H elim H -G -L2 -T1 -T2 /2 width=2 by cpx_sort/
  26 [ #I #G #L2 #K2 #V1 #V2 #W2 #i #HLK2 #_ #HVW2 #IHV12 #L1 #H elim (lleq_fwd_lref_dx … H … HLK2) -L2
  27   [ #H elim (ylt_yle_false … H) //
  28   | * /3 width=7 by cpx_delta/
  29   ]
  30 | #a #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #H elim (lleq_inv_bind_O … H) -H
  31   /3 width=1 by cpx_bind/
  32 | #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  33   /3 width=1 by cpx_flat/
  34 | #G #L2 #V2 #T1 #T #T2 #_ #HT2 #IHT1 #L1 #H elim (lleq_inv_bind_O … H) -H
  35   /3 width=3 by cpx_zeta/
  36 | #G #L2 #W1 #T1 #T2 #_ #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  37   /3 width=1 by cpx_tau/
  38 | #G #L2 #W1 #W2 #T1 #_ #IHW12 #L1 #H elim (lleq_inv_flat … H) -H
  39   /3 width=1 by cpx_ti/
  40 | #a #G #L1 #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  41   #HV1 #H elim (lleq_inv_bind_O … H) -H /3 width=1 by cpx_beta/
  42 | #a #G #L1 #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  43   #HV1 #H elim (lleq_inv_bind_O … H) -H /3 width=3 by cpx_theta/
  44 ]
  45 qed-.
  46
  47 (* Note: lemma 1000 *)
  48 lemma lleq_cpx_conf_dx: ∀h,g,G,L2,T1,T2. ⦃G, L2⦄ ⊢ T1 ➡[h, g] T2 →
  49                         ∀L1. L1 ⋕[T1, 0] L2 → L1 ⋕[T2, 0] L2.
  50 #h #g #G #L2 #T1 #T2 #H elim H -G -L2 -T1 -T2
  51 [ //
  52 | /3 width=3 by lleq_fwd_length, lleq_sort/
  53 | #I #G #L2 #K2 #V1 #V2 #W2 #i #HLK2 #_ #HVW2 #IHV12 #L1 #H elim (lleq_inv_lref_ge_dx … H … HLK2) // -H
  54   #K1 #HLK1 #HV1
  55   lapply (ldrop_fwd_drop2 … HLK1) -HLK1 #HLK1
  56   lapply (ldrop_fwd_drop2 … HLK2) -HLK2 #HLK2
  57   @(lleq_lift_le … HLK1 HLK2 … HVW2) -HLK1 -HLK2 -HVW2 /2 width=1 by/ (**) (* full auto too slow *)
  58 | #a #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #H elim (lleq_inv_bind_O … H) -H
  59   /4 width=5 by lleq_bind_repl_SO, lleq_bind/
  60 | #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  61   /3 width=1 by lleq_flat/
  62 | #G #L2 #V #T1 #T2 #T #_ #HT2 #IHT12 #L1 #H elim (lleq_inv_bind_O … H) -H
  63   /3 width=10 by lleq_inv_lift_le, ldrop_drop/
  64 | #G #L2 #V #T1 #T2 #_ #IHT12 #L1 #H elim (lleq_inv_flat … H) -H /2 width=1 by/
  65 | #G #L2 #V1 #V2 #T #_ #IHV12 #L1 #H elim (lleq_inv_flat … H) -H /2 width=1 by/
  66 | #a #G #L2 #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  67   #HV1 #H elim (lleq_inv_bind_O … H) -H
  68   /4 width=5 by lleq_bind_repl_SO, lleq_flat, lleq_bind/
  69 | #a #G #L2 #V1 #V2 #V #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV12 #IHW12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  70   #HV1 #H elim (lleq_inv_bind_O … H) -H
  71   #HW1 #HT1 @lleq_bind_O /2 width=1 by/ @lleq_flat (**) (* full auto too slow *)
  72   [ /3 width=10 by lleq_lift_le, ldrop_drop/
  73   | /3 width=3 by lleq_bind_repl_O/
  74 ]
  75 qed-.
  76
  77 lemma lleq_cpx_conf_sn: ∀h,g,G,L1,T1,T2. ⦃G, L1⦄ ⊢ T1 ➡[h, g] T2 →
  78                         ∀L2. L1 ⋕[T1, 0] L2 → L1 ⋕[T2, 0] L2.
  79 /4 width=6 by lleq_cpx_conf_dx, lleq_sym/ qed-.