matita/matita/contribs/lambdadelta/basic_2/reduction/fpbc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredproper_8.ma".
  16 include "basic_2/relocation/fquq_alt.ma".
  17 include "basic_2/reduction/fpb.ma".
  18
  19 (* "BIG TREE" PROPER PARALLEL REDUCTION FOR CLOSURES ************************)
  20
  21 inductive fpbc (h) (g) (G1) (L1) (T1): relation3 genv lenv term ≝
  22 | fpbc_fqu: ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ → fpbc h g G1 L1 T1 G2 L2 T2
  23 | fpbc_cpx: ∀T2. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] T2 → (T1 = T2 → ⊥) → fpbc h g G1 L1 T1 G1 L1 T2
  24 .
  25
  26 interpretation
  27    "'big tree' proper parallel reduction (closure)"
  28    'BTPRedProper h g G1 L1 T1 G2 L2 T2 = (fpbc h g G1 L1 T1 G2 L2 T2).
  29
  30 (* Basic properties *********************************************************)
  31
  32 lemma cpr_fpbc: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → (T1 = T2 → ⊥) →
  33                 ⦃G, L, T1⦄ ≻[h, g] ⦃G, L, T2⦄.
  34 /3 width=1 by fpbc_cpx, cpr_cpx/ qed.
  35
  36 lemma fpb_fpbc_or_refl: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≽[h, g] ⦃G2, L2, T2⦄ →
  37                         ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ ∨
  38                         ∧∧ G1 = G2 & ⦃G1, L1⦄ ⊢ ➡[h, g] L2 & T1 = T2.
  39 #h #g #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  40 /3 width=1 by and3_intro, or_intror/
  41 [ #G2 #L2 #T2 #H elim (fquq_inv_gen … H) -H [| * ]
  42   /3 width=1 by fpbc_fqu, and3_intro, or_introl, or_intror/
  43 | #T2 #HT12 elim (term_eq_dec T1 T2) #H destruct
  44   /4 width=1 by and3_intro, or_introl, or_intror, fpbc_cpx/
  45 ]
  46 qed-.
  47
  48 lemma fpb_fpbc: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≽[h, g] ⦃G2, L2, T2⦄ →
  49                 (|G1| = |G2| → |L1| = |L2| → T1 = T2 → ⊥) →
  50                 ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄.
  51 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #H0 elim (fpb_fpbc_or_refl … H) -H // *
  52 #HG #HL #HT destruct lapply (lpx_fwd_length … HL) -HL #HL
  53 elim H0 -H0 //
  54 qed.
  55
  56 (* Basic forward lemmas *****************************************************)
  57
  58 lemma fpbc_fwd_fpb: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  59                     ⦃G1, L1, T1⦄ ≽[h, g] ⦃G2, L2, T2⦄.
  60 #h #g #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  61 /3 width=1 by fpb_fquq, fpb_cpx, fqu_fquq/
  62 qed-.
  63
  64 lemma fpbc_fwd_gen: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  65                     |G1| = |G2| → |L1| = |L2| → T1 = T2 → ⊥.
  66 #h #g #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2 /2 width=1 by /
  67 #G2 #L2 #T2 #H #HG #HL #HT @(fqu_fwd_gen … H) -H // (**) (* auto does not work *)
  68 qed-.