matita/matita/contribs/lambdadelta/basic_2/reduction/lpr_cpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/fsup.ma".
  16 include "basic_2/reduction/lpr_ldrop.ma".
  17
  18 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  19
  20 (* Main properties on context-sensitive parallel reduction for terms ********)
  21
  22 fact cpr_conf_lpr_atom_atom:
  23    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ➡ T & L2 ⊢ ⓪{I} ➡ T.
  24 /2 width=3/ qed-.
  25
  26 fact cpr_conf_lpr_atom_delta:
  27    ∀L0,i. (
  28       ∀L,T.♯{L, T} < ♯{L0, #i} →
  29       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
  30       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
  31       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
  32    ) →
  33    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  34    ∀V2. K0 ⊢ V0 ➡ V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  35    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
  36    ∃∃T. L1 ⊢ #i ➡ T & L2 ⊢ T2 ➡ T.
  37 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  38 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  39 elim (lpr_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  40 elim (lpr_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  41 elim (lpr_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  42 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  43 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  44 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  45 elim (lift_total V 0 (i+1)) #T #HVT
  46 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  47 qed-.
  48
  49 (* Basic_1: includes: pr0_delta_delta pr2_delta_delta *)
  50 fact cpr_conf_lpr_delta_delta:
  51    ∀L0,i. (
  52       ∀L,T.♯{L, T} < ♯{L0, #i} →
  53       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
  54       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
  55       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
  56    ) →
  57    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  58    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  59    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  60    ∀V2. KX ⊢ VX ➡ V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  61    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
  62    ∃∃T. L1 ⊢ T1 ➡ T & L2 ⊢ T2 ➡ T.
  63 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  64 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  65 lapply (ldrop_mono … H … HLK0) -H #H destruct
  66 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  67 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  68 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  69 elim (lpr_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  70 elim (lpr_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  71 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  72 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  73 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  74 elim (lift_total V 0 (i+1)) #T #HVT
  75 lapply (cpr_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  76 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  77 qed-.
  78
  79 fact cpr_conf_lpr_bind_bind:
  80    ∀a,I,L0,V0,T0. (
  81       ∀L,T.♯{L,T} < ♯{L0,ⓑ{a,I}V0.T0} →
  82       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
  83       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
  84       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
  85    ) →
  86    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➡ T1 →
  87    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ➡ T2 →
  88    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
  89    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ➡ T & L2 ⊢ ⓑ{a,I}V2.T2 ➡ T.
  90 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  91 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  92 elim (IH … HV01 … HV02 … HL01 … HL02) //
  93 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  94 qed-.
  95
  96 fact cpr_conf_lpr_bind_zeta:
  97    ∀L0,V0,T0. (
  98       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
  99       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 100       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 101       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 102    ) →
 103    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓓV0 ⊢ T0 ➡ T1 →
 104    ∀T2. L0.ⓓV0 ⊢ T0 ➡ T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 105    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 106    ∃∃T. L1 ⊢ +ⓓV1.T1 ➡ T & L2 ⊢ X2 ➡ T.
 107 #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 108 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 109 elim (IH … HT01 … HT02 (L1.ⓓV1) … (L2.ⓓV1)) -IH -HT01 -HT02 // /2 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 110 elim (cpr_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ /3 width=3/
 111 qed-.
 112
 113 fact cpr_conf_lpr_zeta_zeta:
 114    ∀L0,V0,T0. (
 115       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
 116       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 117       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 118       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 119    ) →
 120    ∀T1. L0.ⓓV0 ⊢ T0 ➡ T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 121    ∀T2. L0.ⓓV0 ⊢ T0 ➡ T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 122    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 123    ∃∃T. L1 ⊢ X1 ➡ T & L2 ⊢ X2 ➡ T.
 124 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 125 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 126 elim (IH … HT01 … HT02 (L1.ⓓV0) … (L2.ⓓV0)) -IH -HT01 -HT02 // /2 width=1/ -L0 -T0 #T #HT1 #HT2
 127 elim (cpr_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ #T1 #HT1 #HXT1
 128 elim (cpr_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ #T2 #HT2 #HXT2
 129 lapply (lift_inj … HT2 … HT1) -T #H destruct /2 width=3/
 130 qed-.
 131
 132 fact cpr_conf_lpr_flat_flat:
 133    ∀I,L0,V0,T0. (
 134       ∀L,T.♯{L,T} < ♯{L0,ⓕ{I}V0.T0} →
 135       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 136       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 137       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 138    ) →
 139    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ T0 ➡ T1 →
 140    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0 ⊢ T0 ➡ T2 →
 141    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 142    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ➡ T & L2 ⊢ ⓕ{I}V2.T2 ➡ T.
 143 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 144 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 145 elim (IH … HV01 … HV02 … HL01 … HL02) //
 146 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 147 qed-.
 148
 149 fact cpr_conf_lpr_flat_tau:
 150    ∀L0,V0,T0. (
 151       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 152       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 153       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 154       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 155    ) →
 156    ∀V1,T1. L0 ⊢ T0 ➡ T1 → ∀T2. L0 ⊢ T0 ➡ T2 →
 157    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 158    ∃∃T. L1 ⊢ ⓝV1.T1 ➡ T & L2 ⊢ T2 ➡ T.
 159 #L0 #V0 #T0 #IH #V1 #T1 #HT01
 160 #T2 #HT02 #L1 #HL01 #L2 #HL02
 161 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 162 qed-.
 163
 164 fact cpr_conf_lpr_tau_tau:
 165    ∀L0,V0,T0. (
 166       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 167       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 168       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 169       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 170    ) →
 171    ∀T1. L0 ⊢ T0 ➡ T1 → ∀T2. L0 ⊢ T0 ➡ T2 →
 172    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 173    ∃∃T. L1 ⊢ T1 ➡ T & L2 ⊢ T2 ➡ T.
 174 #L0 #V0 #T0 #IH #T1 #HT01
 175 #T2 #HT02 #L1 #HL01 #L2 #HL02
 176 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /2 width=3/
 177 qed-.
 178
 179 fact cpr_conf_lpr_flat_beta:
 180    ∀a,L0,V0,W0,T0. (
 181       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓛ{a}W0.T0} →
 182       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 183       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 184       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 185    ) →
 186    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ ⓛ{a}W0.T0 ➡ T1 →
 187    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0.ⓛW0 ⊢ T0 ➡ T2 →
 188    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 189    ∃∃T. L1 ⊢ ⓐV1.T1 ➡ T & L2 ⊢ ⓓ{a}V2.T2 ➡ T.
 190 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #X #H
 191 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 192 elim (cpr_inv_abst1 … H) -H #W1 #T1 #HW01 #HT01 #H destruct
 193 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 194 elim (IH … HT01 … HT02 (L1.ⓛW1) … (L2.ⓛW1)) /2 width=1/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 195 lapply (cpr_lsubr_trans … HT2 (L2.ⓓV2) ?) -HT2 /2 width=1/ /3 width=5/
 196 qed-.
 197
 198 (* Basic-1: includes:
 199             pr0_cong_upsilon_refl pr0_cong_upsilon_zeta
 200             pr0_cong_upsilon_cong pr0_cong_upsilon_delta
 201 *)
 202 fact cpr_conf_lpr_flat_theta:
 203    ∀a,L0,V0,W0,T0. (
 204       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓓ{a}W0.T0} →
 205       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 206       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 207       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 208    ) →
 209    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ ⓓ{a}W0.T0 ➡ T1 →
 210    ∀V2. L0 ⊢ V0 ➡ V2 → ∀U2. ⇧[O, 1] V2 ≡ U2 →
 211    ∀W2. L0 ⊢ W0 ➡ W2 → ∀T2. L0.ⓓW0 ⊢ T0 ➡ T2 →
 212    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 213    ∃∃T. L1 ⊢ ⓐV1.T1 ➡ T & L2 ⊢ ⓓ{a}W2.ⓐU2.T2 ➡ T.
 214 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #X #H
 215 #V2 #HV02 #U2 #HVU2 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 216 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 217 elim (lift_total V 0 1) #U #HVU
 218 lapply (cpr_lift … HV2 (L2.ⓓW2) … HVU2 … HVU) -HVU2 /2 width=1/ #HU2
 219 elim (cpr_inv_abbr1 … H) -H *
 220 [ #W1 #T1 #HW01 #HT01 #H destruct
 221   elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1/
 222   elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0 /4 width=7/
 223 | #T1 #HT01 #HXT1 #H destruct
 224   elim (IH … HT01 … HT02 (L1.ⓓW2) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 225   elim (cpr_inv_lift1 … HT1 L1 … HXT1) -HXT1 /2 width=1/ #Y #HYT #HXY
 226   @(ex2_intro … (ⓐV.Y)) /2 width=1/ /3 width=5/ (**) (* auto /4 width=9/ is too slow *)
 227 ]
 228 qed-.
 229
 230 fact cpr_conf_lpr_beta_beta:
 231    ∀a,L0,V0,W0,T0. (
 232       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓛ{a}W0.T0} →
 233       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 234       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 235       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 236    ) →
 237    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓛW0 ⊢ T0 ➡ T1 →
 238    ∀V2. L0 ⊢ V0 ➡ V2 → ∀T2. L0.ⓛW0 ⊢ T0 ➡ T2 →
 239    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 240    ∃∃T. L1 ⊢ ⓓ{a}V1.T1 ➡ T & L2 ⊢ ⓓ{a}V2.T2 ➡ T.
 241 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #T1 #HT01
 242 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 243 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 244 elim (IH … HT01 … HT02 (L1.ⓛW0) … (L2.ⓛW0)) /2 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 245 lapply (cpr_lsubr_trans … HT1 (L1.ⓓV1) ?) -HT1 /2 width=1/
 246 lapply (cpr_lsubr_trans … HT2 (L2.ⓓV2) ?) -HT2 /2 width=1/ /3 width=5/
 247 qed-.
 248
 249 (* Basic_1: was: pr0_upsilon_upsilon *)
 250 fact cpr_conf_lpr_theta_theta:
 251    ∀a,L0,V0,W0,T0. (
 252       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓓ{a}W0.T0} →
 253       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ➡ T2 →
 254       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ➡ L2 →
 255       ∃∃T0. L1 ⊢ T1 ➡ T0 & L2 ⊢ T2 ➡ T0
 256    ) →
 257    ∀V1. L0 ⊢ V0 ➡ V1 → ∀U1. ⇧[O, 1] V1 ≡ U1 →
 258    ∀W1. L0 ⊢ W0 ➡ W1 → ∀T1. L0.ⓓW0 ⊢ T0 ➡ T1 →
 259    ∀V2. L0 ⊢ V0 ➡ V2 → ∀U2. ⇧[O, 1] V2 ≡ U2 →
 260    ∀W2. L0 ⊢ W0 ➡ W2 → ∀T2. L0.ⓓW0 ⊢ T0 ➡ T2 →
 261    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ➡ L2 →
 262    ∃∃T. L1 ⊢ ⓓ{a}W1.ⓐU1.T1 ➡ T & L2 ⊢ ⓓ{a}W2.ⓐU2.T2 ➡ T.
 263 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #U1 #HVU1 #W1 #HW01 #T1 #HT01
 264 #V2 #HV02 #U2 #HVU2 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 265 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 266 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1/
 267 elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0
 268 elim (lift_total V 0 1) #U #HVU
 269 lapply (cpr_lift … HV1 (L1.ⓓW1) … HVU1 … HVU) -HVU1 /2 width=1/
 270 lapply (cpr_lift … HV2 (L2.ⓓW2) … HVU2 … HVU) -HVU2 /2 width=1/ /4 width=7/
 271 qed-.
 272
 273 theorem cpr_conf_lpr: lpx_sn_confluent cpr cpr.
 274 #L0 #T0 @(f2_ind … fw … L0 T0) -L0 -T0 #n #IH #L0 * [|*]
 275 [ #I0 #Hn #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 276   elim (cpr_inv_atom1 … H1) -H1
 277   elim (cpr_inv_atom1 … H2) -H2
 278   [ #H2 #H1 destruct
 279     /2 width=1 by cpr_conf_lpr_atom_atom/
 280   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 281     /3 width=10 by cpr_conf_lpr_atom_delta/
 282   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 283     /4 width=10 by ex2_commute, cpr_conf_lpr_atom_delta/
 284   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 285     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 286     /3 width=17 by cpr_conf_lpr_delta_delta/
 287   ]
 288 | #a #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 289   elim (cpr_inv_bind1 … H1) -H1 *
 290   [ #V1 #T1 #HV01 #HT01 #H1
 291   | #T1 #HT01 #HXT1 #H11 #H12
 292   ]
 293   elim (cpr_inv_bind1 … H2) -H2 *
 294   [1,3: #V2 #T2 #HV02 #HT02 #H2
 295   |2,4: #T2 #HT02 #HXT2 #H21 #H22
 296   ] destruct
 297   [ /3 width=10 by cpr_conf_lpr_bind_bind/
 298   | /4 width=11 by ex2_commute, cpr_conf_lpr_bind_zeta/
 299   | /3 width=11 by cpr_conf_lpr_bind_zeta/
 300   | /3 width=12 by cpr_conf_lpr_zeta_zeta/
 301   ]
 302 | #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 303   elim (cpr_inv_flat1 … H1) -H1 *
 304   [ #V1 #T1 #HV01 #HT01 #H1
 305   | #HX1 #H1
 306   | #a1 #V1 #Y1 #Z1 #T1 #HV01 #HZT1 #H11 #H12 #H13
 307   | #a1 #V1 #U1 #Y1 #W1 #Z1 #T1 #HV01 #HVU1 #HYW1 #HZT1 #H11 #H12 #H13
 308   ]
 309   elim (cpr_inv_flat1 … H2) -H2 *
 310   [1,5,9,13: #V2 #T2 #HV02 #HT02 #H2
 311   |2,6,10,14: #HX2 #H2
 312   |3,7,11,15: #a2 #V2 #Y2 #Z2 #T2 #HV02 #HZT2 #H21 #H22 #H23
 313   |4,8,12,16: #a2 #V2 #U2 #Y2 #W2 #Z2 #T2 #HV02 #HVU2 #HYW2 #HZT2 #H21 #H22 #H23
 314   ] destruct
 315   [ /3 width=10 by cpr_conf_lpr_flat_flat/
 316   | /4 width=8 by ex2_commute, cpr_conf_lpr_flat_tau/
 317   | /4 width=11 by ex2_commute, cpr_conf_lpr_flat_beta/
 318   | /4 width=14 by ex2_commute, cpr_conf_lpr_flat_theta/
 319   | /3 width=8 by cpr_conf_lpr_flat_tau/
 320   | /3 width=7 by cpr_conf_lpr_tau_tau/
 321   | /3 width=11 by cpr_conf_lpr_flat_beta/
 322   | /3 width=11 by cpr_conf_lpr_beta_beta/
 323   | /3 width=14 by cpr_conf_lpr_flat_theta/
 324   | /3 width=17 by cpr_conf_lpr_theta_theta/
 325   ]
 326 ]
 327 qed-.
 328
 329 (* Basic_1: includes: pr0_confluence pr2_confluence *)
 330 theorem cpr_conf: ∀L. confluent … (cpr L).
 331 /2 width=6 by cpr_conf_lpr/ qed-.
 332
 333 (* Properties on context-sensitive parallel reduction for terms *************)
 334
 335 lemma lpr_cpr_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ➡ L1 →
 336                        ∃∃T. L1 ⊢ T0 ➡ T & L1 ⊢ T1 ➡ T.
 337 #L0 #T0 #T1 #HT01 #L1 #HL01
 338 elim (cpr_conf_lpr … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 339 qed-.
 340
 341 lemma lpr_cpr_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ➡ L1 →
 342                        ∃∃T. L1 ⊢ T0 ➡ T & L0 ⊢ T1 ➡ T.
 343 #L0 #T0 #T1 #HT01 #L1 #HL01
 344 elim (cpr_conf_lpr … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 345 qed-.
 346
 347 lemma fsup_cpr_trans: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ∀U2. L2 ⊢ T2 ➡ U2 →
 348                       ∃∃L,U1. L1 ⊢ ➡ L & L ⊢ T1 ➡ U1 & ⦃L, U1⦄ ⊃ ⦃L2, U2⦄.
 349 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 [1,2,3,4,5: /3 width=5/ ]
 350 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #U2 #HTU2
 351 elim (IHT12 … HTU2) -IHT12 -HTU2 #K #T #HK1 #HT1 #HT2
 352 elim (lift_total T d e) #U #HTU
 353 elim (ldrop_lpr_trans … HLK1 … HK1) -HLK1 -HK1 #L2 #HL12 #HL2K
 354 lapply (cpr_lift … HT1 … HL2K … HTU1 … HTU) -HT1 -HTU1 /3 width=11/
 355 qed-.