matita/matita/contribs/lambdadelta/basic_2/reduction/lpr_cpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lpx_sn_lpx_sn.ma".
  16 include "basic_2/substitution/lpss_ldrop.ma".
  17 include "basic_2/reduction/lpr_ldrop.ma".
  18
  19 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  20
  21 (* Properties on context-sensitive parallel substitution for terms **********)
  22
  23 fact cpr_cpss_conf_lpr_lpss_atom_atom:
  24    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ▶* T & L2 ⊢ ⓪{I} ➡ T.
  25 /2 width=3/ qed-.
  26
  27 fact cpr_cpss_conf_lpr_lpss_atom_delta:
  28    ∀L0,i. (
  29       ∀L,T.♯{L, T} < ♯{L0, #i} →
  30       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  31       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  32       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  33    ) →
  34    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  35    ∀V2. K0 ⊢ V0 ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  36    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  37    ∃∃T. L1 ⊢ #i ▶* T & L2 ⊢ T2 ➡ T.
  38 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  39 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  40 elim (lpr_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  41 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  42 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  43 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  44 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  45 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  46 elim (lift_total V 0 (i+1)) #T #HVT
  47 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  48 qed-.
  49
  50 fact cpr_cpss_conf_lpr_lpss_delta_atom:
  51    ∀L0,i. (
  52       ∀L,T.♯{L, T} < ♯{L0, #i} →
  53       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  54       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  55       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  56    ) →
  57    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  58    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  59    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  60    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ #i ➡ T.
  61 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1 #L1 #HL01 #L2 #HL02
  62 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  63 elim (lpss_inv_pair1 … H2) -H2 #K2 #V2 #HK02 #HV02 #H destruct
  64 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  65 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  66 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  67 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  68 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  69 elim (lift_total V 0 (i+1)) #T #HVT
  70 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1 /3 width=9/
  71 qed-.
  72
  73 fact cpr_cpss_conf_lpr_lpss_delta_delta:
  74    ∀L0,i. (
  75       ∀L,T.♯{L, T} < ♯{L0, #i} →
  76       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  77       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  78       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  79    ) →
  80    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  81    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  82    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  83    ∀V2. KX ⊢ VX ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  84    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  85    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ T2 ➡ T.
  86 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  87 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  88 lapply (ldrop_mono … H … HLK0) -H #H destruct
  89 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  90 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  91 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  92 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  93 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  94 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  95 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  96 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  97 elim (lift_total V 0 (i+1)) #T #HVT
  98 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  99 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
 100 qed-.
 101
 102 fact cpr_cpss_conf_lpr_lpss_bind_bind:
 103    ∀a,I,L0,V0,T0. (
 104       ∀L,T.♯{L,T} < ♯{L0,ⓑ{a,I}V0.T0} →
 105       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 106       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 107       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 108    ) →
 109    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➡ T1 →
 110    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ▶* T2 →
 111    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 112    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ▶* T & L2 ⊢ ⓑ{a,I}V2.T2 ➡ T.
 113 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 114 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 115 elim (IH … HV01 … HV02 … HL01 … HL02) //
 116 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
 117 qed-.
 118
 119 fact cpr_cpss_conf_lpr_lpss_bind_zeta:
 120    ∀L0,V0,T0. (
 121       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
 122       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 123       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 124       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 125    ) →
 126    ∀T1. L0.ⓓV0 ⊢ T0 ➡ T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 127    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓓV0 ⊢ T0 ▶* T2 →
 128    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 129    ∃∃T. L1 ⊢ X1 ▶* T & L2 ⊢ +ⓓV2.T2 ➡ T.
 130 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 131 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 132 elim (IH … HT01 … HT02 (L1.ⓓV2) … (L2.ⓓV2)) -IH -HT01 -HT02 // /2 width=1/ /3 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 133 elim (cpss_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ /3 width=9/
 134 qed-.
 135
 136 fact cpr_cpss_conf_lpr_lpss_flat_flat:
 137    ∀I,L0,V0,T0. (
 138       ∀L,T.♯{L,T} < ♯{L0,ⓕ{I}V0.T0} →
 139       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 140       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 141       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 142    ) →
 143    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ T0 ➡ T1 →
 144    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ T0 ▶* T2 →
 145    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 146    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ▶* T & L2 ⊢ ⓕ{I}V2.T2 ➡ T.
 147 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 148 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 149 elim (IH … HV01 … HV02 … HL01 … HL02) //
 150 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 151 qed-.
 152
 153 fact cpr_cpss_conf_lpr_lpss_flat_tau:
 154    ∀L0,V0,T0. (
 155       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 156       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 157       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 158       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 159    ) →
 160    ∀T1. L0 ⊢ T0 ➡ T1 → ∀V2,T2. L0 ⊢ T0 ▶* T2 →
 161    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 162    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ ⓝV2.T2 ➡ T.
 163 #L0 #V0 #T0 #IH #T1 #HT01
 164 #V2 #T2 #HT02 #L1 #HL01 #L2 #HL02
 165 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 166 qed-.
 167
 168 fact cpr_cpss_conf_lpr_lpss_flat_beta:
 169    ∀a,L0,V0,W0,T0. (
 170       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓛ{a}W0.T0} →
 171       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 172       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 173       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 174    ) →
 175    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓛW0 ⊢ T0 ➡ T1 →
 176    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ ⓛ{a}W0.T0 ▶* T2 →
 177    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 178    ∃∃T. L1 ⊢ ⓓ{a}V1.T1 ▶* T & L2 ⊢ ⓐV2.T2 ➡ T.
 179 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #T1 #HT01
 180 #V2 #HV02 #X #H #L1 #HL01 #L2 #HL02
 181 elim (cpss_inv_bind1 … H) -H #W2 #T2 #HW02 #HT02 #H destruct
 182 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 183 elim (IH … HT01 … HT02 (L1.ⓛW2) … (L2.ⓛW2)) /2 width=1/ /3 width=1/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 184 lapply (cpss_lsubr_trans … HT1 (L1.ⓓV1) ?) -HT1 /2 width=1/ /3 width=5/
 185 qed-.
 186
 187 fact cpr_cpss_conf_lpr_lpss_flat_theta:
 188    ∀a,L0,V0,W0,T0. (
 189       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓓ{a}W0.T0} →
 190       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 191       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 192       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 193    ) →
 194    ∀V1. L0 ⊢ V0 ➡ V1 → ∀U1. ⇧[O, 1] V1 ≡ U1 →
 195    ∀W1. L0 ⊢ W0 ➡ W1 → ∀T1. L0.ⓓW0 ⊢ T0 ➡ T1 →
 196    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ ⓓ{a}W0.T0 ▶* T2 →
 197    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 198    ∃∃T. L1 ⊢ ⓓ{a}W1.ⓐU1.T1 ▶* T & L2 ⊢ ⓐV2.T2 ➡ T.
 199 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #U1 #HVU1 #W1 #HW01 #T1 #HT01
 200 #V2 #HV02 #X #H #L1 #HL01 #L2 #HL02
 201 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 202 elim (lift_total V 0 1) #U #HVU
 203 lapply (cpss_lift … HV1 (L1.ⓓW1) … HVU1 … HVU) -HVU1 /2 width=1/ #HU1
 204 elim (cpss_inv_bind1 … H) -H #W2 #T2 #HW02 #HT02 #H destruct
 205 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1/
 206 elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0
 207 /4 width=9 by ex2_intro, cpr_theta, cpss_bind, cpss_flat/ (**) (* auto too slow without trace *)
 208 qed-.
 209
 210 lemma cpr_cpss_conf_lpr_lpss: lpx_sn_confluent cpr cpss.
 211 #L0 #T0 @(f2_ind … fw … L0 T0) -L0 -T0 #n #IH #L0 * [|*]
 212 [ #I0 #Hn #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 213   elim (cpr_inv_atom1 … H1) -H1
 214   elim (cpss_inv_atom1 … H2) -H2
 215   [ #H2 #H1 destruct
 216     /2 width=1 by cpr_cpss_conf_lpr_lpss_atom_atom/
 217   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 218     /3 width=10 by cpr_cpss_conf_lpr_lpss_atom_delta/
 219   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 220     /3 width=10 by cpr_cpss_conf_lpr_lpss_delta_atom/
 221   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 222     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 223     /3 width=17 by cpr_cpss_conf_lpr_lpss_delta_delta/
 224   ]
 225 | #a #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 226   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H2
 227   elim (cpr_inv_bind1 … H1) -H1 *
 228   [ #V1 #T1 #HV01 #HT01 #H1
 229   | #T1 #HT01 #HXT1 #H11 #H12
 230   ] destruct
 231   [ /3 width=10 by cpr_cpss_conf_lpr_lpss_bind_bind/
 232   | /3 width=11 by cpr_cpss_conf_lpr_lpss_bind_zeta/
 233   ]
 234 | #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 235   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H2
 236   elim (cpr_inv_flat1 … H1) -H1 *
 237   [ #V1 #T1 #HV01 #HT01 #H1
 238   | #HX1 #H1
 239   | #a1 #V1 #Y1 #Z1 #T1 #HV01 #HZT1 #H11 #H12 #H13
 240   | #a1 #V1 #U1 #Y1 #W1 #Z1 #T1 #HV01 #HVU1 #HYW1 #HZT1 #H11 #H12 #H13
 241   ] destruct
 242   [ /3 width=10 by cpr_cpss_conf_lpr_lpss_flat_flat/
 243   | /3 width=8 by cpr_cpss_conf_lpr_lpss_flat_tau/
 244   | /3 width=11 by cpr_cpss_conf_lpr_lpss_flat_beta/
 245   | /3 width=14 by cpr_cpss_conf_lpr_lpss_flat_theta/
 246   ]
 247 ]
 248 qed-.
 249
 250 (* Basic_1: includes: pr0_subst1 *)
 251 lemma cpr_cpss_conf: ∀L. confluent2 … (cpr L) (cpss L).
 252 /2 width=6 by cpr_cpss_conf_lpr_lpss/ qed-.
 253
 254 lemma cpr_lpss_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ▶* L1 →
 255                         ∃∃T. L1 ⊢ T1 ▶* T & L1 ⊢ T0 ➡ T.
 256 #L0 #T0 #T1 #HT01 #L1 #HL01
 257 elim (cpr_cpss_conf_lpr_lpss … HT01 T0 … L1 … HL01) // /2 width=1/ -L0 /2 width=3/
 258 qed-.
 259
 260 lemma cpr_lpss_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ▶* L1 →
 261                         ∃∃T. L0 ⊢ T1 ▶* T & L1 ⊢ T0 ➡ T.
 262 #L0 #T0 #T1 #HT01 #L1 #HL01
 263 elim (cpr_cpss_conf_lpr_lpss … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 264 qed-.
 265
 266 (* Basic_1: includes: pr0_subst1_fwd *)
 267 lemma lpr_cpss_conf: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ➡ L1 →
 268                      ∃∃T. L1 ⊢ T0 ▶* T & L0 ⊢ T1 ➡ T.
 269 #L0 #T0 #T1 #HT01 #L1 #HL01
 270 elim (cpr_cpss_conf_lpr_lpss ?? T0 … HT01 … HL01 L0) // -HT01 -HL01 /2 width=3/
 271 qed-.