matita/matita/contribs/lambdadelta/basic_2/reduction/lpr_cpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lpss_ldrop.ma".
  16 include "basic_2/reduction/lpr_ldrop.ma".
  17
  18 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  19
  20 (* Properties on context-sensitive parallel substitution for terms **********)
  21
  22 fact cpr_cpss_conf_lpr_lpss_atom_atom:
  23    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ▶* T & L2 ⊢ ⓪{I} ➡ T.
  24 /2 width=3/ qed-.
  25
  26 fact cpr_cpss_conf_lpr_lpss_atom_delta:
  27    ∀L0,i. (
  28       ∀L,T.♯{L, T} < ♯{L0, #i} →
  29       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  30       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  31       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  32    ) →
  33    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  34    ∀V2. K0 ⊢ V0 ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  35    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  36    ∃∃T. L1 ⊢ #i ▶* T & L2 ⊢ T2 ➡ T.
  37 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  38 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  39 elim (lpr_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  40 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  41 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  42 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  43 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  44 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  45 elim (lift_total V 0 (i+1)) #T #HVT
  46 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  47 qed-.
  48
  49 fact cpr_cpss_conf_lpr_lpss_delta_atom:
  50    ∀L0,i. (
  51       ∀L,T.♯{L, T} < ♯{L0, #i} →
  52       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  53       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  54       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  55    ) →
  56    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  57    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  58    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  59    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ #i ➡ T.
  60 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1 #L1 #HL01 #L2 #HL02
  61 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  62 elim (lpss_inv_pair1 … H2) -H2 #K2 #V2 #HK02 #HV02 #H destruct
  63 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  64 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  65 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  66 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  67 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  68 elim (lift_total V 0 (i+1)) #T #HVT
  69 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1 /3 width=9/
  70 qed-.
  71
  72 fact cpr_cpss_conf_lpr_lpss_delta_delta:
  73    ∀L0,i. (
  74       ∀L,T.♯{L, T} < ♯{L0, #i} →
  75       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  76       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  77       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  78    ) →
  79    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  80    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  81    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  82    ∀V2. KX ⊢ VX ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  83    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  84    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ T2 ➡ T.
  85 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  86 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  87 lapply (ldrop_mono … H … HLK0) -H #H destruct
  88 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  89 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  90 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  91 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  92 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  93 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  94 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  95 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  96 elim (lift_total V 0 (i+1)) #T #HVT
  97 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  98 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  99 qed-.
 100
 101 fact cpr_cpss_conf_lpr_lpss_bind_bind:
 102    ∀a,I,L0,V0,T0. (
 103       ∀L,T.♯{L,T} < ♯{L0,ⓑ{a,I}V0.T0} →
 104       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 105       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 106       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 107    ) →
 108    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➡ T1 →
 109    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ▶* T2 →
 110    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 111    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ▶* T & L2 ⊢ ⓑ{a,I}V2.T2 ➡ T.
 112 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 113 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 114 elim (IH … HV01 … HV02 … HL01 … HL02) //
 115 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
 116 qed-.
 117
 118 fact cpr_cpss_conf_lpr_lpss_bind_zeta:
 119    ∀L0,V0,T0. (
 120       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
 121       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 122       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 123       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 124    ) →
 125    ∀T1. L0.ⓓV0 ⊢ T0 ➡ T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 126    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓓV0 ⊢ T0 ▶* T2 →
 127    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 128    ∃∃T. L1 ⊢ X1 ▶* T & L2 ⊢ +ⓓV2.T2 ➡ T.
 129 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 130 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 131 elim (IH … HT01 … HT02 (L1.ⓓV2) … (L2.ⓓV2)) -IH -HT01 -HT02 // /2 width=1/ /3 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 132 elim (cpss_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ /3 width=9/
 133 qed-.
 134
 135 fact cpr_cpss_conf_lpr_lpss_flat_flat:
 136    ∀I,L0,V0,T0. (
 137       ∀L,T.♯{L,T} < ♯{L0,ⓕ{I}V0.T0} →
 138       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 139       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 140       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 141    ) →
 142    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ T0 ➡ T1 →
 143    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ T0 ▶* T2 →
 144    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 145    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ▶* T & L2 ⊢ ⓕ{I}V2.T2 ➡ T.
 146 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 147 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 148 elim (IH … HV01 … HV02 … HL01 … HL02) //
 149 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 150 qed-.
 151
 152 fact cpr_cpss_conf_lpr_lpss_flat_tau:
 153    ∀L0,V0,T0. (
 154       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 155       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 156       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 157       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 158    ) →
 159    ∀T1. L0 ⊢ T0 ➡ T1 → ∀V2,T2. L0 ⊢ T0 ▶* T2 →
 160    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 161    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ ⓝV2.T2 ➡ T.
 162 #L0 #V0 #T0 #IH #T1 #HT01
 163 #V2 #T2 #HT02 #L1 #HL01 #L2 #HL02
 164 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 165 qed-.
 166
 167 fact cpr_cpss_conf_lpr_lpss_flat_beta:
 168    ∀a,L0,V0,W0,T0. (
 169       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓛ{a}W0.T0} →
 170       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 171       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 172       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 173    ) →
 174    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓛW0 ⊢ T0 ➡ T1 →
 175    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ ⓛ{a}W0.T0 ▶* T2 →
 176    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 177    ∃∃T. L1 ⊢ ⓓ{a}V1.T1 ▶* T & L2 ⊢ ⓐV2.T2 ➡ T.
 178 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #T1 #HT01
 179 #V2 #HV02 #X #H #L1 #HL01 #L2 #HL02
 180 elim (cpss_inv_bind1 … H) -H #W2 #T2 #HW02 #HT02 #H destruct
 181 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 182 elim (IH … HT01 … HT02 (L1.ⓛW2) … (L2.ⓛW2)) /2 width=1/ /3 width=1/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 183 lapply (cpss_lsubr_trans … HT1 (L1.ⓓV1) ?) -HT1 /2 width=1/ /3 width=5/
 184 qed-.
 185
 186 fact cpr_cpss_conf_lpr_lpss_flat_theta:
 187    ∀a,L0,V0,W0,T0. (
 188       ∀L,T.♯{L,T} < ♯{L0,ⓐV0.ⓓ{a}W0.T0} →
 189       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 190       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 191       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 192    ) →
 193    ∀V1. L0 ⊢ V0 ➡ V1 → ∀U1. ⇧[O, 1] V1 ≡ U1 →
 194    ∀W1. L0 ⊢ W0 ➡ W1 → ∀T1. L0.ⓓW0 ⊢ T0 ➡ T1 →
 195    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ ⓓ{a}W0.T0 ▶* T2 →
 196    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 197    ∃∃T. L1 ⊢ ⓓ{a}W1.ⓐU1.T1 ▶* T & L2 ⊢ ⓐV2.T2 ➡ T.
 198 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #U1 #HVU1 #W1 #HW01 #T1 #HT01
 199 #V2 #HV02 #X #H #L1 #HL01 #L2 #HL02
 200 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 201 elim (lift_total V 0 1) #U #HVU
 202 lapply (cpss_lift … HV1 (L1.ⓓW1) … HVU1 … HVU) -HVU1 /2 width=1/ #HU1
 203 elim (cpss_inv_bind1 … H) -H #W2 #T2 #HW02 #HT02 #H destruct
 204 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1/
 205 elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0
 206 /4 width=9 by ex2_intro, cpr_theta, cpss_bind, cpss_flat/ (**) (* auto too slow without trace *)
 207 qed-.
 208
 209 lemma cpr_cpss_conf_lpr_lpss: lpx_sn_confluent cpr cpss.
 210 #L0 #T0 @(f2_ind … fw … L0 T0) -L0 -T0 #n #IH #L0 * [|*]
 211 [ #I0 #Hn #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 212   elim (cpr_inv_atom1 … H1) -H1
 213   elim (cpss_inv_atom1 … H2) -H2
 214   [ #H2 #H1 destruct
 215     /2 width=1 by cpr_cpss_conf_lpr_lpss_atom_atom/
 216   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 217     /3 width=10 by cpr_cpss_conf_lpr_lpss_atom_delta/
 218   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 219     /3 width=10 by cpr_cpss_conf_lpr_lpss_delta_atom/
 220   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 221     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 222     /3 width=17 by cpr_cpss_conf_lpr_lpss_delta_delta/
 223   ]
 224 | #a #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 225   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H2
 226   elim (cpr_inv_bind1 … H1) -H1 *
 227   [ #V1 #T1 #HV01 #HT01 #H1
 228   | #T1 #HT01 #HXT1 #H11 #H12
 229   ] destruct
 230   [ /3 width=10 by cpr_cpss_conf_lpr_lpss_bind_bind/
 231   | /3 width=11 by cpr_cpss_conf_lpr_lpss_bind_zeta/
 232   ]
 233 | #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 234   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H2
 235   elim (cpr_inv_flat1 … H1) -H1 *
 236   [ #V1 #T1 #HV01 #HT01 #H1
 237   | #HX1 #H1
 238   | #a1 #V1 #Y1 #Z1 #T1 #HV01 #HZT1 #H11 #H12 #H13
 239   | #a1 #V1 #U1 #Y1 #W1 #Z1 #T1 #HV01 #HVU1 #HYW1 #HZT1 #H11 #H12 #H13
 240   ] destruct
 241   [ /3 width=10 by cpr_cpss_conf_lpr_lpss_flat_flat/
 242   | /3 width=8 by cpr_cpss_conf_lpr_lpss_flat_tau/
 243   | /3 width=11 by cpr_cpss_conf_lpr_lpss_flat_beta/
 244   | /3 width=14 by cpr_cpss_conf_lpr_lpss_flat_theta/
 245   ]
 246 ]
 247 qed-.
 248
 249 (* Basic_1: includes: pr0_subst1 *)
 250 lemma cpr_cpss_conf: ∀L. confluent2 … (cpr L) (cpss L).
 251 /2 width=6 by cpr_cpss_conf_lpr_lpss/ qed-.
 252
 253 lemma cpr_lpss_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ▶* L1 →
 254                         ∃∃T. L1 ⊢ T1 ▶* T & L1 ⊢ T0 ➡ T.
 255 #L0 #T0 #T1 #HT01 #L1 #HL01
 256 elim (cpr_cpss_conf_lpr_lpss … HT01 T0 … L1 … HL01) // /2 width=1/ -L0 /2 width=3/
 257 qed-.
 258
 259 lemma cpr_lpss_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ▶* L1 →
 260                         ∃∃T. L0 ⊢ T1 ▶* T & L1 ⊢ T0 ➡ T.
 261 #L0 #T0 #T1 #HT01 #L1 #HL01
 262 elim (cpr_cpss_conf_lpr_lpss … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 263 qed-.
 264
 265 (* Basic_1: includes: pr0_subst1_fwd *)
 266 lemma lpr_cpss_conf: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ➡ L1 →
 267                      ∃∃T. L1 ⊢ T0 ▶* T & L0 ⊢ T1 ➡ T.
 268 #L0 #T0 #T1 #HT01 #L1 #HL01
 269 elim (cpr_cpss_conf_lpr_lpss ?? T0 … HT01 … HL01 L0) // -HT01 -HL01 /2 width=3/
 270 qed-.