matita/matita/contribs/lambdadelta/basic_2/reduction/lpr_ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/fsup.ma".
  16 include "basic_2/relocation/ldrop_lpx_sn.ma".
  17 include "basic_2/reduction/cpr_lift.ma".
  18 include "basic_2/reduction/lpr.ma".
  19
  20 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  21
  22 (* Properies on local environment slicing ***********************************)
  23
  24 (* Basic_1: includes: wcpr0_drop *)
  25 lemma lpr_ldrop_conf: ∀G. dropable_sn (lpr G).
  26 /3 width=5 by lpx_sn_deliftable_dropable, cpr_inv_lift1/ qed-.
  27
  28 (* Basic_1: includes: wcpr0_drop_back *)
  29 lemma ldrop_lpr_trans: ∀G. dedropable_sn (lpr G).
  30 /3 width=9 by lpx_sn_liftable_dedropable, cpr_lift/ qed-.
  31
  32 lemma lpr_ldrop_trans_O1: ∀G. dropable_dx (lpr G).
  33 /2 width=3 by lpx_sn_dropable/ qed-.
  34
  35 (* Properties on context-sensitive parallel reduction for terms *************)
  36
  37 lemma fsup_cpr_trans: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
  38                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡ U2 →
  39                       ∃∃L,U1. ⦃G1, L1⦄ ⊢ ➡ L & ⦃G1, L⦄ ⊢ T1 ➡ U1 & ⦃G1, L, U1⦄ ⊃ ⦃G2, L2, U2⦄.
  40 #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2 [1,2,3,4,5: /3 width=5/ ]
  41 [ #G #L #K #U #T #d #e #HLK #HUT #He #U2 #HU2
  42   elim (lift_total U2 d e) #T2 #HUT2
  43   lapply (cpr_lift … HU2 … HLK … HUT … HUT2) -HU2 -HUT /3 width=9/
  44 | #G1 #G2 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #U2 #HTU2
  45   elim (IHT12 … HTU2) -IHT12 -HTU2 #K #T #HK1 #HT1 #HT2
  46   elim (lift_total T d e) #U #HTU
  47   elim (ldrop_lpr_trans … HLK1 … HK1) -HLK1 -HK1 #L2 #HL12 #HL2K
  48   lapply (cpr_lift … HT1 … HL2K … HTU1 … HTU) -HT1 -HTU1 /3 width=11/
  49 ]
  50 qed-.