matita/matita/contribs/lambdadelta/basic_2/reduction/lpx_ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/ldrop_lpx_sn.ma".
  16 include "basic_2/reduction/cpx_lift.ma".
  17 include "basic_2/reduction/lpx.ma".
  18
  19 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  20
  21 (* Properies on local environment slicing ***********************************)
  22
  23 lemma lpx_ldrop_conf: ∀h,g,G. dropable_sn (lpx h g G).
  24 /3 width=5 by lpx_sn_deliftable_dropable, cpx_inv_lift1/ qed-.
  25
  26 lemma ldrop_lpx_trans: ∀h,g,G. dedropable_sn (lpx h g G).
  27 /3 width=9 by lpx_sn_liftable_dedropable, cpx_lift/ qed-.
  28
  29 lemma lpx_ldrop_trans_O1: ∀h,g,G. dropable_dx (lpx h g G).
  30 /2 width=3 by lpx_sn_dropable/ qed-.
  31
  32 (* Properties on supclosure *************************************************)
  33
  34 lemma fsupq_lpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  35                        ∀K2. ⦃G2, L2⦄ ⊢ ➡[h, g] K2 →
  36                                    ∃∃K1,T. ⦃G1, L1⦄ ⊢ ➡[h, g] K1 & ⦃G1, L1⦄ ⊢ T1 ➡[h, g] T & ⦃G1, K1, T⦄ ⊃⸮ ⦃G2, K2, T2⦄.
  37 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  38 /3 width=5 by fsup_fsupq, fsupq_refl, lpx_pair, fsup_lref_O, fsup_pair_sn, fsup_flat_dx, ex3_2_intro/
  39 [ #a #I #G2 #L2 #V2 #T2 #X #H elim (lpx_inv_pair1 … H) -H
  40   #K2 #W2 #HLK2 #HVW2 #H destruct
  41   /3 width=5 by fsup_fsupq, cpx_pair_sn, fsup_bind_dx, ex3_2_intro/
  42 | #G1 #G2 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IH12 #K0 #HK20
  43         elim (IH12 … HK20) -K2 #K2 #T #HK12
  44         elim (ldrop_lpx_trans … HLK1 … HK12) -HK12
  45         elim (lift_total T d e)
  46         /3 width=11 by cpx_lift, fsupq_ldrop, ex3_2_intro/
  47 ]
  48 qed-.