matita/matita/contribs/lambdadelta/basic_2/reduction/lpx_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lleq_ldrop.ma".
  16 include "basic_2/reduction/lpx_ldrop.ma".
  17
  18 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  19
  20 (* Properties on lazy equivalence for local environments ********************)
  21
  22 axiom lleq_lpx_trans: ∀h,g,G,L2,K2. ⦃G, L2⦄ ⊢ ➡[h, g] K2 →
  23                       ∀L1,T,d. L1 ⋕[T, d] L2 →
  24                       ∃∃K1. ⦃G, L1⦄ ⊢ ➡[h, g] K1 & K1 ⋕[T, d] K2.
  25
  26 lemma lpx_lleq_fqu_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
  27                           ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  28                           ∃∃K2. ⦃G1, K1, T1⦄ ⊃ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  29 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  30 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpx_inv_pair2 … H1) -H1
  31   #K0 #V0 #H1KL1 #_ #H destruct
  32   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
  33   #K1 #H #H2KL1 lapply (ldrop_inv_O2 … H) -H #H destruct
  34   /2 width=4 by fqu_lref_O, ex3_intro/
  35 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
  36   [ elim (lleq_inv_bind … H)
  37   | elim (lleq_inv_flat … H)
  38   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
  39 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
  40   /3 width=4 by lpx_pair, fqu_bind_dx, ex3_intro/
  41 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
  42   /2 width=4 by fqu_flat_dx, ex3_intro/
  43 | #G1 #L1 #L #T1 #U1 #e #HL1 #HTU1 #K1 #H1KL1 #H2KL1
  44   elim (ldrop_O1_le (e+1) K1)
  45   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
  46     #H2KL elim (lpx_ldrop_trans_O1 … H1KL1 … HL1) -L1
  47     #K0 #HK10 #H1KL lapply (ldrop_mono … HK10 … HK1) -HK10 #H destruct
  48     /3 width=4 by fqu_drop, ex3_intro/
  49   | lapply (ldrop_fwd_length_le2 … HL1) -L -T1 -g
  50     lapply (lleq_fwd_length … H2KL1) //
  51   ]
  52 ]
  53 qed-.
  54
  55 lemma lpx_lleq_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  56                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  57                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  58 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  59 elim (fquq_inv_gen … H) -H
  60 [ #H elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  61   /3 width=4 by fqu_fquq, ex3_intro/
  62 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  63 ]
  64 qed-.
  65
  66 lemma lpx_lleq_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
  67                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  68                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  69 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  70 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  71   /3 width=4 by fqu_fqup, ex3_intro/
  72 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
  73   #K #HT1 #H1KL #H2KL elim (lpx_lleq_fqu_trans … HT2 … H1KL H2KL) -L
  74   /3 width=5 by fqup_strap1, ex3_intro/
  75 ]
  76 qed-.
  77
  78 lemma lpx_lleq_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
  79                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[T1, 0] L1 →
  80                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[T2, 0] L2.
  81 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  82 elim (fqus_inv_gen … H) -H
  83 [ #H elim (lpx_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
  84   /3 width=4 by fqup_fqus, ex3_intro/
  85 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  86 ]
  87 qed-.