matita/matita/contribs/lambdadelta/basic_2/reduction/lpx_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lleq_lleq.ma".
  16 include "basic_2/reduction/lpx_ldrop.ma".
  17
  18 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  19
  20 (* Properties on lazy equivalence for local environments ********************)
  21
  22 lemma lpx_lleq_fqu_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
  23                           ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[0, T1] L1 →
  24                           ∃∃K2. ⦃G1, K1, T1⦄ ⊃ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[0, T2] L2.
  25 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  26 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpx_inv_pair2 … H1) -H1
  27   #K0 #V0 #H1KL1 #_ #H destruct
  28   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
  29   #K1 #H #H2KL1 lapply (ldrop_inv_O2 … H) -H #H destruct
  30   /2 width=4 by fqu_lref_O, ex3_intro/
  31 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
  32   [ elim (lleq_inv_bind … H)
  33   | elim (lleq_inv_flat … H)
  34   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
  35 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
  36   /3 width=4 by lpx_pair, fqu_bind_dx, ex3_intro/
  37 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
  38   /2 width=4 by fqu_flat_dx, ex3_intro/
  39 | #G1 #L1 #L #T1 #U1 #e #HL1 #HTU1 #K1 #H1KL1 #H2KL1
  40   elim (ldrop_O1_le (e+1) K1)
  41   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
  42     #H2KL elim (lpx_ldrop_trans_O1 … H1KL1 … HL1) -L1
  43     #K0 #HK10 #H1KL lapply (ldrop_mono … HK10 … HK1) -HK10 #H destruct
  44     /3 width=4 by fqu_drop, ex3_intro/
  45   | lapply (ldrop_fwd_length_le2 … HL1) -L -T1 -g
  46     lapply (lleq_fwd_length … H2KL1) //
  47   ]
  48 ]
  49 qed-.
  50
  51 lemma lpx_lleq_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  52                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[0, T1] L1 →
  53                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[0, T2] L2.
  54 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  55 elim (fquq_inv_gen … H) -H
  56 [ #H elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  57   /3 width=4 by fqu_fquq, ex3_intro/
  58 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  59 ]
  60 qed-.
  61
  62 lemma lpx_lleq_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
  63                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[0, T1] L1 →
  64                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[0, T2] L2.
  65 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  66 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  67   /3 width=4 by fqu_fqup, ex3_intro/
  68 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
  69   #K #HT1 #H1KL #H2KL elim (lpx_lleq_fqu_trans … HT2 … H1KL H2KL) -L
  70   /3 width=5 by fqup_strap1, ex3_intro/
  71 ]
  72 qed-.
  73
  74 lemma lpx_lleq_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
  75                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ⋕[0, T1] L1 →
  76                            ∃∃K2. ⦃G1, K1, T1⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ⋕[0, T2] L2.
  77 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  78 elim (fqus_inv_gen … H) -H
  79 [ #H elim (lpx_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
  80   /3 width=4 by fqup_fqus, ex3_intro/
  81 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  82 ]
  83 qed-.