matita/matita/contribs/lambdadelta/basic_2/relocation/cpy.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_max.ma".
  16 include "basic_2/notation/relations/extpsubst_6.ma".
  17 include "basic_2/grammar/genv.ma".
  18 include "basic_2/grammar/cl_shift.ma".
  19 include "basic_2/relocation/ldrop_append.ma".
  20 include "basic_2/relocation/lsuby.ma".
  21
  22 (* CONTEXT-SENSITIVE EXTENDED ORDINARY SUBSTITUTION FOR TERMS ***************)
  23
  24 (* activate genv *)
  25 inductive cpy: ynat → ynat → relation4 genv lenv term term ≝
  26 | cpy_atom : ∀I,G,L,d,e. cpy d e G L (⓪{I}) (⓪{I})
  27 | cpy_subst: ∀I,G,L,K,V,W,i,d,e. d ≤ yinj i → i < d+e →
  28              ⇩[0, i] L ≡ K.ⓑ{I}V → ⇧[0, i+1] V ≡ W → cpy d e G L (#i) W
  29 | cpy_bind : ∀a,I,G,L,V1,V2,T1,T2,d,e.
  30              cpy d e G L V1 V2 → cpy (⫯d) e G (L.ⓑ{I}V2) T1 T2 →
  31              cpy d e G L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  32 | cpy_flat : ∀I,G,L,V1,V2,T1,T2,d,e.
  33              cpy d e G L V1 V2 → cpy d e G L T1 T2 →
  34              cpy d e G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  35 .
  36
  37 interpretation "context-sensitive extended ordinary substritution (term)"
  38    'ExtPSubst G L T1 d e T2 = (cpy d e G L T1 T2).
  39
  40 (* Basic properties *********************************************************)
  41
  42 lemma lsuby_cpy_trans: ∀G,d,e. lsub_trans … (cpy d e G) (lsuby d e).
  43 #G #d #e #L1 #T1 #T2 #H elim H -G -L1 -T1 -T2 -d -e
  44 [ //
  45 | #I #G #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  46   elim (lsuby_fwd_ldrop2_be … HL12 … HLK1) -HL12 -HLK1 /2 width=5 by cpy_subst/
  47 | /4 width=1 by lsuby_succ, cpy_bind/
  48 | /3 width=1 by cpy_flat/
  49 ]
  50 qed-.
  51
  52 lemma cpy_refl: ∀G,T,L,d,e. ⦃G, L⦄ ⊢ T ▶×[d, e] T.
  53 #G #T elim T -T // * /2 width=1 by cpy_bind, cpy_flat/
  54 qed.
  55
  56 lemma cpy_full: ∀I,G,K,V,T1,L,d. ⇩[0, d] L ≡ K.ⓑ{I}V →
  57                 ∃∃T2,T. ⦃G, L⦄ ⊢ T1 ▶×[d, 1] T2 & ⇧[d, 1] T ≡ T2.
  58 #I #G #K #V #T1 elim T1 -T1
  59 [ * #i #L #d #HLK
  60   /2 width=4 by lift_sort, lift_gref, ex2_2_intro/
  61   elim (lt_or_eq_or_gt i d) #Hid
  62   /3 width=4 by lift_lref_ge_minus, lift_lref_lt, ex2_2_intro/
  63   destruct
  64   elim (lift_total V 0 (i+1)) #W #HVW
  65   elim (lift_split … HVW i i)
  66   /4 width=5 by cpy_subst, ylt_inj, ex2_2_intro/
  67 | * [ #a ] #J #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  68   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  69   [ elim (IHU1 (L.ⓑ{J}W2) (d+1)) -IHU1
  70     /3 width=9 by cpy_bind, ldrop_ldrop, lift_bind, ex2_2_intro/
  71   | elim (IHU1 … HLK) -IHU1 -HLK
  72     /3 width=8 by cpy_flat, lift_flat, ex2_2_intro/
  73   ]
  74 ]
  75 qed-.
  76
  77 lemma cpy_weak: ∀G,L,T1,T2,d1,e1. ⦃G, L⦄ ⊢ T1 ▶×[d1, e1] T2 →
  78                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  79                 ⦃G, L⦄ ⊢ T1 ▶×[d2, e2] T2.
  80 #G #L #T1 #T2 #d1 #e1 #H elim H -G -L -T1 -T2 -d1 -e1 //
  81 [ /3 width=5 by cpy_subst, ylt_yle_trans, yle_trans/
  82 | /4 width=3 by cpy_bind, ylt_yle_trans, yle_succ/
  83 | /3 width=1 by cpy_flat/
  84 ]
  85 qed-.
  86
  87 lemma cpy_weak_top: ∀G,L,T1,T2,d,e.
  88                     ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ⦃G, L⦄ ⊢ T1 ▶×[d, |L| - d] T2.
  89 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e //
  90 [ #I #G #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  91   lapply (ldrop_fwd_length_lt2 … HLK)
  92   /4 width=5 by cpy_subst, ylt_yle_trans, ylt_inj/
  93 | #a #I #G #L #V1 #V2 normalize in match (|L.ⓑ{I}V2|); (**) (* |?| does not work *)
  94   /2 width=1 by cpy_bind/
  95 | /2 width=1 by cpy_flat/
  96 ]
  97 qed-.
  98
  99 lemma cpy_weak_full: ∀G,L,T1,T2,d,e.
 100                      ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ⦃G, L⦄ ⊢ T1 ▶×[0, |L|] T2.
 101 #G #L #T1 #T2 #d #e #HT12
 102 lapply (cpy_weak … HT12 0 (d + e) ? ?) -HT12
 103 /2 width=2 by cpy_weak_top/
 104 qed-.
 105
 106 lemma cpy_split_up: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ∀i. i ≤ d + e →
 107                     ∃∃T. ⦃G, L⦄ ⊢ T1 ▶×[d, i-d] T & ⦃G, L⦄ ⊢ T ▶×[i, d+e-i] T2.
 108 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e
 109 [ /2 width=3 by ex2_intro/
 110 | #I #G #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hjde
 111   elim (ylt_split i j) [ -Hide -Hjde | -Hdi ]
 112   /4 width=9 by cpy_subst, ylt_yle_trans, ex2_intro/
 113 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 114   elim (IHV12 i) -IHV12 // #V
 115   elim (IHT12 (i+1)) -IHT12 /2 width=1 by yle_succ/ -Hide
 116   >yplus_SO2 >yplus_succ1 #T #HT1 #HT2
 117   lapply (lsuby_cpy_trans … HT1 (L.ⓑ{I}V) ?) -HT1
 118   /3 width=5 by lsuby_succ, ex2_intro, cpy_bind/
 119 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 120   elim (IHV12 i) -IHV12 // elim (IHT12 i) -IHT12 // -Hide
 121   /3 width=5 by ex2_intro, cpy_flat/
 122 ]
 123 qed-.
 124
 125 lemma cpy_split_down: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ∀i. i ≤ d + e →
 126                       ∃∃T. ⦃G, L⦄ ⊢ T1 ▶×[i, d+e-i] T & ⦃G, L⦄ ⊢ T ▶×[d, i-d] T2.
 127 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e
 128 [ /2 width=3 by ex2_intro/
 129 | #I #G #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hjde
 130   elim (ylt_split i j) [ -Hide -Hjde | -Hdi ]
 131   /4 width=9 by cpy_subst, ylt_yle_trans, ex2_intro/
 132 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 133   elim (IHV12 i) -IHV12 // #V
 134   elim (IHT12 (i+1)) -IHT12 /2 width=1 by yle_succ/ -Hide
 135   >yplus_SO2 >yplus_succ1 #T #HT1 #HT2
 136   lapply (lsuby_cpy_trans … HT1 (L. ⓑ{I} V) ?) -HT1
 137   /3 width=5 by lsuby_succ, ex2_intro, cpy_bind/
 138 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hide
 139   elim (IHV12 i) -IHV12 // elim (IHT12 i) -IHT12 // -Hide
 140   /3 width=5 by ex2_intro, cpy_flat/
 141 ]
 142 qed-.
 143
 144 lemma cpy_append: ∀G,d,e. l_appendable_sn … (cpy d e G).
 145 #G #d #e #K #T1 #T2 #H elim H -G -K -T1 -T2 -d -e
 146 /2 width=1 by cpy_atom, cpy_bind, cpy_flat/
 147 #I #G #K #K0 #V #W #i #d #e #Hdi #Hide #HK0 #HVW #L
 148 lapply (ldrop_fwd_length_lt2 … HK0) #H
 149 @(cpy_subst I … (L@@K0) … HVW) // (**) (* /4/ does not work *)
 150 @(ldrop_O1_append_sn_le … HK0) /2 width=2 by lt_to_le/
 151 qed-.
 152
 153 (* Basic inversion lemmas ***************************************************)
 154
 155 fact cpy_inv_atom1_aux: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ∀J. T1 = ⓪{J} →
 156                         T2 = ⓪{J} ∨
 157                         ∃∃I,K,V,i. d ≤ yinj i & i < d + e &
 158                                    ⇩[O, i] L ≡ K.ⓑ{I}V &
 159                                    ⇧[O, i + 1] V ≡ T2 &
 160                                    J = LRef i.
 161 #G #L #T1 #T2 #d #e * -G -L -T1 -T2 -d -e
 162 [ #I #G #L #d #e #J #H destruct /2 width=1 by or_introl/
 163 | #I #G #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #J #H destruct /3 width=9 by ex5_4_intro, or_intror/
 164 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 165 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 166 ]
 167 qed-.
 168
 169 lemma cpy_inv_atom1: ∀I,G,L,T2,d,e. ⦃G, L⦄ ⊢ ⓪{I} ▶×[d, e] T2 →
 170                      T2 = ⓪{I} ∨
 171                      ∃∃J,K,V,i. d ≤ yinj i & i < d + e &
 172                                 ⇩[O, i] L ≡ K.ⓑ{J}V &
 173                                 ⇧[O, i + 1] V ≡ T2 &
 174                                 I = LRef i.
 175 /2 width=4 by cpy_inv_atom1_aux/ qed-.
 176
 177 lemma cpy_inv_sort1: ∀G,L,T2,k,d,e. ⦃G, L⦄ ⊢ ⋆k ▶×[d, e] T2 → T2 = ⋆k.
 178 #G #L #T2 #k #d #e #H
 179 elim (cpy_inv_atom1 … H) -H //
 180 * #I #K #V #i #_ #_ #_ #_ #H destruct
 181 qed-.
 182
 183 lemma cpy_inv_lref1: ∀G,L,T2,i,d,e. ⦃G, L⦄ ⊢ #i ▶×[d, e] T2 →
 184                      T2 = #i ∨
 185                      ∃∃I,K,V. d ≤ i & i < d + e &
 186                               ⇩[O, i] L ≡ K.ⓑ{I}V &
 187                               ⇧[O, i + 1] V ≡ T2.
 188 #G #L #T2 #i #d #e #H
 189 elim (cpy_inv_atom1 … H) -H /2 width=1 by or_introl/
 190 * #I #K #V #j #Hdj #Hjde #HLK #HVT2 #H destruct /3 width=5 by ex4_3_intro, or_intror/
 191 qed-.
 192
 193 lemma cpy_inv_gref1: ∀G,L,T2,p,d,e. ⦃G, L⦄ ⊢ §p ▶×[d, e] T2 → T2 = §p.
 194 #G #L #T2 #p #d #e #H
 195 elim (cpy_inv_atom1 … H) -H //
 196 * #I #K #V #i #_ #_ #_ #_ #H destruct
 197 qed-.
 198
 199 fact cpy_inv_bind1_aux: ∀G,L,U1,U2,d,e. ⦃G, L⦄ ⊢ U1 ▶×[d, e] U2 →
 200                         ∀a,I,V1,T1. U1 = ⓑ{a,I}V1.T1 →
 201                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 202                                  ⦃G, L. ⓑ{I}V2⦄ ⊢ T1 ▶×[⫯d, e] T2 &
 203                                  U2 = ⓑ{a,I}V2.T2.
 204 #G #L #U1 #U2 #d #e * -G -L -U1 -U2 -d -e
 205 [ #I #G #L #d #e #b #J #W1 #U1 #H destruct
 206 | #I #G #L #K #V #W #i #d #e #_ #_ #_ #_ #b #J #W1 #U1 #H destruct
 207 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #b #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 208 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #b #J #W1 #U1 #H destruct
 209 ]
 210 qed-.
 211
 212 lemma cpy_inv_bind1: ∀a,I,G,L,V1,T1,U2,d,e. ⦃G, L⦄ ⊢ ⓑ{a,I} V1. T1 ▶×[d, e] U2 →
 213                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 214                               ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ▶×[⫯d, e] T2 &
 215                               U2 = ⓑ{a,I}V2.T2.
 216 /2 width=3 by cpy_inv_bind1_aux/ qed-.
 217
 218 fact cpy_inv_flat1_aux: ∀G,L,U1,U2,d,e. ⦃G, L⦄ ⊢ U1 ▶×[d, e] U2 →
 219                         ∀I,V1,T1. U1 = ⓕ{I}V1.T1 →
 220                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 221                                  ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 &
 222                                  U2 = ⓕ{I}V2.T2.
 223 #G #L #U1 #U2 #d #e * -G -L -U1 -U2 -d -e
 224 [ #I #G #L #d #e #J #W1 #U1 #H destruct
 225 | #I #G #L #K #V #W #i #d #e #_ #_ #_ #_ #J #W1 #U1 #H destruct
 226 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #J #W1 #U1 #H destruct
 227 | #I #G #L #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 228 ]
 229 qed-.
 230
 231 lemma cpy_inv_flat1: ∀I,G,L,V1,T1,U2,d,e. ⦃G, L⦄ ⊢ ⓕ{I} V1. T1 ▶×[d, e] U2 →
 232                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶×[d, e] V2 &
 233                               ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 &
 234                               U2 = ⓕ{I}V2.T2.
 235 /2 width=3 by cpy_inv_flat1_aux/ qed-.
 236
 237
 238 fact cpy_inv_refl_O2_aux: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → e = 0 → T1 = T2.
 239 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e
 240 [ //
 241 | #I #G #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct
 242   elim (ylt_yle_false … Hdi) -Hdi //
 243 | /3 width=1 by eq_f2/
 244 | /3 width=1 by eq_f2/
 245 ]
 246 qed-.
 247
 248 lemma cpy_inv_refl_O2: ∀G,L,T1,T2,d. ⦃G, L⦄ ⊢ T1 ▶×[d, 0] T2 → T1 = T2.
 249 /2 width=6 by cpy_inv_refl_O2_aux/ qed-.
 250
 251 (* Basic forward lemmas *****************************************************)
 252
 253 lemma cpy_fwd_tw: ∀G,L,T1,T2,d,e. ⦃G, L⦄ ⊢ T1 ▶×[d, e] T2 → ♯{T1} ≤ ♯{T2}.
 254 #G #L #T1 #T2 #d #e #H elim H -G -L -T1 -T2 -d -e normalize
 255 /3 width=1 by monotonic_le_plus_l, le_plus/
 256 qed-.
 257
 258 lemma cpy_fwd_shift1: ∀G,L1,L,T1,T,d,e. ⦃G, L⦄ ⊢ L1 @@ T1 ▶×[d, e] T →
 259                       ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 260 #G #L1 @(lenv_ind_dx … L1) -L1 normalize
 261 [ #L #T1 #T #d #e #HT1
 262   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 263 | #I #L1 #V1 #IH #L #T1 #X #d #e
 264   >shift_append_assoc normalize #H
 265   elim (cpy_inv_bind1 … H) -H
 266   #V0 #T0 #_ #HT10 #H destruct
 267   elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 268   >append_length >HL12 -HL12
 269   @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] (**) (* explicit constructor *)
 270   /2 width=3 by trans_eq/
 271 ]
 272 qed-.