matita/matita/contribs/lambdadelta/basic_2/relocation/cpy_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/ldrop_ldrop.ma".
  16 include "basic_2/relocation/cpy.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED ORDINARY SUBSTITUTION FOR TERMS ***************)
  19
  20 (* Relocation properties ****************************************************)
  21
  22 lemma cpy_lift_le: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 →
  23                    ∀L,U1,U2,d,e. ⇩[d, e] L ≡ K →
  24                    ⇧[d, e] T1 ≡ U1 → ⇧[d, e] T2 ≡ U2 →
  25                    dt + et ≤ d → ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2.
  26 #G #K #T1 #T2 #dt #et #H elim H -G -K -T1 -T2 -dt -et
  27 [ #I #G #K #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  28   >(lift_mono … H1 … H2) -H1 -H2 //
  29 | #I #G #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HWU2 #Hdetd
  30   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
  31   lapply (lift_inv_lref1_lt … H … Hid) -H #H destruct
  32   elim (lift_trans_ge … HVW … HWU2) -W // <minus_plus #W #HVW #HWU2
  33   elim (ldrop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  34   elim (ldrop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hid #K #Y #_ #HVY
  35   >(lift_mono … HVY … HVW) -Y -HVW #H destruct /2 width=5 by cpy_subst/
  36 | #a #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  37   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  38   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  39   /4 width=6 by cpy_bind, ldrop_skip, le_S_S/
  40 | #G #I #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  41   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  42   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  43   /3 width=6 by cpy_flat/
  44 ]
  45 qed-.
  46
  47 lemma cpy_lift_be: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 →
  48                    ∀L,U1,U2,d,e. ⇩[d, e] L ≡ K →
  49                    ⇧[d, e] T1 ≡ U1 → ⇧[d, e] T2 ≡ U2 →
  50                    dt ≤ d → d ≤ dt + et → ⦃G, L⦄ ⊢ U1 ▶×[dt, et + e] U2.
  51 #G #K #T1 #T2 #dt #et #H elim H -G -K -T1 -T2 -dt -et
  52 [ #I #G #K #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_ #_
  53   >(lift_mono … H1 … H2) -H1 -H2 //
  54 | #I #G #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HWU2 #Hdtd #_
  55   elim (lift_inv_lref1 … H) -H * #Hid #H destruct
  56   [ -Hdtd
  57     lapply (lt_to_le_to_lt … (dt+et+e) Hidet ?) // -Hidet #Hidete
  58     elim (lift_trans_ge … HVW … HWU2) -W // <minus_plus #W #HVW #HWU2
  59     elim (ldrop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  60     elim (ldrop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hid #K #Y #_ #HVY
  61     >(lift_mono … HVY … HVW) -V #H destruct /2 width=5 by cpy_subst/
  62   | -Hdti
  63     lapply (transitive_le … Hdtd Hid) -Hdtd #Hdti
  64     lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  65     lapply (ldrop_trans_ge_comm … HLK … HKV ?) -K // -Hid /3 width=5 by cpy_subst, lt_minus_to_plus_r, transitive_le/
  66   ]
  67 | #a #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdtd #Hddet
  68   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  69   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  70   /4 width=6 by cpy_bind, ldrop_skip, le_S_S/ (**) (* auto a bit slow *)
  71 | #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  72   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  73   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  74   /3 width=6 by cpy_flat/
  75 ]
  76 qed-.
  77
  78 lemma cpy_lift_ge: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 →
  79                    ∀L,U1,U2,d,e. ⇩[d, e] L ≡ K →
  80                    ⇧[d, e] T1 ≡ U1 → ⇧[d, e] T2 ≡ U2 →
  81                    d ≤ dt → ⦃G, L⦄ ⊢ U1 ▶×[dt + e, et] U2.
  82 #G #K #T1 #T2 #dt #et #H elim H -G -K -T1 -T2 -dt -et
  83 [ #I #G #K #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  84   >(lift_mono … H1 … H2) -H1 -H2 //
  85 | #I #G #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HWU2 #Hddt
  86   lapply (transitive_le … Hddt … Hdti) -Hddt #Hid
  87   lapply (lift_inv_lref1_ge … H … Hid) -H #H destruct
  88   lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  89   lapply (ldrop_trans_ge_comm … HLK … HKV ?) -K // -Hid /3 width=5 by cpy_subst, lt_minus_to_plus_r, monotonic_le_plus_l/
  90 | #a #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  91   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  92   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  93   /4 width=5 by cpy_bind, ldrop_skip, le_minus_to_plus/
  94 | #I #G #K #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  95   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  96   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  97   /3 width=5 by cpy_flat/
  98 ]
  99 qed-.
 100
 101 lemma cpy_inv_lift1_le: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 102                         ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 103                         dt + et ≤ d →
 104                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, et] T2 & ⇧[d, e] T2 ≡ U2.
 105 #G #L #U1 #U2 #dt #et #H elim H -G -L -U1 -U2 -dt -et
 106 [ * #G #L #i #dt #et #K #d #e #_ #T1 #H #_
 107   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by cpy_atom, lift_sort, ex2_intro/
 108   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by cpy_atom, lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 109   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by cpy_atom, lift_gref, ex2_intro/
 110   ]
 111 | #I #G #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdetd
 112   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
 113   lapply (lift_inv_lref2_lt … H … Hid) -H #H destruct
 114   elim (ldrop_conf_lt … HLK … HLKV ?) -L // #L #U #HKL #_ #HUV
 115   elim (lift_trans_le … HUV … HVW ?) -V // >minus_plus <plus_minus_m_m // -Hid /3 width=5 by cpy_subst, ex2_intro/
 116 | #a #I #G #L #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 117   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 118   elim (IHV12 … HLK … HWV1) -V1 // #W2 #HW12 #HWV2
 119   elim (IHU12 … HTU1) -IHU12 -HTU1
 120   /3 width=5 by cpy_bind, ldrop_skip, lift_bind, le_S_S, ex2_intro/
 121 | #I #G #L #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 122   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 123   elim (IHV12 … HLK … HWV1) -V1 //
 124   elim (IHU12 … HLK … HTU1) -U1 -HLK
 125   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 126 ]
 127 qed-.
 128
 129 lemma cpy_inv_lift1_be: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 130                         ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 131                         dt ≤ d → d + e ≤ dt + et →
 132                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, et - e] T2 & ⇧[d, e] T2 ≡ U2.
 133 #G #L #U1 #U2 #dt #et #H elim H -G -L -U1 -U2 -dt -et
 134 [ * #G #L #i #dt #et #K #d #e #_ #T1 #H #_
 135   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by cpy_atom, lift_sort, ex2_intro/
 136   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by cpy_atom, lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 137   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by cpy_atom, lift_gref, ex2_intro/
 138   ]
 139 | #I #G #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdtd #Hdedet
 140   lapply (le_fwd_plus_plus_ge … Hdtd … Hdedet) #Heet
 141   elim (lift_inv_lref2 … H) -H * #Hid #H destruct
 142   [ -Hdtd -Hidet
 143     lapply (lt_to_le_to_lt … (dt + (et - e)) Hid ?) [ <le_plus_minus /2 width=1 by le_plus_to_minus_r/ ] -Hdedet #Hidete
 144     elim (ldrop_conf_lt … HLK … HLKV) -L // #L #U #HKL #_ #HUV
 145     elim (lift_trans_le … HUV … HVW) -V // >minus_plus <plus_minus_m_m // -Hid /3 width=5 by cpy_subst, ex2_intro/
 146   | -Hdti -Hdedet
 147     lapply (transitive_le … (i - e) Hdtd ?) /2 width=1 by le_plus_to_minus_r/ -Hdtd #Hdtie
 148     elim (le_inv_plus_l … Hid) #Hdie #Hei
 149     lapply (ldrop_conf_ge … HLK … HLKV ?) -L // #HKV
 150     elim (lift_split … HVW d (i-e+1)) -HVW [2,3,4: /2 width=1 by le_S_S, le_S/ ] -Hid -Hdie
 151     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O #H
 152     @(ex2_intro … H) @(cpy_subst … Hdtie … HKV HV1) (**) (* explicit constructor *)
 153     >commutative_plus >plus_minus /2 width=1 by monotonic_lt_minus_l/
 154   ]
 155 | #a #I #G #L #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdtd #Hdedet
 156   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 157   elim (IHV12 … HLK … HWV1) -V1 // #W2 #HW12 #HWV2
 158   elim (IHU12 … HTU1) -U1
 159   [5: /2 width=2 by ldrop_skip/ |2: skip
 160   |3: >plus_plus_comm_23 >(plus_plus_comm_23 dt) /2 width=1 by le_S_S/
 161   |4: /2 width=1 by le_S_S/
 162   ]
 163   /3 width=5 by cpy_bind, lift_bind, ex2_intro/
 164 | #I #G #L #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdtd #Hdedet
 165   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 166   elim (IHV12 … HLK … HWV1) -V1 //
 167   elim (IHU12 … HLK … HTU1) -U1 -HLK //
 168   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 169 ]
 170 qed-.
 171
 172 lemma cpy_inv_lift1_ge: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 173                         ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 174                         d + e ≤ dt →
 175                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt - e, et] T2 & ⇧[d, e] T2 ≡ U2.
 176 #G #L #U1 #U2 #dt #et #H elim H -G -L -U1 -U2 -dt -et
 177 [ * #G #L #i #dt #et #K #d #e #_ #T1 #H #_
 178   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by cpy_atom, lift_sort, ex2_intro/
 179   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct /3 width=3 by cpy_atom, lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 180   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by cpy_atom, lift_gref, ex2_intro/
 181   ]
 182 | #I #G #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdedt
 183   lapply (transitive_le … Hdedt … Hdti) #Hdei
 184   elim (le_inv_plus_l … Hdedt) -Hdedt #_ #Hedt
 185   elim (le_inv_plus_l … Hdei) #Hdie #Hei
 186   lapply (lift_inv_lref2_ge … H … Hdei) -H #H destruct
 187   lapply (ldrop_conf_ge … HLK … HLKV ?) -L // #HKV
 188   elim (lift_split … HVW d (i-e+1)) -HVW [2,3,4: /2 width=1 by le_S_S, le_S/ ] -Hdei -Hdie
 189   #V0 #HV10 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O #H
 190   @(ex2_intro … H) @(cpy_subst … HKV HV10) /2 width=1 by monotonic_le_minus_l2/ (**) (* explicit constructor *)
 191   >plus_minus /2 width=1 by monotonic_lt_minus_l/
 192 | #a #I #G #L #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 193   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 194   elim (le_inv_plus_l … Hdetd) #_ #Hedt
 195   elim (IHV12 … HLK … HWV1) -V1 // #W2 #HW12 #HWV2
 196   elim (IHU12 … HTU1) -U1 [4: @ldrop_skip // |2: skip |3: /2 width=1 by le_S_S/ ]
 197   <plus_minus /3 width=5 by cpy_bind, lift_bind, ex2_intro/
 198 | #I #G #L #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 199   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 200   elim (IHV12 … HLK … HWV1) -V1 //
 201   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 202 ]
 203 qed-.
 204
 205 lemma cpy_inv_lift1_eq: ∀G,L,U1,U2,d,e.
 206                         ⦃G, L⦄ ⊢ U1 ▶×[d, e] U2 → ∀T1. ⇧[d, e] T1 ≡ U1 → U1 = U2.
 207 #G #L #U1 #U2 #d #e #H elim H -G -L -U1 -U2 -d -e
 208 [ //
 209 | #I #G #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #T1 #H
 210   elim (lift_inv_lref2 … H) -H * #H
 211   [ lapply (le_to_lt_to_lt … Hdi … H) -Hdi -H #H
 212     elim (lt_refl_false … H)
 213   | lapply (lt_to_le_to_lt … Hide … H) -Hide -H #H
 214     elim (lt_refl_false … H)
 215   ]
 216 | #a #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 217   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #H destruct
 218   >IHV12 // >IHT12 //
 219 | #I #G #L #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 220   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #H destruct
 221   >IHV12 // >IHT12 //
 222 ]
 223 qed-.
 224
 225 lemma cpy_inv_lift1_ge_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 226                            ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 227                            d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
 228                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[d, dt + et - (d + e)] T2 & ⇧[d, e] T2 ≡ U2.
 229 #G #L #U1 #U2 #dt #et #HU12 #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet
 230 elim (cpy_split_up … HU12 (d + e)) -HU12 // -Hdedet #U #HU1 #HU2
 231 lapply (cpy_weak … HU1 d e ? ?) -HU1 // [ >commutative_plus /2 width=1 by le_minus_to_plus_r/ ] -Hddt -Hdtde #HU1
 232 lapply (cpy_inv_lift1_eq … HU1 … HTU1) -HU1 #HU1 destruct
 233 elim (cpy_inv_lift1_ge … HU2 … HLK … HTU1) -U -L // <minus_plus_m_m /2 width=3 by ex2_intro/
 234 qed-.
 235
 236 lemma cpy_inv_lift1_be_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 237                            ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 238                            dt ≤ d → dt + et ≤ d + e →
 239                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 240 #G #L #U1 #U2 #dt #et #HU12 #K #d #e #HLK #T1 #HTU1 #Hdtd #Hdetde
 241 lapply (cpy_weak … HU12 dt (d + e - dt) ? ?) -HU12 /2 width=3 by transitive_le, le_n/ -Hdetde #HU12
 242 elim (cpy_inv_lift1_be … HU12 … HLK … HTU1) -U1 -L /2 width=3 by ex2_intro/
 243 qed-.
 244
 245 lemma cpy_inv_lift1_le_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶×[dt, et] U2 →
 246                            ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 247                            dt ≤ d → d ≤ dt + et → dt + et ≤ d + e →
 248                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 249 #G #L #U1 #U2 #dt #et #HU12 #K #d #e #HLK #T1 #HTU1 #Hdtd #Hddet #Hdetde
 250 elim (cpy_split_up … HU12 d) -HU12 // #U #HU1 #HU2
 251 elim (cpy_inv_lift1_le … HU1 … HLK … HTU1) -U1 [2: >commutative_plus /2 width=1 by le_minus_to_plus_r/ ] -Hdtd #T #HT1 #HTU
 252 lapply (cpy_weak … HU2 d e ? ?) -HU2 // [ >commutative_plus <plus_minus_m_m // ] -Hddet -Hdetde #HU2
 253 lapply (cpy_inv_lift1_eq … HU2 … HTU) -L #H destruct /2 width=3 by ex2_intro/
 254 qed-.