matita/matita/contribs/lambdadelta/basic_2/relocation/fsup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/ldrop.ma".
  16
  17 (* SUPCLOSURE ***************************************************************)
  18
  19 inductive fsup: bi_relation lenv term ≝
  20 | fsup_lref   : ∀I,L,V. fsup (L.ⓑ{I}V) (#0) L V
  21 | fsup_pair_sn: ∀I,L,V,T. fsup L (②{I}V.T) L V
  22 | fsup_bind_dx: ∀a,I,L,V,T. fsup L (ⓑ{a,I}V.T) (L.ⓑ{I}V) T
  23 | fsup_flat_dx: ∀I,L,V,T.   fsup L (ⓕ{I}V.T) L T
  24 | fsup_ldrop  : ∀L1,K1,K2,T1,T2,U1,d,e.
  25                 ⇩[d, e] L1 ≡ K1 → ⇧[d, e] T1 ≡ U1 →
  26                 fsup K1 T1 K2 T2 → fsup L1 U1 K2 T2
  27 .
  28
  29 interpretation
  30    "structural successor (closure)"
  31    'SupTerm L1 T1 L2 T2 = (fsup L1 T1 L2 T2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma fsup_lref_S_lt: ∀I,L,K,V,T,i. 0 < i → ⦃L, #(i-1)⦄ ⊃ ⦃K, T⦄ → ⦃L.ⓑ{I}V, #i⦄ ⊃ ⦃K, T⦄.
  36 /3 width=7/ qed.
  37
  38 lemma fsup_lref: ∀I,K,V,i,L. ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃L, #i⦄ ⊃ ⦃K, V⦄.
  39 #I #K #V #i @(nat_elim1 i) -i #i #IH #L #H
  40 elim (ldrop_inv_O1_pair2 … H) -H *
  41 [ #H1 #H2 destruct //
  42 | #I1 #K1 #V1 #HK1 #H #Hi destruct
  43   lapply (IH … HK1) /2 width=1/
  44 ]
  45 qed.
  46
  47 (* Basic forward lemmas *****************************************************)
  48
  49 lemma fsup_fwd_cw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ♯{L2, T2} < ♯{L1, T1}.
  50 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 //
  51 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12
  52 lapply (ldrop_fwd_lw … HLK1) -HLK1 #HLK1
  53 lapply (lift_fwd_tw … HTU1) -HTU1 #HTU1
  54 @(lt_to_le_to_lt … IHT12) -IHT12 /2 width=1/
  55 qed-.
  56
  57 fact fsup_fwd_length_lref1_aux: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ∀i. T1 = #i → |L2| < |L1|.
  58 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2
  59 [5: #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #i #H destruct
  60     lapply (ldrop_fwd_length … HLK1) -HLK1 #HLK1
  61     elim (lift_inv_lref2 … HTU1) -HTU1 * #Hdei #H destruct
  62     @(lt_to_le_to_lt … HLK1) /2 width=2/
  63 | normalize // |3: #a
  64 ] #I #L #V #T #j #H destruct
  65 qed-.
  66
  67 lemma fsup_fwd_length_lref1: ∀L1,L2,T2,i. ⦃L1, #i⦄ ⊃ ⦃L2, T2⦄ → |L2| < |L1|.
  68 /2 width=5 by fsup_fwd_length_lref1_aux/
  69 qed-.