matita/matita/contribs/lambdadelta/basic_2/relocation/fsup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/cl_weight.ma".
  16 include "basic_2/relocation/ldrop.ma".
  17
  18 (* SUPCLOSURE ***************************************************************)
  19
  20 inductive fsup: bi_relation lenv term ≝
  21 | fsup_lref_O  : ∀I,L,V. fsup (L.ⓑ{I}V) (#0) L V
  22 | fsup_pair_sn : ∀I,L,V,T. fsup L (②{I}V.T) L V
  23 | fsup_bind_dx : ∀a,I,L,V,T. fsup L (ⓑ{a,I}V.T) (L.ⓑ{I}V) T
  24 | fsup_flat_dx : ∀I,L,V,T.   fsup L (ⓕ{I}V.T) L T
  25 | fsup_ldrop_lt: ∀L,K,T,U,d,e.
  26                  ⇩[d, e] L ≡ K → ⇧[d, e] T ≡ U → |K| < |L| → fsup L U K T
  27 | fsup_ldrop   : ∀L1,K1,K2,T1,T2,U1,d,e.
  28                  ⇩[d, e] L1 ≡ K1 → ⇧[d, e] T1 ≡ U1 →
  29                  fsup K1 T1 K2 T2 → fsup L1 U1 K2 T2
  30 .
  31
  32 interpretation
  33    "structural successor (closure)"
  34    'SupTerm L1 T1 L2 T2 = (fsup L1 T1 L2 T2).
  35
  36 (* Basic properties *********************************************************)
  37
  38 lemma fsup_lref_S_lt: ∀I,L,K,V,T,i. 0 < i → ⦃L, #(i-1)⦄ ⊃ ⦃K, T⦄ → ⦃L.ⓑ{I}V, #i⦄ ⊃ ⦃K, T⦄.
  39 /3 width=7/ qed.
  40
  41 lemma fsup_lref: ∀I,K,V,i,L. ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃L, #i⦄ ⊃ ⦃K, V⦄.
  42 #I #K #V #i @(nat_elim1 i) -i #i #IH #L #H
  43 elim (ldrop_inv_O1_pair2 … H) -H *
  44 [ #H1 #H2 destruct //
  45 | #I1 #K1 #V1 #HK1 #H #Hi destruct
  46   lapply (IH … HK1) /2 width=1/
  47 ]
  48 qed.
  49
  50 (* Basic forward lemmas *****************************************************)
  51
  52 lemma fsup_fwd_fw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ♯{L2, T2} < ♯{L1, T1}.
  53 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 //
  54 [ #L #K #T #U #d #e #HLK #HTU #HKL
  55   lapply (ldrop_fwd_lw_lt … HLK HKL) -HKL -HLK #HKL
  56   lapply (lift_fwd_tw … HTU) -d -e #H
  57   normalize in ⊢ (?%%); /2 width=1/
  58 | #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12
  59   lapply (ldrop_fwd_lw … HLK1) -HLK1 #HLK1
  60   lapply (lift_fwd_tw … HTU1) -HTU1 #HTU1
  61   @(lt_to_le_to_lt … IHT12) -IHT12 /2 width=1/
  62 ]
  63 qed-.
  64
  65 fact fsup_fwd_length_lref1_aux: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ →
  66                                 ∀i. T1 = #i → |L2| < |L1|.
  67 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2
  68 [1,5:  normalize //
  69 |3: #a
  70 |6: #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #i #H destruct
  71     lapply (ldrop_fwd_length … HLK1) -HLK1 #HLK1
  72     elim (lift_inv_lref2 … HTU1) -HTU1 * #Hdei #H destruct
  73     @(lt_to_le_to_lt … HLK1) /2 width=2/
  74 ] #I #L #V #T #j #H destruct
  75 qed-.
  76
  77 lemma fsup_fwd_length_lref1: ∀L1,L2,T2,i. ⦃L1, #i⦄ ⊃ ⦃L2, T2⦄ → |L2| < |L1|.
  78 /2 width=5 by fsup_fwd_length_lref1_aux/
  79 qed-.