matita/matita/contribs/lambdadelta/basic_2/relocation/ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/lstar.ma".
  16 include "basic_2/notation/relations/rdrop_4.ma".
  17 include "basic_2/grammar/lenv_length.ma".
  18 include "basic_2/grammar/cl_restricted_weight.ma".
  19 include "basic_2/relocation/lift.ma".
  20
  21 (* LOCAL ENVIRONMENT SLICING ************************************************)
  22
  23 (* Basic_1: includes: drop_skip_bind *)
  24 inductive ldrop: relation4 nat nat lenv lenv ≝
  25 | ldrop_atom : ∀d. ldrop d 0 (⋆) (⋆)
  26 | ldrop_pair : ∀L,I,V. ldrop 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  27 | ldrop_ldrop: ∀L1,L2,I,V,e. ldrop 0 e L1 L2 → ldrop 0 (e + 1) (L1. ⓑ{I} V) L2
  28 | ldrop_skip : ∀L1,L2,I,V1,V2,d,e.
  29                ldrop d e L1 L2 → ⇧[d,e] V2 ≡ V1 →
  30                ldrop (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  31 .
  32
  33 interpretation "local slicing" 'RDrop d e L1 L2 = (ldrop d e L1 L2).
  34
  35 definition l_liftable: predicate (lenv → relation term) ≝
  36                        λR. ∀K,T1,T2. R K T1 T2 → ∀L,d,e. ⇩[d, e] L ≡ K →
  37                        ∀U1. ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 → R L U1 U2.
  38
  39 definition l_deliftable_sn: predicate (lenv → relation term) ≝
  40                             λR. ∀L,U1,U2. R L U1 U2 → ∀K,d,e. ⇩[d, e] L ≡ K →
  41                             ∀T1. ⇧[d, e] T1 ≡ U1 →
  42                             ∃∃T2. ⇧[d, e] T2 ≡ U2 & R K T1 T2.
  43
  44 definition dropable_sn: predicate (relation lenv) ≝
  45                         λR. ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀L2. R L1 L2 →
  46                         ∃∃K2. R K1 K2 & ⇩[d, e] L2 ≡ K2.
  47
  48 definition dedropable_sn: predicate (relation lenv) ≝
  49                           λR. ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀K2. R K1 K2 →
  50                           ∃∃L2. R L1 L2 & ⇩[d, e] L2 ≡ K2.
  51
  52 definition dropable_dx: predicate (relation lenv) ≝
  53                         λR. ∀L1,L2. R L1 L2 → ∀K2,e. ⇩[0, e] L2 ≡ K2 →
  54                         ∃∃K1. ⇩[0, e] L1 ≡ K1 & R K1 K2.
  55
  56 (* Basic inversion lemmas ***************************************************)
  57
  58 fact ldrop_inv_atom1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → L1 = ⋆ →
  59                           L2 = ⋆ ∧ e = 0.
  60 #d #e #L1 #L2 * -d -e -L1 -L2
  61 [ /2 width=1/
  62 | #L #I #V #H destruct
  63 | #L1 #L2 #I #V #e #_ #H destruct
  64 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  65 ]
  66 qed-.
  67
  68 (* Basic_1: was: drop_gen_sort *)
  69 lemma ldrop_inv_atom1: ∀d,e,L2. ⇩[d, e] ⋆ ≡ L2 → L2 = ⋆ ∧ e = 0.
  70 /2 width=4 by ldrop_inv_atom1_aux/ qed-.
  71
  72 fact ldrop_inv_O1_pair1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → d = 0 →
  73                              ∀K,I,V. L1 = K. ⓑ{I} V →
  74                              (e = 0 ∧ L2 = K. ⓑ{I} V) ∨
  75                              (0 < e ∧ ⇩[d, e - 1] K ≡ L2).
  76 #d #e #L1 #L2 * -d -e -L1 -L2
  77 [ #d #_ #K #I #V #H destruct
  78 | #L #I #V #_ #K #J #W #HX destruct /3 width=1/
  79 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct /3 width=1/
  80 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  81 ]
  82 qed-.
  83
  84 lemma ldrop_inv_O1_pair1: ∀e,K,I,V,L2. ⇩[0, e] K. ⓑ{I} V ≡ L2 →
  85                           (e = 0 ∧ L2 = K. ⓑ{I} V) ∨
  86                           (0 < e ∧ ⇩[0, e - 1] K ≡ L2).
  87 /2 width=3 by ldrop_inv_O1_pair1_aux/ qed-.
  88
  89 lemma ldrop_inv_pair1: ∀K,I,V,L2. ⇩[0, 0] K. ⓑ{I} V ≡ L2 → L2 = K. ⓑ{I} V.
  90 #K #I #V #L2 #H
  91 elim (ldrop_inv_O1_pair1 … H) -H * // #H destruct
  92 elim (lt_refl_false … H)
  93 qed-.
  94
  95 (* Basic_1: was: drop_gen_drop *)
  96 lemma ldrop_inv_ldrop1: ∀e,K,I,V,L2.
  97                         ⇩[0, e] K. ⓑ{I} V ≡ L2 → 0 < e → ⇩[0, e - 1] K ≡ L2.
  98 #e #K #I #V #L2 #H #He
  99 elim (ldrop_inv_O1_pair1 … H) -H * // #H destruct
 100 elim (lt_refl_false … He)
 101 qed-.
 102
 103 fact ldrop_inv_skip1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → 0 < d →
 104                           ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
 105                           ∃∃K2,V2. ⇩[d - 1, e] K1 ≡ K2 &
 106                                    ⇧[d - 1, e] V2 ≡ V1 &
 107                                    L2 = K2. ⓑ{I} V2.
 108 #d #e #L1 #L2 * -d -e -L1 -L2
 109 [ #d #_ #I #K #V #H destruct
 110 | #L #I #V #H elim (lt_refl_false … H)
 111 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 112 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct /2 width=5/
 113 ]
 114 qed-.
 115
 116 (* Basic_1: was: drop_gen_skip_l *)
 117 lemma ldrop_inv_skip1: ∀d,e,I,K1,V1,L2. ⇩[d, e] K1. ⓑ{I} V1 ≡ L2 → 0 < d →
 118                        ∃∃K2,V2. ⇩[d - 1, e] K1 ≡ K2 &
 119                                 ⇧[d - 1, e] V2 ≡ V1 &
 120                                 L2 = K2. ⓑ{I} V2.
 121 /2 width=3 by ldrop_inv_skip1_aux/ qed-.
 122
 123 lemma ldrop_inv_O1_pair2: ∀I,K,V,e,L1. ⇩[0, e] L1 ≡ K. ⓑ{I} V →
 124                           (e = 0 ∧ L1 = K. ⓑ{I} V) ∨
 125                           ∃∃I1,K1,V1. ⇩[0, e - 1] K1 ≡ K. ⓑ{I} V & L1 = K1.ⓑ{I1}V1 & 0 < e.
 126 #I #K #V #e *
 127 [ #H elim (ldrop_inv_atom1 … H) -H #H destruct
 128 | #L1 #I1 #V1 #H
 129   elim (ldrop_inv_O1_pair1 … H) -H *
 130   [ #H1 #H2 destruct /3 width=1/
 131   | /3 width=5/
 132   ]
 133 ]
 134 qed-.
 135
 136 fact ldrop_inv_skip2_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → 0 < d →
 137                           ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 138                           ∃∃K1,V1. ⇩[d - 1, e] K1 ≡ K2 &
 139                                    ⇧[d - 1, e] V2 ≡ V1 &
 140                                    L1 = K1. ⓑ{I} V1.
 141 #d #e #L1 #L2 * -d -e -L1 -L2
 142 [ #d #_ #I #K #V #H destruct
 143 | #L #I #V #H elim (lt_refl_false … H)
 144 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 145 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct /2 width=5/
 146 ]
 147 qed-.
 148
 149 (* Basic_1: was: drop_gen_skip_r *)
 150 lemma ldrop_inv_skip2: ∀d,e,I,L1,K2,V2. ⇩[d, e] L1 ≡ K2. ⓑ{I} V2 → 0 < d →
 151                        ∃∃K1,V1. ⇩[d - 1, e] K1 ≡ K2 & ⇧[d - 1, e] V2 ≡ V1 &
 152                                 L1 = K1. ⓑ{I} V1.
 153 /2 width=3 by ldrop_inv_skip2_aux/ qed-.
 154
 155 (* Basic properties *********************************************************)
 156
 157 (* Basic_1: was by definition: drop_refl *)
 158 lemma ldrop_refl: ∀L,d. ⇩[d, 0] L ≡ L.
 159 #L elim L -L //
 160 #L #I #V #IHL #d @(nat_ind_plus … d) -d // /2 width=1/
 161 qed.
 162
 163 lemma ldrop_ldrop_lt: ∀L1,L2,I,V,e.
 164                       ⇩[0, e - 1] L1 ≡ L2 → 0 < e → ⇩[0, e] L1. ⓑ{I} V ≡ L2.
 165 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) // /2 width=1/
 166 qed.
 167
 168 lemma ldrop_skip_lt: ∀L1,L2,I,V1,V2,d,e.
 169                      ⇩[d - 1, e] L1 ≡ L2 → ⇧[d - 1, e] V2 ≡ V1 → 0 < d →
 170                      ⇩[d, e] L1. ⓑ{I} V1 ≡ L2. ⓑ{I} V2.
 171 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV21 #Hd >(plus_minus_m_m d 1) // /2 width=1/
 172 qed.
 173
 174 lemma ldrop_O1_le: ∀e,L. e ≤ |L| → ∃K. ⇩[0, e] L ≡ K.
 175 #e @(nat_ind_plus … e) -e /2 width=2/
 176 #e #IHe *
 177 [ #H lapply (le_n_O_to_eq … H) -H >commutative_plus normalize #H destruct
 178 | #L #I #V normalize #H
 179   elim (IHe L) -IHe /2 width=1/ -H /3 width=2/
 180 ]
 181 qed.
 182
 183 lemma ldrop_O1_lt: ∀L,e. e < |L| → ∃∃I,K,V. ⇩[0, e] L ≡ K.ⓑ{I}V.
 184 #L elim L -L
 185 [ #e #H elim (lt_zero_false … H)
 186 | #L #I #V #IHL #e @(nat_ind_plus … e) -e /2 width=4/
 187   #e #_ normalize #H
 188   elim (IHL e) -IHL /2 width=1/ -H /3 width=4/
 189 ]
 190 qed.
 191
 192 lemma l_liftable_LTC: ∀R. l_liftable R → l_liftable (LTC … R).
 193 #R #HR #K #T1 #T2 #H elim H -T2
 194 [ /3 width=9/
 195 | #T #T2 #_ #HT2 #IHT1 #L #d #e #HLK #U1 #HTU1 #U2 #HTU2
 196   elim (lift_total T d e) /4 width=11 by step/ (**) (* auto too slow without trace *)
 197 ]
 198 qed.
 199
 200 lemma l_deliftable_sn_LTC: ∀R. l_deliftable_sn R → l_deliftable_sn (LTC … R).
 201 #R #HR #L #U1 #U2 #H elim H -U2
 202 [ #U2 #HU12 #K #d #e #HLK #T1 #HTU1
 203   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3/
 204 | #U #U2 #_ #HU2 #IHU1 #K #d #e #HLK #T1 #HTU1
 205   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 206   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5/
 207 ]
 208 qed.
 209
 210 lemma dropable_sn_TC: ∀R. dropable_sn R → dropable_sn (TC … R).
 211 #R #HR #L1 #K1 #d #e #HLK1 #L2 #H elim H -L2
 212 [ #L2 #HL12
 213   elim (HR … HLK1 … HL12) -HR -L1 /3 width=3/
 214 | #L #L2 #_ #HL2 * #K #HK1 #HLK
 215   elim (HR … HLK … HL2) -HR -L /3 width=3/
 216 ]
 217 qed.
 218
 219 lemma dedropable_sn_TC: ∀R. dedropable_sn R → dedropable_sn (TC … R).
 220 #R #HR #L1 #K1 #d #e #HLK1 #K2 #H elim H -K2
 221 [ #K2 #HK12
 222   elim (HR … HLK1 … HK12) -HR -K1 /3 width=3/
 223 | #K #K2 #_ #HK2 * #L #HL1 #HLK
 224   elim (HR … HLK … HK2) -HR -K /3 width=3/
 225 ]
 226 qed.
 227
 228 lemma dropable_dx_TC: ∀R. dropable_dx R → dropable_dx (TC … R).
 229 #R #HR #L1 #L2 #H elim H -L2
 230 [ #L2 #HL12 #K2 #e #HLK2
 231   elim (HR … HL12 … HLK2) -HR -L2 /3 width=3/
 232 | #L #L2 #_ #HL2 #IHL1 #K2 #e #HLK2
 233   elim (HR … HL2 … HLK2) -HR -L2 #K #HLK #HK2
 234   elim (IHL1 … HLK) -L /3 width=5/
 235 ]
 236 qed.
 237
 238 lemma l_deliftable_sn_llstar: ∀R. l_deliftable_sn R →
 239                               ∀l. l_deliftable_sn (llstar … R l).
 240 #R #HR #l #L #U1 #U2 #H @(lstar_ind_r … l U2 H) -l -U2
 241 [ /2 width=3/
 242 | #l #U #U2 #_ #HU2 #IHU1 #K #d #e #HLK #T1 #HTU1
 243   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 244   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5/
 245 ]
 246 qed.
 247
 248 (* Basic forvard lemmas *****************************************************)
 249
 250 (* Basic_1: was: drop_S *)
 251 lemma ldrop_fwd_ldrop2: ∀L1,I2,K2,V2,e. ⇩[O, e] L1 ≡ K2. ⓑ{I2} V2 →
 252                         ⇩[O, e + 1] L1 ≡ K2.
 253 #L1 elim L1 -L1
 254 [ #I2 #K2 #V2 #e #H lapply (ldrop_inv_atom1 … H) -H * #H destruct
 255 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 256   elim (ldrop_inv_O1_pair1 … H) -H * #He #H
 257   [ -IHL1 destruct /2 width=1/
 258   | @ldrop_ldrop >(plus_minus_m_m e 1) // /2 width=3/
 259   ]
 260 ]
 261 qed-.
 262
 263 lemma ldrop_fwd_length: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L1| = |L2| + e.
 264 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize /2 width=1/
 265 qed-.
 266
 267 lemma ldrop_fwd_length_minus2: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L2| = |L1| - e.
 268 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H /2 width=1/
 269 qed-.
 270
 271 lemma ldrop_fwd_length_minus4: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → e = |L1| - |L2|.
 272 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 273 qed-.
 274
 275 lemma ldrop_fwd_length_le2: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → e ≤ |L1|.
 276 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 277 qed-.
 278
 279 lemma ldrop_fwd_length_le4: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L2| ≤ |L1|.
 280 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 281 qed-.
 282
 283 lemma ldrop_fwd_length_lt2: ∀L1,I2,K2,V2,d,e.
 284                             ⇩[d, e] L1 ≡ K2. ⓑ{I2} V2 → e < |L1|.
 285 #L1 #I2 #K2 #V2 #d #e #H
 286 lapply (ldrop_fwd_length … H) normalize in ⊢ (%→?); -I2 -V2 //
 287 qed-.
 288
 289 lemma ldrop_fwd_length_lt4: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → 0 < e → |L2| < |L1|.
 290 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H /2 width=1/
 291 qed-.
 292
 293 lemma ldrop_fwd_length_eq: ∀L1,L2,K1,K2,d,e. ⇩[d, e] L1 ≡ K1 → ⇩[d, e] L2 ≡ K2 →
 294                            |L1| = |L2| → |K1| = |K2|.
 295 #L1 #L2 #K1 #K2 #d #e #HLK1 #HLK2 #HL12
 296 lapply (ldrop_fwd_length … HLK1) -HLK1
 297 lapply (ldrop_fwd_length … HLK2) -HLK2
 298 /2 width=2 by injective_plus_r/ (**) (* full auto fails *)
 299 qed-.
 300
 301 lemma ldrop_fwd_lw: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → ♯{L2} ≤ ♯{L1}.
 302 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize
 303 [ /2 width=3/
 304 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12
 305   >(lift_fwd_tw … HV21) -HV21 /2 width=1/
 306 ]
 307 qed-.
 308
 309 lemma ldrop_fwd_lw_lt: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → 0 < e → ♯{L2} < ♯{L1}.
 310 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e //
 311 [ #L #I #V #H elim (lt_refl_false … H)
 312 | #L1 #L2 #I #V #e #HL12 #_ #_
 313   lapply (ldrop_fwd_lw … HL12) -HL12 #HL12
 314   @(le_to_lt_to_lt … HL12) -HL12 //
 315 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12 #H normalize in ⊢ (?%%); -I
 316   >(lift_fwd_tw … HV21) -V2 /3 by lt_minus_to_plus/ (**) (* auto too slow without trace *)
 317 ]
 318 qed-.
 319
 320 lemma ldrop_fwd_rfw: ∀I,L,K,V,i. ⇩[O, i] L ≡ K.ⓑ{I}V → ♯{K, V} < ♯{L, #i}.
 321 #I #L #K #V #i #HLK lapply (ldrop_fwd_lw … HLK) -HLK
 322 normalize in ⊢ (%→?%%); /2 width=1 by le_S_S/
 323 qed-.
 324
 325 (* Advanced inversion lemmas ************************************************)
 326
 327 fact ldrop_inv_O2_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → e = 0 → L1 = L2.
 328 #d #e #L1 #L2 #H elim H -d -e -L1 -L2
 329 [ //
 330 | //
 331 | #L1 #L2 #I #V #e #_ #_ >commutative_plus normalize #H destruct
 332 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12 #H
 333   >(IHL12 H) -L1 >(lift_inv_O2_aux … HV21 … H) -V2 -d -e //
 334 ]
 335 qed-.
 336
 337 (* Basic_1: was: drop_gen_refl *)
 338 lemma ldrop_inv_O2: ∀L1,L2,d. ⇩[d, 0] L1 ≡ L2 → L1 = L2.
 339 /2 width=4 by ldrop_inv_O2_aux/ qed-.
 340
 341 lemma ldrop_inv_length_eq: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L1| = |L2| → e = 0.
 342 #L1 #L2 #d #e #H #HL12 lapply (ldrop_fwd_length_minus4 … H) //
 343 qed-.
 344
 345 lemma ldrop_inv_refl: ∀L,d,e. ⇩[d, e] L ≡ L → e = 0.
 346 /2 width=5 by ldrop_inv_length_eq/ qed-.
 347
 348 (* Basic_1: removed theorems 50:
 349             drop_ctail drop_skip_flat
 350             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 351             drop_clear drop_clear_O drop_clear_S
 352             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 353             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 354             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 355             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 356             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 357             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 358             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 359             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 360             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 361 *)