matita/matita/contribs/lambdadelta/basic_2/relocation/ldrop_append.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_append.ma".
  16 include "basic_2/relocation/ldrop.ma".
  17
  18 (* DROPPING *****************************************************************)
  19
  20 (* Properties on append for local environments ******************************)
  21
  22 fact ldrop_O1_append_sn_le_aux: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 →
  23                                 d = 0 → e ≤ |L1| →
  24                                 ∀L. ⇩[0, e] L @@ L1 ≡ L @@ L2.
  25 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e normalize
  26 /4 width=1 by ldrop_skip_lt, ldrop_ldrop, arith_b1, lt_minus_to_plus_r, monotonic_pred/
  27 qed-.
  28
  29 lemma ldrop_O1_append_sn_le: ∀L1,L2,e. ⇩[0, e] L1 ≡ L2 → e ≤ |L1| →
  30                              ∀L. ⇩[0, e] L @@ L1 ≡ L @@ L2.
  31 /2 width=3 by ldrop_O1_append_sn_le_aux/ qed.
  32
  33 (* Inversion lemmas on append for local environments ************************)
  34
  35 lemma ldrop_O1_inv_append1_ge: ∀K,L1,L2,e. ⇩[0, e] L1 @@ L2 ≡ K →
  36                                |L2| ≤ e → ⇩[0, e - |L2|] L1 ≡ K.
  37 #K #L1 #L2 elim L2 -L2 normalize //
  38 #L2 #I #V #IHL2 #e #H #H1e
  39 elim (ldrop_inv_O1_pair1 … H) -H * #H2e #HL12 destruct
  40 [ lapply (le_n_O_to_eq … H1e) -H1e -IHL2
  41   >commutative_plus normalize #H destruct
  42 | <minus_plus >minus_minus_comm /3 width=1 by monotonic_pred/
  43 ]
  44 qed-.
  45
  46 lemma ldrop_O1_inv_append1_le: ∀K,L1,L2,e. ⇩[0, e] L1 @@ L2 ≡ K → e ≤ |L2| →
  47                                ∀K2. ⇩[0, e] L2 ≡ K2 → K = L1 @@ K2.
  48 #K #L1 #L2 elim L2 -L2 normalize
  49 [ #e #H1 #H2 #K2 #H3
  50   lapply (le_n_O_to_eq … H2) -H2 #H2
  51   elim (ldrop_inv_atom1 … H3) -H3 #H3 #_ destruct
  52   >(ldrop_inv_O2 … H1) -H1 //
  53 | #L2 #I #V #IHL2 #e @(nat_ind_plus … e) -e [ -IHL2 ]
  54   [ #H1 #_ #K2 #H2
  55     lapply (ldrop_inv_O2 … H1) -H1 #H1
  56     lapply (ldrop_inv_O2 … H2) -H2 #H2 destruct //
  57   | /4 width=6 by ldrop_inv_ldrop1, le_plus_to_le_r/
  58   ]
  59 ]
  60 qed-.