matita/matita/contribs/lambdadelta/basic_2/relocation/llpx_sn_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lift_neg.ma".
  16 include "basic_2/relocation/ldrop_ldrop.ma".
  17 include "basic_2/relocation/llpx_sn.ma".
  18
  19 (* LAZY SN POINTWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS ****)
  20
  21 (* alternative definition of llpx_sn_alt *)
  22 inductive llpx_sn_alt (R:relation3 lenv term term): relation4 ynat term lenv lenv ≝
  23 | llpx_sn_alt_intro: ∀L1,L2,T,d.
  24                      (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
  25                         ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 → I1 = I2 ∧ R K1 V1 V2
  26                      ) →
  27                      (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
  28                         ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 → llpx_sn_alt R 0 V1 K1 K2
  29                      ) → |L1| = |L2| → llpx_sn_alt R d T L1 L2
  30 .
  31
  32 (* Basic inversion lemmas ****************************************************)
  33
  34 lemma llpx_sn_alt_inv_gen: ∀R,L1,L2,T,d. llpx_sn_alt R d T L1 L2 →
  35                            |L1| = |L2| ∧
  36                            ∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
  37                            ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
  38                            ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn_alt R 0 V1 K1 K2.
  39 #R #L1 #L2 #T #d * -L1 -L2 -T -d
  40 #L1 #L2 #T #d #IH1 #IH2 #HL12 @conj //
  41 #I1 #I2 #K1 #K2 #HLK1 #HLK2 #i #Hid #HnT #HLK1 #HLK2
  42 elim (IH1 … HnT HLK1 HLK2) -IH1 /4 width=8 by and3_intro/
  43 qed-.
  44
  45 lemma llpx_sn_alt_inv_flat: ∀R,I,L1,L2,V,T,d. llpx_sn_alt R d (ⓕ{I}V.T) L1 L2 →
  46                             llpx_sn_alt R d V L1 L2 ∧ llpx_sn_alt R d T L1 L2.
  47 #R #I #L1 #L2 #V #T #d #H elim (llpx_sn_alt_inv_gen … H) -H
  48 #HL12 #IH @conj @llpx_sn_alt_intro // -HL12
  49 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hdi #H #HLK1 #HLK2
  50 elim (IH … HLK1 HLK2) -IH -HLK1 -HLK2
  51 /3 width=8 by nlift_flat_sn, nlift_flat_dx, conj/
  52 qed-.
  53
  54 lemma llpx_sn_alt_inv_bind: ∀R,a,I,L1,L2,V,T,d. llpx_sn_alt R d (ⓑ{a,I}V.T) L1 L2 →
  55                             llpx_sn_alt R d V L1 L2 ∧ llpx_sn_alt R (⫯d) T (L1.ⓑ{I}V) (L2.ⓑ{I}V).
  56 #R #a #I #L1 #L2 #V #T #d #H elim (llpx_sn_alt_inv_gen … H) -H
  57 #HL12 #IH @conj @llpx_sn_alt_intro [3,6: normalize // ] -HL12
  58 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hdi #H #HLK1 #HLK2
  59 [1,2: elim (IH … HLK1 HLK2) -IH -HLK1 -HLK2
  60   /3 width=9 by nlift_bind_sn, conj/
  61 |3,4: lapply (yle_inv_succ1 … Hdi) -Hdi * #Hdi #Hi
  62   lapply (ldrop_inv_drop1_lt … HLK1 ?) -HLK1 /2 width=1 by ylt_O/ #HLK1
  63   lapply (ldrop_inv_drop1_lt … HLK2 ?) -HLK2 /2 width=1 by ylt_O/ #HLK2
  64   elim (IH … HLK1 HLK2) -IH -HLK1 -HLK2
  65   [1,3,4,6: /2 width=1 by conj/ ]
  66   @nlift_bind_dx <plus_minus_m_m /2 width=2 by ylt_O/
  67 ]
  68 qed-.
  69
  70 (* Basic forward lemmas ******************************************************)
  71
  72 lemma llpx_sn_alt_fwd_length: ∀R,L1,L2,T,d. llpx_sn_alt R d T L1 L2 → |L1| = |L2|.
  73 #R #L1 #L2 #T #d * -L1 -L2 -T -d //
  74 qed-.
  75
  76 lemma llpx_sn_alt_fwd_lref: ∀R,L1,L2,d,i. llpx_sn_alt R d (#i) L1 L2 →
  77                             ∨∨ |L1| ≤ i ∧ |L2| ≤ i
  78                              | yinj i < d
  79                              | ∃∃I,K1,K2,V1,V2. ⇩[i] L1 ≡ K1.ⓑ{I}V1 &
  80                                                 ⇩[i] L2 ≡ K2.ⓑ{I}V2 &
  81                                                 llpx_sn_alt R (yinj 0) V1 K1 K2 &
  82                                                 R K1 V1 V2 & d ≤ yinj i.
  83 #R #L1 #L2 #d #i #H elim (llpx_sn_alt_inv_gen … H) -H
  84 #HL12 #IH elim (lt_or_ge i (|L1|)) /3 width=1 by or3_intro0, conj/
  85 elim (ylt_split i d) /3 width=1 by or3_intro1/
  86 #Hdi #HL1 elim (ldrop_O1_lt … HL1)
  87 #I1 #K1 #V1 #HLK1 elim (ldrop_O1_lt L2 i) //
  88 #I2 #K2 #V2 #HLK2 elim (IH … HLK1 HLK2) -IH
  89 /3 width=9 by nlift_lref_be_SO, or3_intro2, ex5_5_intro/
  90 qed-.
  91
  92 (* Basic properties **********************************************************)
  93
  94 lemma llpx_sn_alt_intro_alt: ∀R,L1,L2,T,d. |L1| = |L2| →
  95                              (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
  96                                 ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
  97                                 ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn_alt R 0 V1 K1 K2
  98                              ) → llpx_sn_alt R d T L1 L2.
  99 #R #L1 #L2 #T #d #HL12 #IH @llpx_sn_alt_intro // -HL12
 100 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hid #HnT #HLK1 #HLK2
 101 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /2 width=1 by conj/
 102 qed.
 103
 104 lemma llpx_sn_alt_sort: ∀R,L1,L2,d,k. |L1| = |L2| → llpx_sn_alt R d (⋆k) L1 L2.
 105 #R #L1 #L2 #d #k #HL12 @llpx_sn_alt_intro_alt // -HL12
 106 #I1 #I2 #K1 #K2 #V1 #V2 #i #_ #H elim (H (⋆k)) //
 107 qed.
 108
 109 lemma llpx_sn_alt_gref: ∀R,L1,L2,d,p. |L1| = |L2| → llpx_sn_alt R d (§p) L1 L2.
 110 #R #L1 #L2 #d #p #HL12 @llpx_sn_alt_intro_alt // -HL12
 111 #I1 #I2 #K1 #K2 #V1 #V2 #i #_ #H elim (H (§p)) //
 112 qed.
 113
 114 lemma llpx_sn_alt_skip: ∀R,L1,L2,d,i. |L1| = |L2| → yinj i < d → llpx_sn_alt R d (#i) L1 L2.
 115 #R #L1 #L2 #d #i #HL12 #Hid @llpx_sn_alt_intro_alt // -HL12
 116 #I1 #I2 #K1 #K2 #V1 #V2 #j #Hdj #H elim (H (#i)) -H
 117 /4 width=3 by lift_lref_lt, ylt_yle_trans, ylt_inv_inj/
 118 qed.
 119
 120 lemma llpx_sn_alt_free: ∀R,L1,L2,d,i. |L1| ≤ i → |L2| ≤ i → |L1| = |L2| →
 121                         llpx_sn_alt R d (#i) L1 L2.
 122 #R #L1 #L2 #d #i #HL1 #_ #HL12 @llpx_sn_alt_intro_alt // -HL12
 123 #I1 #I2 #K1 #K2 #V1 #V2 #j #_ #H #HLK1 elim (H (#(i-1))) -H
 124 lapply (ldrop_fwd_length_lt2 … HLK1) -HLK1
 125 /3 width=3 by lift_lref_ge_minus, lt_to_le_to_lt/
 126 qed.
 127
 128 lemma llpx_sn_alt_lref: ∀R,I,L1,L2,K1,K2,V1,V2,d,i. d ≤ yinj i →
 129                         ⇩[i] L1 ≡ K1.ⓑ{I}V1 → ⇩[i] L2 ≡ K2.ⓑ{I}V2 →
 130                         llpx_sn_alt R 0 V1 K1 K2 → R K1 V1 V2 →
 131                         llpx_sn_alt R d (#i) L1 L2.
 132 #R #I #L1 #L2 #K1 #K2 #V1 #V2 #d #i #Hdi #HLK1 #HLK2 #HK12 #HV12 @llpx_sn_alt_intro_alt
 133 [ lapply (llpx_sn_alt_fwd_length … HK12) -HK12 #HK12
 134   @(ldrop_fwd_length_eq2 … HLK1 HLK2) normalize //
 135 | #Z1 #Z2 #Y1 #Y2 #X1 #X2 #j #Hdj #H #HLY1 #HLY2
 136   elim (lt_or_eq_or_gt i j) #Hij destruct
 137   [ elim (H (#i)) -H /2 width=1 by lift_lref_lt/
 138   | lapply (ldrop_mono … HLY1 … HLK1) -HLY1 -HLK1 #H destruct
 139     lapply (ldrop_mono … HLY2 … HLK2) -HLY2 -HLK2 #H destruct /2 width=1 by and3_intro/
 140   | elim (H (#(i-1))) -H /2 width=1 by lift_lref_ge_minus/
 141   ]
 142 ]
 143 qed.
 144
 145 lemma llpx_sn_alt_flat: ∀R,I,L1,L2,V,T,d.
 146                         llpx_sn_alt R d V L1 L2 → llpx_sn_alt R d T L1 L2 →
 147                         llpx_sn_alt R d (ⓕ{I}V.T) L1 L2.
 148 #R #I #L1 #L2 #V #T #d #HV #HT
 149 elim (llpx_sn_alt_inv_gen … HV) -HV #HL12 #IHV
 150 elim (llpx_sn_alt_inv_gen … HT) -HT #_ #IHT
 151 @llpx_sn_alt_intro_alt // -HL12
 152 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hdi #HnVT #HLK1 #HLK2
 153 elim (nlift_inv_flat … HnVT) -HnVT #H
 154 [ elim (IHV … HLK1 … HLK2) -IHV /2 width=2 by and3_intro/
 155 | elim (IHT … HLK1 … HLK2) -IHT /3 width=2 by and3_intro/
 156 ]
 157 qed.
 158
 159 lemma llpx_sn_alt_bind: ∀R,a,I,L1,L2,V,T,d.
 160                         llpx_sn_alt R d V L1 L2 →
 161                         llpx_sn_alt R (⫯d) T (L1.ⓑ{I}V) (L2.ⓑ{I}V) →
 162                         llpx_sn_alt R d (ⓑ{a,I}V.T) L1 L2.
 163 #R #a #I #L1 #L2 #V #T #d #HV #HT
 164 elim (llpx_sn_alt_inv_gen … HV) -HV #HL12 #IHV
 165 elim (llpx_sn_alt_inv_gen … HT) -HT #_ #IHT
 166 @llpx_sn_alt_intro_alt // -HL12
 167 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hdi #HnVT #HLK1 #HLK2
 168 elim (nlift_inv_bind … HnVT) -HnVT #H
 169 [ elim (IHV … HLK1 … HLK2) -IHV /2 width=2 by and3_intro/
 170 | elim IHT -IHT /2 width=12 by ldrop_drop, yle_succ, and3_intro/
 171 ]
 172 qed.
 173
 174 (* Main properties **********************************************************)
 175
 176 theorem llpx_sn_lpx_sn_alt: ∀R,L1,L2,T,d. llpx_sn R d T L1 L2 → llpx_sn_alt R d T L1 L2.
 177 #R #L1 #L2 #T #d #H elim H -L1 -L2 -T -d
 178 /2 width=9 by llpx_sn_alt_sort, llpx_sn_alt_gref, llpx_sn_alt_skip, llpx_sn_alt_free, llpx_sn_alt_lref, llpx_sn_alt_flat, llpx_sn_alt_bind/
 179 qed.
 180
 181 (* Main inversion lemmas ****************************************************)
 182
 183 theorem llpx_sn_alt_inv_lpx_sn: ∀R,T,L1,L2,d. llpx_sn_alt R d T L1 L2 → llpx_sn R d T L1 L2.
 184 #R #T #L1 @(f2_ind … rfw … L1 T) -L1 -T #n #IH #L1 * *
 185 [1,3: /3 width=4 by llpx_sn_alt_fwd_length, llpx_sn_gref, llpx_sn_sort/
 186 | #i #Hn #L2 #d #H lapply (llpx_sn_alt_fwd_length … H)
 187   #HL12 elim (llpx_sn_alt_fwd_lref … H) -H
 188   [ * /2 width=1 by llpx_sn_free/
 189   | /2 width=1 by llpx_sn_skip/
 190   | * /4 width=9 by llpx_sn_lref, ldrop_fwd_rfw/
 191   ]
 192 | #a #I #V #T #Hn #L2 #d #H elim (llpx_sn_alt_inv_bind … H) -H
 193   /3 width=1 by llpx_sn_bind/
 194 | #I #V #T #Hn #L2 #d #H elim (llpx_sn_alt_inv_flat … H) -H
 195   /3 width=1 by llpx_sn_flat/
 196 ]
 197 qed-.
 198
 199 (* Advanced properties ******************************************************)
 200
 201 lemma llpx_sn_intro_alt: ∀R,L1,L2,T,d. |L1| = |L2| →
 202                          (∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
 203                             ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
 204                             ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn R 0 V1 K1 K2
 205                          ) → llpx_sn R d T L1 L2.
 206 #R #L1 #L2 #T #d #HL12 #IH @llpx_sn_alt_inv_lpx_sn
 207 @llpx_sn_alt_intro_alt // -HL12
 208 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hid #HnT #HLK1 #HLK2
 209 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /3 width=1 by llpx_sn_lpx_sn_alt, and3_intro/
 210 qed.
 211
 212 (* Advanced inversion lemmas ************************************************)
 213
 214 lemma llpx_sn_inv_gen: ∀R,L1,L2,T,d. llpx_sn R d T L1 L2 →
 215                        |L1| = |L2| ∧
 216                        ∀I1,I2,K1,K2,V1,V2,i. d ≤ yinj i → (∀U. ⇧[i, 1] U ≡ T → ⊥) →
 217                        ⇩[i] L1 ≡ K1.ⓑ{I1}V1 → ⇩[i] L2 ≡ K2.ⓑ{I2}V2 →
 218                        ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn R 0 V1 K1 K2.
 219 #R #L1 #L2 #T #d #H lapply (llpx_sn_lpx_sn_alt … H) -H
 220 #H elim (llpx_sn_alt_inv_gen … H) -H
 221 #HL12 #IH @conj //
 222 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hid #HnT #HLK1 #HLK2
 223 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /3 width=1 by llpx_sn_alt_inv_lpx_sn, and3_intro/
 224 qed-.