matita/matita/contribs/lambdadelta/basic_2/restricted/cpqs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/cpss.ma".
  16
  17 (* CONTEXT-SENSITIVE RESTRICTED PARALLEL COMPUTATION FOR TERMS **************)
  18
  19 inductive cpqs: lenv → relation term ≝
  20 | cpqs_atom : ∀I,L. cpqs L (⓪{I}) (⓪{I})
  21 | cpqs_delta: ∀L,K,V,V2,W2,i.
  22               ⇩[0, i] L ≡ K. ⓓV → cpqs K V V2 →
  23               ⇧[0, i + 1] V2 ≡ W2 → cpqs L (#i) W2
  24 | cpqs_bind : ∀a,I,L,V1,V2,T1,T2.
  25               cpqs L V1 V2 → cpqs (L. ⓑ{I} V1) T1 T2 →
  26               cpqs L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  27 | cpqs_flat : ∀I,L,V1,V2,T1,T2.
  28               cpqs L V1 V2 → cpqs L T1 T2 →
  29               cpqs L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  30 | cpqs_zeta : ∀L,V,T1,T,T2. cpqs (L.ⓓV) T1 T →
  31               ⇧[0, 1] T2 ≡ T → cpqs L (+ⓓV. T1) T2
  32 | cpqs_tau  : ∀L,V,T1,T2. cpqs L T1 T2 → cpqs L (ⓝV. T1) T2
  33 .
  34
  35 interpretation "context-sensitive restricted parallel computation (term)"
  36    'PRestStar L T1 T2 = (cpqs L T1 T2).
  37
  38 (* Basic properties *********************************************************)
  39
  40 (* Note: it does not hold replacing |L1| with |L2| *)
  41 lemma cpqs_lsubr_trans: ∀L1,T1,T2. L1 ⊢ T1 ➤* T2 →
  42                         ∀L2. L2 ⊑ [0, |L1|] L1 → L2 ⊢ T1 ➤* T2.
  43 #L1 #T1 #T2 #H elim H -L1 -T1 -T2
  44 [ //
  45 | #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  46   lapply (ldrop_fwd_ldrop2_length … HLK1) #Hi
  47   lapply (ldrop_fwd_O1_length … HLK1) #H2i
  48   elim (ldrop_lsubr_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // -Hi
  49   <H2i -H2i <minus_plus_m_m /3 width=6/
  50 | /4 width=1/
  51 | /3 width=1/
  52 | /4 width=3/
  53 | /3 width=1/
  54 ]
  55 qed-.
  56
  57 lemma cpss_cpqs: ∀L,T1,T2. L ⊢ T1 ▶* T2 → L ⊢ T1 ➤* T2.
  58 #L #T1 #T2 #H elim H -L -T1 -T2 // /2 width=1/ /2 width=6/
  59 qed.
  60
  61 lemma cpqs_refl: ∀T,L. L ⊢ T ➤* T.
  62 /2 width=1/ qed.
  63
  64 lemma cpqs_delift: ∀L,K,V,T1,d. ⇩[0, d] L ≡ (K. ⓓV) →
  65                    ∃∃T2,T. L ⊢ T1 ➤* T2 & ⇧[d, 1] T ≡ T2.
  66 #L #K #V #T1 #d #HLK
  67 elim (cpss_delift … T1 … HLK) -HLK /3 width=4/
  68 qed-.
  69
  70 lemma cpqs_append: l_appendable_sn … cpqs.
  71 #K #T1 #T2 #H elim H -K -T1 -T2 // /2 width=1/ /2 width=3/
  72 #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
  73 lapply (ldrop_fwd_ldrop2_length … HK0) #H
  74 @(cpqs_delta … (L@@K0) V1 … HVW2) //
  75 @(ldrop_O1_append_sn_le … HK0) /2 width=2/ (**) (* /3/ does not work *)
  76 qed.
  77
  78 (* Basic inversion lemmas ***************************************************)
  79
  80 fact cpqs_inv_atom1_aux: ∀L,T1,T2. L ⊢ T1 ➤* T2 → ∀I. T1 = ⓪{I} →
  81                          T2 = ⓪{I} ∨
  82                          ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  83                                      K ⊢ V ➤* V2 &
  84                                      ⇧[O, i + 1] V2 ≡ T2 &
  85                                      I = LRef i.
  86 #L #T1 #T2 * -L -T1 -T2
  87 [ #I #L #J #H destruct /2 width=1/
  88 | #L #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=8/
  89 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  90 | #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  91 | #L #V #T1 #T #T2 #_ #_ #J #H destruct
  92 | #L #V #T1 #T2 #_ #J #H destruct
  93 ]
  94 qed-.
  95
  96 lemma cpqs_inv_atom1: ∀I,L,T2. L ⊢ ⓪{I} ➤* T2 →
  97                       T2 = ⓪{I} ∨
  98                       ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  99                                   K ⊢ V ➤* V2 &
 100                                   ⇧[O, i + 1] V2 ≡ T2 &
 101                                   I = LRef i.
 102 /2 width=3 by cpqs_inv_atom1_aux/ qed-.
 103
 104 lemma cpqs_inv_sort1: ∀L,T2,k. L ⊢ ⋆k ➤* T2 → T2 = ⋆k.
 105 #L #T2 #k #H
 106 elim (cpqs_inv_atom1 … H) -H //
 107 * #K #V #V2 #i #_ #_ #_ #H destruct
 108 qed-.
 109
 110 lemma cpqs_inv_lref1: ∀L,T2,i. L ⊢ #i ➤* T2 →
 111                       T2 = #i ∨
 112                       ∃∃K,V,V2. ⇩[O, i] L ≡ K. ⓓV &
 113                                 K ⊢ V ➤* V2 &
 114                                 ⇧[O, i + 1] V2 ≡ T2.
 115 #L #T2 #i #H
 116 elim (cpqs_inv_atom1 … H) -H /2 width=1/
 117 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6/
 118 qed-.
 119
 120 lemma cpqs_inv_gref1: ∀L,T2,p. L ⊢ §p ➤* T2 → T2 = §p.
 121 #L #T2 #p #H
 122 elim (cpqs_inv_atom1 … H) -H //
 123 * #K #V #V2 #i #_ #_ #_ #H destruct
 124 qed-.
 125
 126 fact cpqs_inv_bind1_aux: ∀L,U1,U2. L ⊢ U1 ➤* U2 →
 127                          ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 → (
 128                          ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 129                                   L. ⓑ{I} V1 ⊢ T1 ➤* T2 &
 130                                   U2 = ⓑ{a,I} V2. T2
 131                          ) ∨
 132                          ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true & I = Abbr.
 133 #L #U1 #U2 * -L -U1 -U2
 134 [ #I #L #b #J #W1 #U1 #H destruct
 135 | #L #K #V #V2 #W2 #i #_ #_ #_ #b #J #W1 #U1 #H destruct
 136 | #a #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W1 #U1 #H destruct /3 width=5/
 137 | #I #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W1 #U1 #H destruct
 138 | #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W1 #U1 #H destruct /3 width=3/
 139 | #L #V #T1 #T2 #_ #b #J #W1 #U1 #H destruct
 140 ]
 141 qed-.
 142
 143 lemma cpqs_inv_bind1: ∀a,I,L,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ➤* U2 → (
 144                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 145                                L. ⓑ{I} V1 ⊢ T1 ➤* T2 &
 146                                U2 = ⓑ{a,I} V2. T2
 147                       ) ∨
 148                       ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true & I = Abbr.
 149 /2 width=3 by cpqs_inv_bind1_aux/ qed-.
 150
 151 lemma cpqs_inv_abbr1: ∀a,L,V1,T1,U2. L ⊢ ⓓ{a} V1. T1 ➤* U2 → (
 152                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 153                                L. ⓓ V1 ⊢ T1 ➤* T2 &
 154                                U2 = ⓓ{a} V2. T2
 155                       ) ∨
 156                       ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true.
 157 #a #L #V1 #T1 #U2 #H
 158 elim (cpqs_inv_bind1 … H) -H * /3 width=3/ /3 width=5/
 159 qed-.
 160
 161 lemma cpqs_inv_abst1: ∀a,L,V1,T1,U2. L ⊢ ⓛ{a} V1. T1 ➤* U2 →
 162                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 163                                L. ⓛ V1 ⊢ T1 ➤* T2 &
 164                                U2 = ⓛ{a} V2. T2.
 165 #a #L #V1 #T1 #U2 #H
 166 elim (cpqs_inv_bind1 … H) -H *
 167 [ /3 width=5/
 168 | #T #_ #_ #_ #H destruct
 169 ]
 170 qed-.
 171
 172 fact cpqs_inv_flat1_aux: ∀L,U1,U2. L ⊢ U1 ➤* U2 →
 173                          ∀I,V1,T1. U1 = ⓕ{I} V1. T1 → (
 174                          ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 175                                   U2 = ⓕ{I} V2. T2
 176                          ) ∨
 177                          (L ⊢ T1 ➤* U2 ∧ I = Cast).
 178 #L #U1 #U2 * -L -U1 -U2
 179 [ #I #L #J #W1 #U1 #H destruct
 180 | #L #K #V #V2 #W2 #i #_ #_ #_ #J #W1 #U1 #H destruct
 181 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #W1 #U1 #H destruct
 182 | #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W1 #U1 #H destruct /3 width=5/
 183 | #L #V #T1 #T #T2 #_ #_ #J #W1 #U1 #H destruct
 184 | #L #V #T1 #T2 #HT12 #J #W1 #U1 #H destruct /3 width=1/
 185 ]
 186 qed-.
 187
 188 lemma cpqs_inv_flat1: ∀I,L,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ➤* U2 → (
 189                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 190                                U2 = ⓕ{I} V2. T2
 191                       ) ∨
 192                       (L ⊢ T1 ➤* U2 ∧ I = Cast).
 193 /2 width=3 by cpqs_inv_flat1_aux/ qed-.
 194
 195 lemma cpqs_inv_appl1: ∀L,V1,T1,U2. L ⊢ ⓐ V1. T1 ➤* U2 →
 196                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 197                                U2 = ⓐ V2. T2.
 198 #L #V1 #T1 #U2 #H elim (cpqs_inv_flat1 … H) -H *
 199 [ /3 width=5/
 200 | #_ #H destruct
 201 ]
 202 qed-.
 203
 204 lemma cpqs_inv_cast1: ∀L,V1,T1,U2. L ⊢ ⓝ V1. T1 ➤* U2 → (
 205                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 206                                U2 = ⓝ V2. T2
 207                       ) ∨
 208                       L ⊢ T1 ➤* U2.
 209 #L #V1 #T1 #U2 #H elim (cpqs_inv_flat1 … H) -H * /2 width=1/ /3 width=5/
 210 qed-.
 211
 212 (* Basic forward lemmas *****************************************************)
 213
 214 lemma cpqs_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ➤* T →
 215                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 216 #L1 @(lenv_ind_dx … L1) -L1 normalize
 217 [ #L #T1 #T #HT1
 218   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 219 | #I #L1 #V1 #IH #L #T1 #X
 220   >shift_append_assoc normalize #H
 221   elim (cpqs_inv_bind1 … H) -H *
 222   [ #V0 #T0 #_ #HT10 #H destruct
 223     elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 224     >append_length >HL12 -HL12
 225     @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 226   | #T #_ #_ #H destruct
 227   ]
 228 ]
 229 qed-.