matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpre_cpre.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cprs_cnr.ma".
  16 include "basic_2/rt_computation/cprs_cprs.ma".
  17 include "basic_2/rt_computation/cpre.ma".
  18
  19 (* EVALUATION FOR CONTEXT-SENSITIVE PARALLEL R-TRANSITION ON TERMS *********)
  20
  21 (* Properties with context-sensitive parallel r-computation for terms ******)
  22
  23 lemma cpre_cprs_conf (h) (G) (L) (T):
  24       ∀T1. ⦃G,L⦄ ⊢ T ➡*[h] T1 → ∀T2. ⦃G,L⦄ ⊢ T ➡*[h] 𝐍⦃T2⦄ → ⦃G,L⦄ ⊢ T1 ➡*[h] 𝐍⦃T2⦄.
  25 #h #G #L #T0 #T1 #HT01 #T2 * #HT02 #HT2
  26 elim (cprs_conf … HT01 … HT02) -T0 #T0 #HT10 #HT20
  27 lapply (cprs_inv_cnr_sn … HT20 HT2) -HT20 #H destruct
  28 /2 width=1 by conj/
  29 qed-.
  30
  31 (* Main properties *********************************************************)
  32
  33 (* Basic_1: was: nf2_pr3_confluence *)
  34 theorem cpre_mono (h) (G) (L) (T):
  35         ∀T1. ⦃G,L⦄ ⊢ T ➡*[h] 𝐍⦃T1⦄ → ∀T2. ⦃G,L⦄ ⊢ T ➡*[h] 𝐍⦃T2⦄ → T1 = T2.
  36 #h #G #L #T0 #T1 * #HT01 #HT1 #T2 * #HT02 #HT2
  37 elim (cprs_conf … HT01 … HT02) -T0 #T0 #HT10 #HT20
  38 >(cprs_inv_cnr_sn … HT10 HT1) -T1
  39 >(cprs_inv_cnr_sn … HT20 HT2) -T2 //
  40 qed-.