matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs_lpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cpxs_fqus.ma".
  16 include "basic_2/rt_computation/cpxs_reqg.ma".
  17 include "basic_2/rt_computation/lpxs_feqg.ma".
  18 include "basic_2/rt_computation/fpbs_lpx.ma".
  19 include "basic_2/rt_computation/fpbs_cpxs.ma".
  20
  21 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  22
  23 (* Properties with extended rt-computation on full local environments  ******)
  24
  25 lemma lpxs_fpbs:
  26       ∀G,L1,L2,T. ❨G,L1❩ ⊢ ⬈* L2 → ❨G,L1,T❩ ≥ ❨G,L2,T❩.
  27 #G #L1 #L2 #T #H @(lpxs_ind_dx … H) -L2
  28 /3 width=5 by lpx_fpb, fpbs_strap1/
  29 qed.
  30
  31 lemma fpbs_lpxs_trans:
  32       ∀G1,G2,L1,L,T1,T2. ❨G1,L1,T1❩ ≥ ❨G2,L,T2❩ →
  33       ∀L2. ❨G2,L❩ ⊢ ⬈* L2 → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  34 #G1 #G2 #L1 #L #T1 #T2 #H1 #L2 #H @(lpxs_ind_dx … H) -L2
  35 /3 width=5 by fpbs_strap1, lpx_fpb/
  36 qed-.
  37
  38 lemma lpxs_fpbs_trans:
  39       ∀G1,G2,L,L2,T1,T2. ❨G1,L,T1❩ ≥ ❨G2,L2,T2❩ →
  40       ∀L1. ❨G1,L1❩ ⊢ ⬈* L → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  41 #G1 #G2 #L #L2 #T1 #T2 #H1 #L1 #H @(lpxs_ind_sn … H) -L1
  42 /3 width=5 by fpbs_strap2, lpx_fpb/
  43 qed-.
  44
  45 (* Basic_2A1: uses: lpxs_lleq_fpbs *)
  46 lemma lpxs_feqg_fpbs (S) (L):
  47       reflexive … S → symmetric … S →
  48       ∀G1,L1,T1. ❨G1,L1❩ ⊢ ⬈* L →
  49       ∀G2,L2,T2. ❨G1,L,T1❩ ≛[S] ❨G2,L2,T2❩ → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  50 /3 width=4 by lpxs_fpbs_trans, feqg_fpbs/ qed.
  51
  52 (* Properties with star-iterated structural successor for closures **********)
  53
  54 lemma fqus_lpxs_fpbs:
  55       ∀G1,G2,L1,L,T1,T2. ❨G1,L1,T1❩ ⬂* ❨G2,L,T2❩ →
  56       ∀L2. ❨G2,L❩ ⊢ ⬈* L2 → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  57 /3 width=3 by fpbs_lpxs_trans, fqus_fpbs/ qed.
  58
  59 (* Properties with extended context-sensitive parallel rt-computation *******)
  60
  61 lemma cpxs_fqus_lpxs_fpbs:
  62       ∀G1,L1,T1,T. ❨G1,L1❩ ⊢ T1 ⬈* T →
  63       ∀G2,L,T2. ❨G1,L1,T❩ ⬂* ❨G2,L,T2❩ →
  64       ∀L2.❨G2,L❩ ⊢ ⬈* L2 → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  65 /3 width=5 by cpxs_fqus_fpbs, fpbs_lpxs_trans/ qed.
  66
  67 lemma fpbs_cpxs_teqg_fqup_lpx_trans (S):
  68       reflexive … S → symmetric … S →
  69       ∀G1,G3,L1,L3,T1,T3. ❨G1,L1,T1❩ ≥  ❨G3,L3,T3❩ →
  70       ∀T4. ❨G3,L3❩ ⊢ T3 ⬈* T4 → ∀T5. T4 ≛[S] T5 →
  71       ∀G2,L4,T2. ❨G3,L3,T5❩ ⬂+ ❨G2,L4,T2❩ →
  72       ∀L2. ❨G2,L4❩ ⊢ ⬈ L2 → ❨G1,L1,T1❩ ≥  ❨G2,L2,T2❩.
  73 #S #H1S #H2S #G1 #G3 #L1 #L3 #T1 #T3 #H13 #T4 #HT34 #T5 #HT45 #G2 #L4 #T2 #H34 #L2 #HL42
  74 @(fpbs_lpx_trans … HL42) -L2 (**) (* full auto too slow *)
  75 @(fpbs_fqup_trans … H34) -G2 -L4 -T2
  76 /3 width=6 by fpbs_cpxs_trans, fpbs_teqg_trans/
  77 qed-.
  78
  79 (* Advanced properties ******************************************************)
  80
  81 (* Basic_2A1: uses: fpbs_intro_alt *)
  82 lemma fpbs_intro_star (S) (G) (T) (T0) (L) (L0):
  83       reflexive … S → symmetric … S →
  84       ∀G1,L1,T1. ❨G1,L1❩ ⊢ T1 ⬈* T →
  85       ❨G1,L1,T❩ ⬂* ❨G,L,T0❩ → ❨G,L❩ ⊢ ⬈* L0 →
  86       ∀G2,L2,T2. ❨G,L0,T0❩ ≛[S] ❨G2,L2,T2❩ → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  87 /3 width=8 by cpxs_fqus_lpxs_fpbs, fpbs_strap1, feqg_fpb/ qed.
  88
  89 (* Advanced inversion lemmas *************************************************)
  90
  91 (* Basic_2A1: uses: fpbs_inv_alt *)
  92 lemma fpbs_inv_star (S):
  93       reflexive … S → symmetric … S → Transitive  … S →
  94       ∀G1,G2,L1,L2,T1,T2. ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩ →
  95       ∃∃G,L,L0,T,T0. ❨G1,L1❩ ⊢ T1 ⬈* T & ❨G1,L1,T❩ ⬂* ❨G,L,T0❩ & ❨G,L❩ ⊢ ⬈* L0 & ❨G,L0,T0❩ ≛[S] ❨G2,L2,T2❩.
  96 #S #H1S #H2S #H3S #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind_dx … H) -G1 -L1 -T1
  97 [ /3 width=9 by feqg_refl, ex4_5_intro/
  98 | #G1 #G0 #L1 #L0 #T1 #T0 *
  99   #L3 #T3 #H13 #HT30 #HL30 #_ *
 100   #G4 #L4 #L5 #T4 #T5 #HT04 #H45 #HL45 #H52
 101   lapply (rpx_cpx_conf_sn … HT30 … HL30) -HL30 #HL30
 102   elim (fquq_cpx_trans … H13 … HT30) -T3 #T3 #HT13 #H30
 103   elim (rpx_fwd_lpx_reqg S … HL30) -HL30 // #L #HL3 #HL0
 104   lapply (reqg_cpxs_trans … HT04 … HL0) -HT04 // #HT04
 105   lapply (cpxs_reqg_conf_sn … HT04 … HL0) -HL0 #HL0
 106   lapply (lpx_cpxs_trans … HT04 … HL3) -HT04 #HT04
 107   elim (fquq_cpxs_trans … HT04 … H30) -T0 #T0 #HT30 #H04
 108   lapply (cpxs_strap2 … HT13 … HT30) -T3 #HT10
 109   elim (reqg_fqus_trans … H45 … HL0) -L0 // #L0 #T3 #H43 #HT35 #HL04
 110   lapply (feqg_intro_dx … G4 … HL04 … HT35) -HL04 -HT35 // #H35
 111   elim (lpx_fqus_trans … H43 … HL3) -L #L #T #HT4 #H3 #HL0
 112   elim (fquq_cpxs_trans … HT4 … H04) -T4 #T4 #HT04 #H4
 113   lapply (cpxs_trans … HT10 … HT04) -T0 #HT14
 114   lapply (fqus_strap2 … H4 … H3) -G0 -L3 -T #H43
 115   elim (feqg_lpxs_trans … H35 … HL45) -L4 // #L4 #HL04 #H35
 116   lapply (lpxs_step_sn … HL0 … HL04) -L0 #HL4
 117   lapply (feqg_trans … H35 … H52) -L5 -T5 // #H32
 118   /2 width=9 by ex4_5_intro/
 119 ]
 120 qed-.