matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpbc_lpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/lpx_reqg.ma".
  16 include "basic_2/rt_transition/fpbc.ma".
  17
  18 (* PROPER PARALLEL RST-TRANSITION FOR CLOSURES ******************************)
  19
  20 (* Properties with extended rt-transition for full local envs ***************)
  21
  22 (* Basic_2A1: uses: fpb_lpx *)
  23 lemma lpx_fpbc (G) (T):
  24       ∀L1,L2. ❪G,L1❫ ⊢ ⬈ L2 → (L1 ≅[T] L2 → ⊥) → ❪G,L1,T❫ ≻ ❪G,L2,T❫.
  25 /3 width=1 by rpx_fpbc, lpx_rpx/ qed.
  26
  27 (* Forward lemmas with extended rt-transition for full local envs ***********)
  28
  29 lemma fpbc_fwd_lpx (G1) (G2) (L1) (L2) (T1) (T2):
  30       ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ →
  31       ∨∨ ∃∃G,L,T. ❪G1,L1,T1❫ ⬂ ❪G,L,T❫ & ❪G,L,T❫ ≽ ❪G2,L2,T2❫
  32        | ∃∃T. ❪G1,L1❫ ⊢ T1 ⬈ T & T1 ≅ T → ⊥ & ❪G1,L1,T❫ ≽ ❪G2,L2,T2❫
  33        | ∃∃L. ❪G1,L1❫ ⊢ ⬈ L & (L1 ≅[T1] L → ⊥) & ❪G1,L,T1❫ ≽ ❪G2,L2,T2❫.
  34 #G1 #G2 #L1 #L2 #T1 #T2 #H
  35 elim (fpbc_inv_gen sfull … H) -H #H12 #Hn12
  36 elim (fpb_inv_gen … H12) -H12 #L #T #H1 #HT2 #HL2
  37 elim H1 -H1 [ /4 width=9 by fpb_intro, ex2_3_intro, or3_intro0/ ]
  38 * #H1 #H2 #H3 destruct
  39 elim (teqg_dec sfull … T T2)
  40 [ -HT2 #HT2 |*: /5 width=11 by fpb_intro, cpx_rex_conf_sn, ex3_intro, or3_intro1, sfull_dec/ ]
  41 elim (rpx_fwd_lpx_reqg sfull … HL2) -HL2 // #L0 #HL0 #HL02
  42 elim (reqg_dec sfull … L L0 T)
  43 [ -HL0 #HL0 |*: /5 width=11 by fpb_intro, reqg_rpx, teqg_cpx, ex3_intro, or3_intro2, sfull_dec/ ]
  44 elim Hn12 -Hn12 /3 width=3 by feqg_intro_sn, reqg_trans/
  45 qed-.