matita/matita/contribs/lambdadelta/basic_2/static/ssta.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/ldrop.ma".
  16 include "basic_2/unfold/frsups.ma".
  17 include "basic_2/static/sd.ma".
  18
  19 (* STRATIFIED STATIC TYPE ASSIGNMENT ON TERMS *******************************)
  20
  21 inductive ssta (h:sh) (g:sd h): nat → lenv → relation term ≝
  22 | ssta_sort: ∀L,k,l. deg h g k l → ssta h g l L (⋆k) (⋆(next h k))
  23 | ssta_ldef: ∀L,K,V,W,U,i,l. ⇩[0, i] L ≡ K. ⓓV → ssta h g l K V W →
  24              ⇧[0, i + 1] W ≡ U → ssta h g l L (#i) U
  25 | ssta_ldec: ∀L,K,W,V,U,i,l. ⇩[0, i] L ≡ K. ⓛW → ssta h g l K W V →
  26              ⇧[0, i + 1] W ≡ U → ssta h g (l+1) L (#i) U
  27 | ssta_bind: ∀a,I,L,V,T,U,l. ssta h g l (L. ⓑ{I} V) T U →
  28              ssta h g l L (ⓑ{a,I}V.T) (ⓑ{a,I}V.U)
  29 | ssta_appl: ∀L,V,T,U,l. ssta h g l L T U →
  30              ssta h g l L (ⓐV.T) (ⓐV.U)
  31 | ssta_cast: ∀L,W,T,U,l. ssta h g l L T U → ssta h g l L (ⓝW. T) U
  32 .
  33
  34 interpretation "stratified static type assignment (term)"
  35    'StaticType h g L T U l = (ssta h g l L T U).
  36
  37 definition ssta_step: ∀h. sd h → lenv → relation term ≝ λh,g,L,T,U.
  38                       ∃l. ⦃h, L⦄ ⊢ T •[g] ⦃l+1, U⦄.
  39
  40 (* Basic inversion lemmas ************************************************)
  41
  42 fact ssta_inv_sort1_aux: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ → ∀k0. T = ⋆k0 →
  43                          deg h g k0 l ∧ U = ⋆(next h k0).
  44 #h #g #L #T #U #l * -L -T -U -l
  45 [ #L #k #l #Hkl #k0 #H destruct /2 width=1/
  46 | #L #K #V #W #U #i #l #_ #_ #_ #k0 #H destruct
  47 | #L #K #W #V #U #i #l #_ #_ #_ #k0 #H destruct
  48 | #a #I #L #V #T #U #l #_ #k0 #H destruct
  49 | #L #V #T #U #l #_ #k0 #H destruct
  50 | #L #W #T #U #l #_ #k0 #H destruct
  51 qed.
  52
  53 (* Basic_1: was just: sty0_gen_sort *)
  54 lemma ssta_inv_sort1: ∀h,g,L,U,k,l. ⦃h, L⦄ ⊢ ⋆k •[g] ⦃l, U⦄ →
  55                       deg h g k l ∧ U = ⋆(next h k).
  56 /2 width=4/ qed-.
  57
  58 fact ssta_inv_lref1_aux: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ → ∀j. T = #j →
  59                          (∃∃K,V,W. ⇩[0, j] L ≡ K. ⓓV & ⦃h, K⦄ ⊢ V •[g] ⦃l, W⦄ &
  60                                    ⇧[0, j + 1] W ≡ U
  61                          ) ∨
  62                          (∃∃K,W,V,l0. ⇩[0, j] L ≡ K. ⓛW & ⦃h, K⦄ ⊢ W •[g] ⦃l0, V⦄ &
  63                                       ⇧[0, j + 1] W ≡ U & l = l0 + 1
  64                          ).
  65 #h #g #L #T #U #l * -L -T -U -l
  66 [ #L #k #l #_ #j #H destruct
  67 | #L #K #V #W #U #i #l #HLK #HVW #HWU #j #H destruct /3 width=6/
  68 | #L #K #W #V #U #i #l #HLK #HWV #HWU #j #H destruct /3 width=8/
  69 | #a #I #L #V #T #U #l #_ #j #H destruct
  70 | #L #V #T #U #l #_ #j #H destruct
  71 | #L #W #T #U #l #_ #j #H destruct
  72 ]
  73 qed.
  74
  75 (* Basic_1: was just: sty0_gen_lref *)
  76 lemma ssta_inv_lref1: ∀h,g,L,U,i,l. ⦃h, L⦄ ⊢ #i •[g] ⦃l, U⦄ →
  77                       (∃∃K,V,W. ⇩[0, i] L ≡ K. ⓓV & ⦃h, K⦄ ⊢ V •[g] ⦃l, W⦄ &
  78                                 ⇧[0, i + 1] W ≡ U
  79                       ) ∨
  80                       (∃∃K,W,V,l0. ⇩[0, i] L ≡ K. ⓛW & ⦃h, K⦄ ⊢ W •[g] ⦃l0, V⦄ &
  81                                    ⇧[0, i + 1] W ≡ U & l = l0 + 1
  82                       ).
  83 /2 width=3/ qed-.
  84
  85 fact ssta_inv_gref1_aux: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ → ∀p0. T = §p0 → ⊥.
  86 #h #g #L #T #U #l * -L -T -U -l
  87 [ #L #k #l #_ #p0 #H destruct
  88 | #L #K #V #W #U #i #l #_ #_ #_ #p0 #H destruct
  89 | #L #K #W #V #U #i #l #_ #_ #_ #p0 #H destruct
  90 | #a #I #L #V #T #U #l #_ #p0 #H destruct
  91 | #L #V #T #U #l #_ #p0 #H destruct
  92 | #L #W #T #U #l #_ #p0 #H destruct
  93 qed.
  94
  95 lemma ssta_inv_gref1: ∀h,g,L,U,p,l. ⦃h, L⦄ ⊢ §p •[g] ⦃l, U⦄ → ⊥.
  96 /2 width=9/ qed-.
  97
  98 fact ssta_inv_bind1_aux: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ →
  99                          ∀a,I,X,Y. T = ⓑ{a,I}Y.X →
 100                          ∃∃Z. ⦃h, L.ⓑ{I}Y⦄ ⊢ X •[g] ⦃l, Z⦄ & U = ⓑ{a,I}Y.Z.
 101 #h #g #L #T #U #l * -L -T -U -l
 102 [ #L #k #l #_ #a #I #X #Y #H destruct
 103 | #L #K #V #W #U #i #l #_ #_ #_ #a #I #X #Y #H destruct
 104 | #L #K #W #V #U #i #l #_ #_ #_ #a #I #X #Y #H destruct
 105 | #b #J #L #V #T #U #l #HTU #a #I #X #Y #H destruct /2 width=3/
 106 | #L #V #T #U #l #_ #a #I #X #Y #H destruct
 107 | #L #W #T #U #l #_ #a #I #X #Y #H destruct
 108 ]
 109 qed.
 110
 111 (* Basic_1: was just: sty0_gen_bind *)
 112 lemma ssta_inv_bind1: ∀h,g,a,I,L,Y,X,U,l. ⦃h, L⦄ ⊢ ⓑ{a,I}Y.X •[g] ⦃l, U⦄ →
 113                       ∃∃Z. ⦃h, L.ⓑ{I}Y⦄ ⊢ X •[g] ⦃l, Z⦄ & U = ⓑ{a,I}Y.Z.
 114 /2 width=3/ qed-.
 115
 116 fact ssta_inv_appl1_aux: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ → ∀X,Y. T = ⓐY.X →
 117                          ∃∃Z. ⦃h, L⦄ ⊢ X •[g] ⦃l, Z⦄ & U = ⓐY.Z.
 118 #h #g #L #T #U #l * -L -T -U -l
 119 [ #L #k #l #_ #X #Y #H destruct
 120 | #L #K #V #W #U #i #l #_ #_ #_ #X #Y #H destruct
 121 | #L #K #W #V #U #i #l #_ #_ #_ #X #Y #H destruct
 122 | #a #I #L #V #T #U #l #_ #X #Y #H destruct
 123 | #L #V #T #U #l #HTU #X #Y #H destruct /2 width=3/
 124 | #L #W #T #U #l #_ #X #Y #H destruct
 125 ]
 126 qed.
 127
 128 (* Basic_1: was just: sty0_gen_appl *)
 129 lemma ssta_inv_appl1: ∀h,g,L,Y,X,U,l. ⦃h, L⦄ ⊢ ⓐY.X •[g] ⦃l, U⦄ →
 130                       ∃∃Z. ⦃h, L⦄ ⊢ X •[g] ⦃l, Z⦄ & U = ⓐY.Z.
 131 /2 width=3/ qed-.
 132
 133 fact ssta_inv_cast1_aux: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ →
 134                          ∀X,Y. T = ⓝY.X → ⦃h, L⦄ ⊢ X •[g] ⦃l, U⦄.
 135 #h #g #L #T #U #l * -L -T -U -l
 136 [ #L #k #l #_ #X #Y #H destruct
 137 | #L #K #V #W #U #l #i #_ #_ #_ #X #Y #H destruct
 138 | #L #K #W #V #U #l #i #_ #_ #_ #X #Y #H destruct
 139 | #a #I #L #V #T #U #l #_ #X #Y #H destruct
 140 | #L #V #T #U #l #_ #X #Y #H destruct
 141 | #L #W #T #U #l #HTU #X #Y #H destruct //
 142 ]
 143 qed.
 144
 145 (* Basic_1: was just: sty0_gen_cast *)
 146 lemma ssta_inv_cast1: ∀h,g,L,X,Y,U,l. ⦃h, L⦄ ⊢ ⓝY.X •[g] ⦃l, U⦄ →
 147                       ⦃h, L⦄ ⊢ X •[g] ⦃l, U⦄.
 148 /2 width=4/ qed-.
 149
 150 (* Advanced inversion lemmas ************************************************)
 151
 152 lemma ssta_inv_frsupp: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ → ⦃L, U⦄ ⧁+ ⦃L, T⦄ → ⊥.
 153 #h #g #L #T #U #l #H elim H -L -T -U -l
 154 [ #L #k #l #_ #H
 155   elim (frsupp_inv_atom1_frsups … H)
 156 | #L #K #V #W #U #i #l #_ #_ #HWU #_ #H
 157   elim (lift_frsupp_trans … (⋆) … H … HWU) -U #X #H
 158   elim (lift_inv_lref2_be … H ? ?) -H //
 159 | #L #K #W #V #U #i #l #_ #_ #HWU #_ #H
 160   elim (lift_frsupp_trans … (⋆) … H … HWU) -U #X #H
 161   elim (lift_inv_lref2_be … H ? ?) -H //
 162 | #a #I #L #V #T #U #l #_ #IHTU #H
 163   elim (frsupp_inv_bind1_frsups … H) -H #H [2: /4 width=4/ ] -IHTU
 164   lapply (frsups_fwd_fw … H) -H normalize
 165   <associative_plus <associative_plus #H
 166   elim (le_plus_xySz_x_false … H)
 167 | #L #V #T #U #l #_ #IHTU #H
 168   elim (frsupp_inv_flat1_frsups … H) -H #H [2: /4 width=4/ ] -IHTU
 169   lapply (frsups_fwd_fw … H) -H normalize
 170   <associative_plus <associative_plus #H
 171   elim (le_plus_xySz_x_false … H)
 172 | /3 width=4/
 173 ]
 174 qed-.
 175
 176 fact ssta_inv_refl_aux: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ → T = U → ⊥.
 177 #h #g #L #T #U #l #H elim H -L -T -U -l
 178 [ #L #k #l #_ #H
 179   lapply (next_lt h k) destruct -H -e0 (**) (* destruct: these premises are not erased *)
 180   <e1 -e1 #H elim (lt_refl_false … H)
 181 | #L #K #V #W #U #i #l #_ #_ #HWU #_ #H destruct
 182   elim (lift_inv_lref2_be … HWU ? ?) -HWU //
 183 | #L #K #W #V #U #i #l #_ #_ #HWU #_ #H destruct
 184   elim (lift_inv_lref2_be … HWU ? ?) -HWU //
 185 | #a #I #L #V #T #U #l #_ #IHTU #H destruct /2 width=1/
 186 | #L #V #T #U #l #_ #IHTU #H destruct /2 width=1/
 187 | #L #W #T #U #l #HTU #_ #H destruct
 188   elim (ssta_inv_frsupp … HTU ?) -HTU /2 width=1/
 189 ]
 190 qed-.
 191
 192 lemma ssta_inv_refl: ∀h,g,T,L,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, T⦄ → ⊥.
 193 /2 width=8 by ssta_inv_refl_aux/ qed-.
 194
 195 lemma ssta_inv_frsups: ∀h,g,L,T,U,l. ⦃h, L⦄ ⊢ T •[g] ⦃l, U⦄ → ⦃L, U⦄ ⧁* ⦃L, T⦄ → ⊥.
 196 #h #g #L #T #U #L #HTU #H elim (frsups_inv_all … H) -H
 197 [ * #_ #H destruct /2 width=6 by ssta_inv_refl/
 198 | /2 width=8 by ssta_inv_frsupp/
 199 ]
 200 qed-.