matita/matita/contribs/lambdadelta/basic_2/substitution/cpye.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/psubsteval_6.ma".
  16 include "basic_2/relocation/cny.ma".
  17 include "basic_2/substitution/cpys.ma".
  18
  19 (* EVALUATION FOR CONTEXT-SENSITIVE EXTENDED SUBSTITUTION ON TERMS **********)
  20
  21 definition cpye: ynat → ynat → relation4 genv lenv term term ≝
  22                  λd,e,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ▶*[d, e] T2 ∧ ⦃G, L⦄ ⊢ ▶[d, e] 𝐍⦃T2⦄.
  23
  24 interpretation "evaluation for context-sensitive extended substitution (term)"
  25    'PSubstEval G L T1 T2 d e = (cpye d e G L T1 T2).
  26
  27 (* Basic_properties *********************************************************)
  28
  29 lemma cpye_sort: ∀G,L,d,e,k. ⦃G, L⦄ ⊢ ⋆k ▶*[d, e] 𝐍⦃⋆k⦄.
  30 /3 width=5 by cny_sort, conj/ qed.
  31
  32 lemma cpye_free: ∀G,L,d,e,i. |L| ≤ i → ⦃G, L⦄ ⊢ #i ▶*[d, e] 𝐍⦃#i⦄.
  33 /3 width=6 by cny_lref_free, conj/ qed.
  34
  35 lemma cpye_top: ∀G,L,d,e,i. d + e ≤ yinj i → ⦃G, L⦄ ⊢ #i ▶*[d, e] 𝐍⦃#i⦄.
  36 /3 width=6 by cny_lref_top, conj/ qed.
  37
  38 lemma cpye_skip: ∀G,L,d,e,i. yinj i < d → ⦃G, L⦄ ⊢ #i ▶*[d, e] 𝐍⦃#i⦄.
  39 /3 width=6 by cny_lref_skip, conj/ qed.
  40
  41 lemma cpye_gref: ∀G,L,d,e,p. ⦃G, L⦄ ⊢ §p ▶*[d, e] 𝐍⦃§p⦄.
  42 /3 width=5 by cny_gref, conj/ qed.
  43
  44 lemma cpye_bind: ∀G,L,V1,V2,d,e. ⦃G, L⦄ ⊢ V1 ▶*[d, e] 𝐍⦃V2⦄ →
  45                  ∀I,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ▶*[⫯d, e] 𝐍⦃T2⦄ →
  46                  ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ▶*[d, e] 𝐍⦃ⓑ{a,I}V2.T2⦄.
  47 #G #L #V1 #V2 #d #e * #HV12 #HV2 #I #T1 #T2 *
  48 /5 width=8 by cpys_bind, cny_bind, lsuby_cny_conf, lsuby_succ, conj/
  49 qed.
  50
  51 lemma cpye_flat: ∀G,L,V1,V2,d,e. ⦃G, L⦄ ⊢ V1 ▶*[d, e] 𝐍⦃V2⦄ →
  52                  ∀T1,T2. ⦃G, L⦄ ⊢ T1 ▶*[d, e] 𝐍⦃T2⦄ →
  53                  ∀I. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ▶*[d, e] 𝐍⦃ⓕ{I}V2.T2⦄.
  54 #G #L #V1 #V2 #d #e * #HV12 #HV2 #T1 #T2 *
  55 /3 width=7 by cpys_flat, cny_flat, conj/
  56 qed.
  57
  58 (* Basic inversion lemmas ***************************************************)
  59
  60 lemma cpye_inv_sort1: ∀G,L,X,d,e,k. ⦃G, L⦄ ⊢ ⋆k ▶*[d, e] 𝐍⦃X⦄ → X = ⋆k.
  61 #G #L #X #d #e #k * /2 width=5 by cpys_inv_sort1/
  62 qed-.
  63
  64 lemma cpye_inv_gref1: ∀G,L,X,d,e,p. ⦃G, L⦄ ⊢ §p ▶*[d, e] 𝐍⦃X⦄ → X = §p.
  65 #G #L #X #d #e #p * /2 width=5 by cpys_inv_gref1/
  66 qed-.
  67
  68 lemma cpye_inv_bind1: ∀a,I,G,L,V1,T1,X,d,e. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ▶*[d, e] 𝐍⦃X⦄ →
  69                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶*[d, e] 𝐍⦃V2⦄ & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ▶*[⫯d, e] 𝐍⦃T2⦄ &
  70                                X = ⓑ{a,I}V2.T2.
  71 #a #I #G #L #V1 #T1 #X #d #e * #H1 #H2 elim (cpys_inv_bind1 … H1) -H1
  72 #V2 #T2 #HV12 #HT12 #H destruct elim (cny_inv_bind … H2) -H2
  73 /5 width=8 by lsuby_cny_conf, lsuby_succ, ex3_2_intro, conj/
  74 qed-.
  75
  76 lemma cpye_inv_flat1: ∀I,G,L,V1,T1,X,d,e. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ▶*[d, e] 𝐍⦃X⦄ →
  77                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶*[d, e] 𝐍⦃V2⦄ & ⦃G, L⦄ ⊢ T1 ▶*[d, e] 𝐍⦃T2⦄ &
  78                                X = ⓕ{I}V2.T2.
  79 #I #G #L #V1 #T1 #X #d #e * #H1 #H2 elim (cpys_inv_flat1 … H1) -H1
  80 #V2 #T2 #HV12 #HT12 #H destruct elim (cny_inv_flat … H2) -H2
  81 /3 width=5 by ex3_2_intro, conj/
  82 qed-.