matita/matita/contribs/lambdadelta/basic_2/substitution/cpys_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/cpy_lift.ma".
  16 include "basic_2/substitution/cpys.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED MULTIPLE SUBSTITUTION FOR TERMS ***************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma cpys_subst: ∀I,G,L,K,V,U1,i,d,e.
  23                   d ≤ yinj i → i < d + e →
  24                   ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃G, K⦄ ⊢ V ▶*×[0, ⫰(d+e-i)] U1 →
  25                   ∀U2. ⇧[0, i+1] U1 ≡ U2 → ⦃G, L⦄ ⊢ #i ▶*×[d, e] U2.
  26 #I #G #L #K #V #U1 #i #d #e #Hdi #Hide #HLK #H @(cpys_ind … H) -U1
  27 [ /3 width=5 by cpy_cpys, cpy_subst/
  28 | #U #U1 #_ #HU1 #IHU #U2 #HU12
  29   elim (lift_total U 0 (i+1)) #U0 #HU0
  30   lapply (IHU … HU0) -IHU #H
  31   lapply (ldrop_fwd_ldrop2 … HLK) -HLK #HLK
  32   lapply (cpy_lift_ge … HU1 … HLK HU0 HU12 ?) -HU1 -HLK -HU0 -HU12 // #HU02
  33   lapply (cpy_weak … HU02 d e ? ?) -HU02
  34   [2,3: /2 width=3 by cpys_strap1, yle_succ_dx/ ]
  35   >yplus_O1 <yplus_inj >ymax_pre_sn_comm /2 width=1 by ylt_fwd_le_succ/
  36 ]
  37 qed.
  38
  39 (* Advanced inverion lemmas *************************************************)
  40
  41 lemma cpys_inv_atom1: ∀I,G,L,T2,d,e. ⦃G, L⦄ ⊢ ⓪{I} ▶*×[d, e] T2 →
  42                       T2 = ⓪{I} ∨
  43                       ∃∃J,K,V1,V2,i. d ≤ yinj i & i < d + e &
  44                                     ⇩[O, i] L ≡ K.ⓑ{J}V1 &
  45                                      ⦃G, K⦄ ⊢ V1 ▶*×[0, d+e-i-1] V2 &
  46                                      ⇧[O, i+1] V2 ≡ T2 &
  47                                      I = LRef i.
  48 #I #G #L #T2 #d #e #H @(cpys_ind … H) -T2
  49 [ /2 width=1 by or_introl/
  50 | #T #T2 #_ #HT2 *
  51   [ #H destruct
  52     elim (cpy_inv_atom1 … HT2) -HT2 [ /2 width=1 by or_introl/ | * /3 width=11 by ex6_5_intro, or_intror/ ]
  53   | * #J #K #V1 #V #i #Hdi #Hide #HLK #HV1 #HVT #HI
  54     lapply (ldrop_fwd_ldrop2 … HLK) #H
  55     elim (cpy_inv_lift1_ge_up … HT2 … H … HVT) -HT2 -H -HVT
  56     [2,3,4: /2 width=1 by ylt_fwd_le_succ, yle_succ_dx/ ]
  57     /4 width=11 by cpys_strap1, ex6_5_intro, or_intror/
  58   ]
  59 ]
  60 qed-.
  61
  62 lemma cpys_inv_lref1: ∀G,L,T2,i,d,e. ⦃G, L⦄ ⊢ #i ▶*×[d, e] T2 →
  63                       T2 = #i ∨
  64                       ∃∃I,K,V1,V2. d ≤ i & i < d + e &
  65                                    ⇩[O, i] L ≡ K.ⓑ{I}V1 &
  66                                    ⦃G, K⦄ ⊢ V1 ▶*×[0, d+e-i-1] V2 &
  67                                    ⇧[O, i+1] V2 ≡ T2.
  68 #G #L #T2 #i #d #e #H elim (cpys_inv_atom1 … H) -H /2 width=1 by or_introl/
  69 * #I #K #V1 #V2 #j #Hdj #Hjde #HLK #HV12 #HVT2 #H destruct /3 width=7 by ex5_4_intro, or_intror/
  70 qed-.
  71
  72 lemma cpys_inv_lref1_ldrop: ∀G,L,T2,i,d,e. ⦃G, L⦄ ⊢ #i ▶*×[d, e] T2 →
  73                             ∀I,K,V1. ⇩[O, i] L ≡ K.ⓑ{I}V1 →
  74                             ∀V2. ⇧[O, i+1] V2 ≡ T2 →
  75                             ∧∧ ⦃G, K⦄ ⊢ V1 ▶*×[0, d+e-i-1] V2
  76                              & d ≤ i
  77                              & i < d + e.
  78 #G #L #T2 #i #d #e #H #I #K #V1 #HLK #V2 #HVT2 elim (cpys_inv_lref1 … H) -H
  79 [ #H destruct elim (lift_inv_lref2_be … HVT2) -HVT2 -HLK //
  80 | * #Z #Y #X1 #X2 #Hdi #Hide #HLY #HX12 #HXT2
  81   lapply (lift_inj … HXT2 … HVT2) -T2 #H destruct
  82   lapply (ldrop_mono … HLY … HLK) -L #H destruct
  83   /2 width=1 by and3_intro/
  84 ]
  85 qed-.
  86
  87 (* Relocation properties ****************************************************)
  88
  89 lemma cpys_lift_le: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
  90                     ∀L,U1,d,e. dt + et ≤ yinj d → ⇩[d, e] L ≡ K →
  91                     ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 →
  92                     ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2.
  93 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hdetd #HLK #HTU1 @(cpys_ind … H) -T2
  94 [ #U2 #H >(lift_mono … HTU1 … H) -H //
  95 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
  96   elim (lift_total T d e) #U #HTU
  97   lapply (IHT … HTU) -IHT #HU1
  98   lapply (cpy_lift_le … HT2 … HLK HTU HTU2 ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
  99 ]
 100 qed-.
 101
 102 lemma cpys_lift_be: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
 103                     ∀L,U1,d,e. dt ≤ yinj d → d ≤ dt + et →
 104                     ⇩[d, e] L ≡ K → ⇧[d, e] T1 ≡ U1 →
 105                     ∀U2. ⇧[d, e] T2 ≡ U2 → ⦃G, L⦄ ⊢ U1 ▶*×[dt, et + e] U2.
 106 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hdtd #Hddet #HLK #HTU1 @(cpys_ind … H) -T2
 107 [ #U2 #H >(lift_mono … HTU1 … H) -H //
 108 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
 109   elim (lift_total T d e) #U #HTU
 110   lapply (IHT … HTU) -IHT #HU1
 111   lapply (cpy_lift_be … HT2 … HLK HTU HTU2 ? ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
 112 ]
 113 qed-.
 114
 115 lemma cpys_lift_ge: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
 116                     ∀L,U1,d,e. yinj d ≤ dt → ⇩[d, e] L ≡ K →
 117                     ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 →
 118                     ⦃G, L⦄ ⊢ U1 ▶*×[dt+e, et] U2.
 119 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hddt #HLK #HTU1 @(cpys_ind … H) -T2
 120 [ #U2 #H >(lift_mono … HTU1 … H) -H //
 121 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
 122   elim (lift_total T d e) #U #HTU
 123   lapply (IHT … HTU) -IHT #HU1
 124   lapply (cpy_lift_ge … HT2 … HLK HTU HTU2 ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
 125 ]
 126 qed-.
 127
 128 lemma cpys_inv_lift1_le: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 129                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 130                          dt + et ≤ d →
 131                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 & ⇧[d, e] T2 ≡ U2.
 132 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdetd @(cpys_ind … H) -U2
 133 [ /2 width=3 by ex2_intro/
 134 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 135   elim (cpy_inv_lift1_le … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 136 ]
 137 qed-.
 138
 139 lemma cpys_inv_lift1_be: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 140                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 141                          dt ≤ d → d + e ≤ dt + et →
 142                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et - e] T2 & ⇧[d, e] T2 ≡ U2.
 143 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hdedet @(cpys_ind … H) -U2
 144 [ /2 width=3 by ex2_intro/
 145 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 146   elim (cpy_inv_lift1_be … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 147 ]
 148 qed-.
 149
 150 lemma cpys_inv_lift1_ge: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 151                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 152                          d + e ≤ dt →
 153                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt - e, et] T2 & ⇧[d, e] T2 ≡ U2.
 154 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdedt @(cpys_ind … H) -U2
 155 [ /2 width=3 by ex2_intro/
 156 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 157   elim (cpy_inv_lift1_ge … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 158 ]
 159 qed-.
 160
 161 lemma cpys_inv_lift1_eq: ∀G,L,U1,U2. ∀d,e:nat.
 162                          ⦃G, L⦄ ⊢ U1 ▶*×[d, e] U2 → ∀T1. ⇧[d, e] T1 ≡ U1 → U1 = U2.
 163 #G #L #U1 #U2 #d #e #H #T1 #HTU1 @(cpys_ind … H) -U2 //
 164 #U #U2 #_ #HU2 #IHU destruct
 165 <(cpy_inv_lift1_eq … HTU1 … HU2) -HU2 -HTU1 //
 166 qed-.
 167
 168 lemma cpys_inv_lift1_ge_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 169                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 170                             d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
 171                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[d, dt + et - (d + e)] T2 &
 172                                  ⇧[d, e] T2 ≡ U2.
 173 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet @(cpys_ind … H) -U2
 174 [ /2 width=3 by ex2_intro/
 175 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 176   elim (cpy_inv_lift1_ge_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 177 ]
 178 qed-.
 179
 180 lemma cpys_inv_lift1_be_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 181                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 182                             dt ≤ d → dt + et ≤ d + e →
 183                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 184 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hdetde @(cpys_ind … H) -U2
 185 [ /2 width=3 by ex2_intro/
 186 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 187   elim (cpy_inv_lift1_be_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 188 ]
 189 qed-.
 190
 191 lemma cpys_inv_lift1_le_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 192                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 193                             dt ≤ d → d ≤ dt + et → dt + et ≤ d + e →
 194                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 195 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hddet #Hdetde @(cpys_ind … H) -U2
 196 [ /2 width=3 by ex2_intro/
 197 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 198   elim (cpy_inv_lift1_le_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 199 ]
 200 qed-.