matita/matita/contribs/lambdadelta/basic_2/substitution/cpys_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/cpy_lift.ma".
  16 include "basic_2/substitution/cpys.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED MULTIPLE SUBSTITUTION FOR TERMS ***************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma cpys_subst: ∀I,G,L,K,V,U1,i,d,e.
  23                   d ≤ yinj i → i < d + e →
  24                   ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃G, K⦄ ⊢ V ▶*×[0, ⫰(d+e-i)] U1 →
  25                   ∀U2. ⇧[0, i+1] U1 ≡ U2 → ⦃G, L⦄ ⊢ #i ▶*×[d, e] U2.
  26 #I #G #L #K #V #U1 #i #d #e #Hdi #Hide #HLK #H @(cpys_ind … H) -U1
  27 [ /3 width=5 by cpy_cpys, cpy_subst/
  28 | #U #U1 #_ #HU1 #IHU #U2 #HU12
  29   elim (lift_total U 0 (i+1)) #U0 #HU0
  30   lapply (IHU … HU0) -IHU #H
  31   lapply (ldrop_fwd_ldrop2 … HLK) -HLK #HLK
  32   lapply (cpy_lift_ge … HU1 … HLK HU0 HU12 ?) -HU1 -HLK -HU0 -HU12 // #HU02
  33   lapply (cpy_weak … HU02 d e ? ?) -HU02
  34   [2,3: /2 width=3 by cpys_strap1, yle_succ_dx/ ]
  35   >yplus_O_sn <yplus_inj >ymax_pre_sn_comm /2 width=1 by ylt_fwd_le_succ/
  36 ]
  37 qed.
  38
  39 (* Advanced inverion lemmas *************************************************)
  40
  41 lemma cpys_inv_atom1: ∀I,G,L,T2,d,e. ⦃G, L⦄ ⊢ ⓪{I} ▶*×[d, e] T2 →
  42                       T2 = ⓪{I} ∨
  43                       ∃∃J,K,V1,V2,i. d ≤ yinj i & i < d + e &
  44                                     ⇩[O, i] L ≡ K.ⓑ{J}V1 &
  45                                      ⦃G, K⦄ ⊢ V1 ▶*×[0, d+e-i-1] V2 &
  46                                      ⇧[O, i+1] V2 ≡ T2 &
  47                                      I = LRef i.
  48 #I #G #L #T2 #d #e #H @(cpys_ind … H) -T2
  49 [ /2 width=1 by or_introl/
  50 | #T #T2 #_ #HT2 *
  51   [ #H destruct
  52     elim (cpy_inv_atom1 … HT2) -HT2 [ /2 width=1 by or_introl/ | * /3 width=11 by ex6_5_intro, or_intror/ ]
  53   | * #J #K #V1 #V #i #Hdi #Hide #HLK #HV1 #HVT #HI
  54     lapply (ldrop_fwd_ldrop2 … HLK) #H
  55     elim (cpy_inv_lift1_ge_up … HT2 … H … HVT) -HT2 -H -HVT
  56     [2,3,4: /2 width=1 by ylt_fwd_le_succ, yle_succ_dx/ ]
  57     /4 width=11 by cpys_strap1, ex6_5_intro, or_intror/
  58   ]
  59 ]
  60 qed-.
  61
  62 lemma cpys_inv_lref1: ∀G,L,T2,i,d,e. ⦃G, L⦄ ⊢ #i ▶*×[d, e] T2 →
  63                       T2 = #i ∨
  64                       ∃∃I,K,V1,V2. d ≤ i & i < d + e &
  65                                    ⇩[O, i] L ≡ K.ⓑ{I}V1 &
  66                                    ⦃G, K⦄ ⊢ V1 ▶*×[0, d+e-i-1] V2 &
  67                                    ⇧[O, i+1] V2 ≡ T2.
  68 #G #L #T2 #i #d #e #H elim (cpys_inv_atom1 … H) -H /2 width=1 by or_introl/
  69 * #I #K #V1 #V2 #j #Hdj #Hjde #HLK #HV12 #HVT2 #H destruct /3 width=7 by ex5_4_intro, or_intror/
  70 qed-.
  71
  72 (* Relocation properties ****************************************************)
  73
  74 lemma cpys_lift_le: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
  75                     ∀L,U1,d,e. dt + et ≤ yinj d → ⇩[d, e] L ≡ K →
  76                     ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 →
  77                     ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2.
  78 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hdetd #HLK #HTU1 @(cpys_ind … H) -T2
  79 [ #U2 #H >(lift_mono … HTU1 … H) -H //
  80 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
  81   elim (lift_total T d e) #U #HTU
  82   lapply (IHT … HTU) -IHT #HU1
  83   lapply (cpy_lift_le … HT2 … HLK HTU HTU2 ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
  84 ]
  85 qed-.
  86
  87 lemma cpys_lift_be: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
  88                     ∀L,U1,d,e. dt ≤ yinj d → d ≤ dt + et →
  89                     ⇩[d, e] L ≡ K → ⇧[d, e] T1 ≡ U1 →
  90                     ∀U2. ⇧[d, e] T2 ≡ U2 → ⦃G, L⦄ ⊢ U1 ▶*×[dt, et + e] U2.
  91 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hdtd #Hddet #HLK #HTU1 @(cpys_ind … H) -T2
  92 [ #U2 #H >(lift_mono … HTU1 … H) -H //
  93 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
  94   elim (lift_total T d e) #U #HTU
  95   lapply (IHT … HTU) -IHT #HU1
  96   lapply (cpy_lift_be … HT2 … HLK HTU HTU2 ? ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
  97 ]
  98 qed-.
  99
 100 lemma cpys_lift_ge: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
 101                     ∀L,U1,d,e. yinj d ≤ dt → ⇩[d, e] L ≡ K →
 102                     ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 →
 103                     ⦃G, L⦄ ⊢ U1 ▶*×[dt+e, et] U2.
 104 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hddt #HLK #HTU1 @(cpys_ind … H) -T2
 105 [ #U2 #H >(lift_mono … HTU1 … H) -H //
 106 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
 107   elim (lift_total T d e) #U #HTU
 108   lapply (IHT … HTU) -IHT #HU1
 109   lapply (cpy_lift_ge … HT2 … HLK HTU HTU2 ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
 110 ]
 111 qed-.
 112
 113 lemma cpys_inv_lift1_le: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 114                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 115                          dt + et ≤ d →
 116                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 & ⇧[d, e] T2 ≡ U2.
 117 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdetd @(cpys_ind … H) -U2
 118 [ /2 width=3 by ex2_intro/
 119 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 120   elim (cpy_inv_lift1_le … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 121 ]
 122 qed-.
 123
 124 lemma cpys_inv_lift1_be: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 125                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 126                          dt ≤ d → d + e ≤ dt + et →
 127                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et - e] T2 & ⇧[d, e] T2 ≡ U2.
 128 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hdedet @(cpys_ind … H) -U2
 129 [ /2 width=3 by ex2_intro/
 130 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 131   elim (cpy_inv_lift1_be … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 132 ]
 133 qed-.
 134
 135 lemma cpys_inv_lift1_ge: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 136                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 137                          d + e ≤ dt →
 138                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt - e, et] T2 & ⇧[d, e] T2 ≡ U2.
 139 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdedt @(cpys_ind … H) -U2
 140 [ /2 width=3 by ex2_intro/
 141 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 142   elim (cpy_inv_lift1_ge … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 143 ]
 144 qed-.
 145
 146 lemma cpys_inv_lift1_eq: ∀G,L,U1,U2. ∀d,e:nat.
 147                          ⦃G, L⦄ ⊢ U1 ▶*×[d, e] U2 → ∀T1. ⇧[d, e] T1 ≡ U1 → U1 = U2.
 148 #G #L #U1 #U2 #d #e #H #T1 #HTU1 @(cpys_ind … H) -U2 //
 149 #U #U2 #_ #HU2 #IHU destruct
 150 <(cpy_inv_lift1_eq … HTU1 … HU2) -HU2 -HTU1 //
 151 qed-.
 152
 153 lemma cpys_inv_lift1_ge_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 154                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 155                             d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
 156                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[d, dt + et - (d + e)] T2 &
 157                                  ⇧[d, e] T2 ≡ U2.
 158 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet @(cpys_ind … H) -U2
 159 [ /2 width=3 by ex2_intro/
 160 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 161   elim (cpy_inv_lift1_ge_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 162 ]
 163 qed-.
 164
 165 lemma cpys_inv_lift1_be_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 166                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 167                             dt ≤ d → dt + et ≤ d + e →
 168                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 169 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hdetde @(cpys_ind … H) -U2
 170 [ /2 width=3 by ex2_intro/
 171 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 172   elim (cpy_inv_lift1_be_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 173 ]
 174 qed-.
 175
 176 lemma cpys_inv_lift1_le_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 177                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 178                             dt ≤ d → d ≤ dt + et → dt + et ≤ d + e →
 179                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 180 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hddet #Hdetde @(cpys_ind … H) -U2
 181 [ /2 width=3 by ex2_intro/
 182 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 183   elim (cpy_inv_lift1_le_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 184 ]
 185 qed-.