matita/matita/contribs/lambdadelta/basic_2/substitution/cpys_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/cpy_lift.ma".
  16 include "basic_2/substitution/cpys.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED MULTIPLE SUBSTITUTION FOR TERMS ***************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma cpys_subst: ∀I,G,L,K,V,U1,i,d,e.
  23                   d ≤ i → i < d + e →
  24                   ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃G, K⦄ ⊢ V ▶*×[0, d+e-i-1] U1 →
  25                   ∀U2. ⇧[0, i + 1] U1 ≡ U2 → ⦃G, L⦄ ⊢ #i ▶*×[d, e] U2.
  26 #I #G #L #K #V #U1 #i #d #e #Hdi #Hide #HLK #H @(cpys_ind … H) -U1
  27 [ /3 width=5 by cpy_cpys, cpy_subst/
  28 | #U #U1 #_ #HU1 #IHU #U2 #HU12
  29   elim (lift_total U 0 (i+1)) #U0 #HU0
  30   lapply (IHU … HU0) -IHU #H
  31   lapply (ldrop_fwd_ldrop2 … HLK) -HLK #HLK
  32   lapply (cpy_lift_ge … HU1 … HLK HU0 HU12 ?) -HU1 -HLK -HU0 -HU12 // normalize #HU02
  33   lapply (cpy_weak … HU02 d e ? ?) -HU02 [2,3: /2 width=3 by cpys_strap1, le_S/ ]
  34   >minus_plus >commutative_plus /2 width=1 by le_minus_to_plus_r/
  35 ]
  36 qed.
  37
  38 (* Advanced inverion lemmas *************************************************)
  39
  40 lemma cpys_inv_atom1: ∀G,L,T2,I,d,e. ⦃G, L⦄ ⊢ ⓪{I} ▶*×[d, e] T2 →
  41                       T2 = ⓪{I} ∨
  42                       ∃∃J,K,V1,V2,i. d ≤ i & i < d + e &
  43                                     ⇩[O, i] L ≡ K.ⓑ{J}V1 &
  44                                      ⦃G, K⦄ ⊢ V1 ▶*×[0, d+e-i-1] V2 &
  45                                      ⇧[O, i + 1] V2 ≡ T2 &
  46                                      I = LRef i.
  47 #G #L #T2 #I #d #e #H @(cpys_ind … H) -T2
  48 [ /2 width=1 by or_introl/
  49 | #T #T2 #_ #HT2 *
  50   [ #H destruct
  51     elim (cpy_inv_atom1 … HT2) -HT2 [ /2 width=1 by or_introl/ | * /3 width=11 by ex6_5_intro, or_intror/ ]
  52   | * #J #K #V1 #V #i #Hdi #Hide #HLK #HV1 #HVT #HI
  53     lapply (ldrop_fwd_ldrop2 … HLK) #H
  54     elim (cpy_inv_lift1_ge_up … HT2 … H … HVT) normalize -HT2 -H -HVT [2,3,4: /2 width=1 by le_S/ ]
  55     <minus_plus /4 width=11 by cpys_strap1, ex6_5_intro, or_intror/
  56   ]
  57 ]
  58 qed-.
  59
  60 lemma cpys_inv_lref1: ∀G,L,T2,i,d,e. ⦃G, L⦄ ⊢ #i ▶*×[d, e] T2 →
  61                       T2 = #i ∨
  62                       ∃∃I,K,V1,V2. d ≤ i & i < d + e &
  63                                    ⇩[O, i] L ≡ K.ⓑ{I}V1 &
  64                                    ⦃G, K⦄ ⊢ V1 ▶*×[0, d + e - i - 1] V2 &
  65                                    ⇧[O, i + 1] V2 ≡ T2.
  66 #G #L #T2 #i #d #e #H elim (cpys_inv_atom1 … H) -H /2 width=1 by or_introl/
  67 * #I #K #V1 #V2 #j #Hdj #Hjde #HLK #HV12 #HVT2 #H destruct /3 width=7 by ex5_4_intro, or_intror/
  68 qed-.
  69
  70 (* Relocation properties ****************************************************)
  71
  72 lemma cpys_lift_le: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
  73                     ∀L,U1,d,e. dt + et ≤ d → ⇩[d, e] L ≡ K →
  74                     ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 →
  75                     ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2.
  76 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hdetd #HLK #HTU1 @(cpys_ind … H) -T2
  77 [ #U2 #H >(lift_mono … HTU1 … H) -H //
  78 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
  79   elim (lift_total T d e) #U #HTU
  80   lapply (IHT … HTU) -IHT #HU1
  81   lapply (cpy_lift_le … HT2 … HLK HTU HTU2 ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
  82 ]
  83 qed-.
  84
  85 lemma cpys_lift_be: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
  86                     ∀L,U1,d,e. dt ≤ d → d ≤ dt + et →
  87                     ⇩[d, e] L ≡ K → ⇧[d, e] T1 ≡ U1 →
  88                     ∀U2. ⇧[d, e] T2 ≡ U2 → ⦃G, L⦄ ⊢ U1 ▶*×[dt, et + e] U2.
  89 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hdtd #Hddet #HLK #HTU1 @(cpys_ind … H) -T2
  90 [ #U2 #H >(lift_mono … HTU1 … H) -H //
  91 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
  92   elim (lift_total T d e) #U #HTU
  93   lapply (IHT … HTU) -IHT #HU1
  94   lapply (cpy_lift_be … HT2 … HLK HTU HTU2 ? ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
  95 ]
  96 qed-.
  97
  98 lemma cpys_lift_ge: ∀G,K,T1,T2,dt,et. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 →
  99                     ∀L,U1,d,e. d ≤ dt → ⇩[d, e] L ≡ K →
 100                     ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 →
 101                     ⦃G, L⦄ ⊢ U1 ▶*×[dt + e, et] U2.
 102 #G #K #T1 #T2 #dt #et #H #L #U1 #d #e #Hddt #HLK #HTU1 @(cpys_ind … H) -T2
 103 [ #U2 #H >(lift_mono … HTU1 … H) -H //
 104 | -HTU1 #T #T2 #_ #HT2 #IHT #U2 #HTU2
 105   elim (lift_total T d e) #U #HTU
 106   lapply (IHT … HTU) -IHT #HU1
 107   lapply (cpy_lift_ge … HT2 … HLK HTU HTU2 ?) -HT2 -HLK -HTU -HTU2 /2 width=3 by cpys_strap1/
 108 ]
 109 qed-.
 110
 111 lemma cpys_inv_lift1_le: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 112                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 113                          dt + et ≤ d →
 114                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et] T2 & ⇧[d, e] T2 ≡ U2.
 115 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdetd @(cpys_ind … H) -U2
 116 [ /2 width=3 by ex2_intro/
 117 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 118   elim (cpy_inv_lift1_le … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 119 ]
 120 qed-.
 121
 122 lemma cpys_inv_lift1_be: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 123                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 124                          dt ≤ d → d + e ≤ dt + et →
 125                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, et - e] T2 & ⇧[d, e] T2 ≡ U2.
 126 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hdedet @(cpys_ind … H) -U2
 127 [ /2 width=3 by ex2_intro/
 128 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 129   elim (cpy_inv_lift1_be … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 130 ]
 131 qed-.
 132
 133 lemma cpys_inv_lift1_ge: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 134                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 135                          d + e ≤ dt →
 136                          ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt - e, et] T2 & ⇧[d, e] T2 ≡ U2.
 137 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdedt @(cpys_ind … H) -U2
 138 [ /2 width=3 by ex2_intro/
 139 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 140   elim (cpy_inv_lift1_ge … HU2 … HLK … HTU ?) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 141 ]
 142 qed-.
 143
 144 lemma cpys_inv_lift1_eq: ∀G,L,U1,U2,d,e.
 145                          ⦃G, L⦄ ⊢ U1 ▶*×[d, e] U2 → ∀T1. ⇧[d, e] T1 ≡ U1 → U1 = U2.
 146 #G #L #U1 #U2 #d #e #H #T1 #HTU1 @(cpys_ind … H) -U2 //
 147 #U #U2 #_ #HU2 #IHU destruct
 148 <(cpy_inv_lift1_eq … HU2 … HTU1) -HU2 -HTU1 //
 149 qed-.
 150
 151 lemma cpys_inv_lift1_ge_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 152                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 153                             d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
 154                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[d, dt + et - (d + e)] T2 &
 155                                  ⇧[d, e] T2 ≡ U2.
 156 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet @(cpys_ind … H) -U2
 157 [ /2 width=3 by ex2_intro/
 158 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 159   elim (cpy_inv_lift1_ge_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 160 ]
 161 qed-.
 162
 163 lemma cpys_inv_lift1_be_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 164                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 165                             dt ≤ d → dt + et ≤ d + e →
 166                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 167 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hdetde @(cpys_ind … H) -U2
 168 [ /2 width=3 by ex2_intro/
 169 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 170   elim (cpy_inv_lift1_be_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 171 ]
 172 qed-.
 173
 174 lemma cpys_inv_lift1_le_up: ∀G,L,U1,U2,dt,et. ⦃G, L⦄ ⊢ U1 ▶*×[dt, et] U2 →
 175                             ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
 176                             dt ≤ d → d ≤ dt + et → dt + et ≤ d + e →
 177                             ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶*×[dt, d - dt] T2 & ⇧[d, e] T2 ≡ U2.
 178 #G #L #U1 #U2 #dt #et #H #K #d #e #HLK #T1 #HTU1 #Hdtd #Hddet #Hdetde @(cpys_ind … H) -U2
 179 [ /2 width=3 by ex2_intro/
 180 | -HTU1 #U #U2 #_ #HU2 * #T #HT1 #HTU
 181   elim (cpy_inv_lift1_le_up … HU2 … HLK … HTU) -HU2 -HLK -HTU /3 width=3 by cpys_strap1, ex2_intro/
 182 ]
 183 qed-.