matita/matita/contribs/lambdadelta/basic_2/unfold/cpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/ldrop_append.ma".
  16
  17 (* CONTEXT-SENSITIVE PARALLEL UNFOLD FOR TERMS ******************************)
  18
  19 inductive cpss: lenv → relation term ≝
  20 | cpss_atom : ∀L,I. cpss L (⓪{I}) (⓪{I})
  21 | cpss_subst: ∀L,K,V,V2,W2,i.
  22               ⇩[0, i] L ≡ K. ⓓV → cpss K V V2 →
  23               ⇧[0, i + 1] V2 ≡ W2 → cpss L (#i) W2
  24 | cpss_bind : ∀L,a,I,V1,V2,T1,T2.
  25               cpss L V1 V2 → cpss (L. ⓑ{I} V1) T1 T2 →
  26               cpss L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  27 | cpss_flat : ∀L,I,V1,V2,T1,T2.
  28               cpss L V1 V2 → cpss L T1 T2 →
  29               cpss L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  30 .
  31
  32 interpretation "context-sensitive parallel unfold (term)"
  33    'PSubstStar L T1 T2 = (cpss L T1 T2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 (* Note: it does not hold replacing |L1| with |L2| *)
  38 lemma cpss_lsubr_trans: ∀L1,T1,T2. L1 ⊢ T1 ▶* T2 →
  39                         ∀L2. L2 ⊑ [0, |L1|] L1 → L2 ⊢ T1 ▶* T2.
  40 #L1 #T1 #T2 #H elim H -L1 -T1 -T2
  41 [ //
  42 | #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  43   lapply (ldrop_fwd_ldrop2_length … HLK1) #Hi
  44   lapply (ldrop_fwd_O1_length … HLK1) #H2i
  45   elim (ldrop_lsubr_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // -Hi
  46   <H2i -H2i <minus_plus_m_m /3 width=6/
  47 | /4 width=1/
  48 | /3 width=1/
  49 ]
  50 qed-.
  51
  52 lemma cpss_refl: ∀T,L. L ⊢ T ▶* T.
  53 #T elim T -T //
  54 #I elim I -I /2 width=1/
  55 qed.
  56
  57 lemma cpss_delift: ∀K,V,T1,L,d. ⇩[0, d] L ≡ (K. ⓓV) →
  58                    ∃∃T2,T. L ⊢ T1 ▶* T2 & ⇧[d, 1] T ≡ T2.
  59 #K #V #T1 elim T1 -T1
  60 [ * #i #L #d #HLK /2 width=4/
  61   elim (lt_or_eq_or_gt i d) #Hid /3 width=4/
  62   destruct
  63   elim (lift_total V 0 (i+1)) #W #HVW
  64   elim (lift_split … HVW i i ? ? ?) // /3 width=6/
  65 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  66   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  67   [ elim (IHU1 (L. ⓑ{I} W1) (d+1) ?) -IHU1 /2 width=1/ -HLK /3 width=9/
  68   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8/
  69   ]
  70 ]
  71 qed-.
  72
  73 lemma cpss_append: ∀K,T1,T2. K ⊢ T1 ▶* T2 → ∀L. L @@ K ⊢ T1 ▶* T2.
  74 #K #T1 #T2 #H elim H -K -T1 -T2 // /2 width=1/
  75 #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
  76 lapply (ldrop_fwd_ldrop2_length … HK0) #H
  77 @(cpss_subst … (L@@K0) V1 … HVW2) //
  78 @(ldrop_O1_append_sn_le … HK0) /2 width=2/ (**) (* /3/ does not work *)
  79 qed.
  80
  81 (* Basic inversion lemmas ***************************************************)
  82
  83 fact cpss_inv_atom1_aux: ∀L,T1,T2. L ⊢ T1 ▶* T2 → ∀I. T1 = ⓪{I} →
  84                          T2 = ⓪{I} ∨
  85                          ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  86                                      K ⊢ V ▶* V2 &
  87                                      ⇧[O, i + 1] V2 ≡ T2 &
  88                                      I = LRef i.
  89 #L #T1 #T2 * -L -T1 -T2
  90 [ #L #I #J #H destruct /2 width=1/
  91 | #L #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #I #H destruct /3 width=8/
  92 | #L #a #I #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  93 | #L #I #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  94 ]
  95 qed-.
  96
  97 lemma cpss_inv_atom1: ∀L,T2,I. L ⊢ ⓪{I} ▶* T2 →
  98                       T2 = ⓪{I} ∨
  99                       ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
 100                                   K ⊢ V ▶* V2 &
 101                                   ⇧[O, i + 1] V2 ≡ T2 &
 102                                   I = LRef i.
 103 /2 width=3 by cpss_inv_atom1_aux/ qed-.
 104
 105 lemma cpss_inv_sort1: ∀L,T2,k. L ⊢ ⋆k ▶* T2 → T2 = ⋆k.
 106 #L #T2 #k #H
 107 elim (cpss_inv_atom1 … H) -H //
 108 * #K #V #V2 #i #_ #_ #_ #H destruct
 109 qed-.
 110
 111 lemma cpss_inv_lref1: ∀L,T2,i. L ⊢ #i ▶* T2 →
 112                       T2 = #i ∨
 113                       ∃∃K,V,V2. ⇩[O, i] L ≡ K. ⓓV &
 114                                 K ⊢ V ▶* V2 &
 115                                 ⇧[O, i + 1] V2 ≡ T2.
 116 #L #T2 #i #H
 117 elim (cpss_inv_atom1 … H) -H /2 width=1/
 118 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6/
 119 qed-.
 120
 121 lemma cpss_inv_gref1: ∀L,T2,p. L ⊢ §p ▶* T2 → T2 = §p.
 122 #L #T2 #p #H
 123 elim (cpss_inv_atom1 … H) -H //
 124 * #K #V #V2 #i #_ #_ #_ #H destruct
 125 qed-.
 126
 127 fact cpss_inv_bind1_aux: ∀L,U1,U2. L ⊢ U1 ▶* U2 →
 128                          ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 →
 129                          ∃∃V2,T2. L ⊢ V1 ▶* V2 &
 130                                   L. ⓑ{I} V1 ⊢ T1 ▶* T2 &
 131                                   U2 = ⓑ{a,I} V2. T2.
 132 #L #U1 #U2 * -L -U1 -U2
 133 [ #L #k #a #I #V1 #T1 #H destruct
 134 | #L #K #V #V2 #W2 #i #_ #_ #_ #a #I #V1 #T1 #H destruct
 135 | #L #b #J #V1 #V2 #T1 #T2 #HV12 #HT12 #a #I #V #T #H destruct /2 width=5/
 136 | #L #J #V1 #V2 #T1 #T2 #_ #_ #a #I #V #T #H destruct
 137 ]
 138 qed-.
 139
 140 lemma cpss_inv_bind1: ∀L,a,I,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ▶* U2 →
 141                       ∃∃V2,T2. L ⊢ V1 ▶* V2 &
 142                                L. ⓑ{I} V1 ⊢ T1 ▶* T2 &
 143                                U2 = ⓑ{a,I} V2. T2.
 144 /2 width=3 by cpss_inv_bind1_aux/ qed-.
 145
 146 fact cpss_inv_flat1_aux: ∀L,U1,U2. L ⊢ U1 ▶* U2 →
 147                          ∀I,V1,T1. U1 = ⓕ{I} V1. T1 →
 148                          ∃∃V2,T2. L ⊢ V1 ▶* V2 & L ⊢ T1 ▶* T2 &
 149                                   U2 =  ⓕ{I} V2. T2.
 150 #L #U1 #U2 * -L -U1 -U2
 151 [ #L #k #I #V1 #T1 #H destruct
 152 | #L #K #V #V2 #W2 #i #_ #_ #_ #I #V1 #T1 #H destruct
 153 | #L #a #J #V1 #V2 #T1 #T2 #_ #_ #I #V #T #H destruct
 154 | #L #J #V1 #V2 #T1 #T2 #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 155 ]
 156 qed-.
 157
 158 lemma cpss_inv_flat1: ∀L,I,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ▶* U2 →
 159                       ∃∃V2,T2. L ⊢ V1 ▶* V2 & L ⊢ T1 ▶* T2 &
 160                                U2 =  ⓕ{I} V2. T2.
 161 /2 width=3 by cpss_inv_flat1_aux/ qed-.
 162
 163 (* Basic forward lemmas *****************************************************)
 164
 165 lemma cpss_fwd_tw: ∀L,T1,T2. L ⊢ T1 ▶* T2 → ♯{T1} ≤ ♯{T2}.
 166 #L #T1 #T2 #H elim H -L -T1 -T2 normalize
 167 /3 by monotonic_le_plus_l, le_plus/ (**) (* just /3 width=1/ is too slow *)
 168 qed-.
 169
 170 lemma cpss_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ▶* T →
 171                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 172 #L1 @(lenv_ind_dx … L1) -L1 normalize
 173 [ #L #T1 #T #HT1
 174   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 175 | #I #L1 #V1 #IH #L #T1 #X
 176   >shift_append_assoc normalize #H
 177   elim (cpss_inv_bind1 … H) -H
 178   #V0 #T0 #_ #HT10 #H destruct
 179   elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 180   >append_length >HL12 -HL12
 181   @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 182 ]
 183 qed-.