matita/matita/contribs/lambdadelta/basic_2/unfold/lcpss_cpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/fsup.ma".
  16 include "basic_2/unfold/lcpss_ldrop.ma".
  17
  18 (* SN PARALLEL UNFOLD FOR LOCAL ENVIRONMENTS ********************************)
  19
  20 (* Main properties on context-sensitive parallel unfold for terms ***********)
  21
  22 fact cpss_conf_lcpss_aux: ∀L0,i. (
  23                              ∀L,T0.♯{L, T0} < ♯{L0, #i} →
  24                              ∀T1. L ⊢ T0 ▶* T1 → ∀T2. L ⊢ T0 ▶* T2 →
  25                              ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  26                              ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ T2 ▶* T
  27                           ) →
  28                           ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  29                           ∀V2. K0 ⊢ V0 ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  30                           ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  31                           ∃∃T. L1 ⊢ #i ▶* T & L2 ⊢ T2 ▶* T.
  32 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  33 elim (lcpss_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  34 elim (lcpss_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  35 elim (lcpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  36 elim (lcpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  37 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  38 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  39 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  40 elim (lift_total V 0 (i+1)) #T #HVT
  41 lapply (cpss_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  42 qed-.
  43
  44 theorem cpss_conf_lcpss: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀T2. L0 ⊢ T0 ▶* T2 →
  45                          ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  46                          ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ T2 ▶* T.
  47 #L0 #T0 @(f2_ind … fw … L0 T0) -L0 -T0 #n #IH #L0 * [|*]
  48 [ #I0 #Hn #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
  49   elim (cpss_inv_atom1 … H1) -H1
  50   elim (cpss_inv_atom1 … H2) -H2
  51   [ #H2 #H1 destruct /2 width=3/
  52   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
  53     /3 width=10 by cpss_conf_lcpss_aux/
  54   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
  55     /4 width=10 by ex2_commute, cpss_conf_lcpss_aux/
  56   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
  57     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
  58     lapply (ldrop_mono … H … HLK0) -H #H destruct
  59     elim (lcpss_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  60     elim (lcpss_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  61     lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  62     elim (lcpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  63     elim (lcpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  64     lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  65     lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  66     elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  67     elim (lift_total V 0 (i+1)) #T #HVT
  68     lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  69     lapply (cpss_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  70   ]
  71 | #a #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
  72   elim (cpss_inv_bind1 … H1) -H1 #V1 #T1 #HV01 #HT01 #H destruct
  73   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H destruct
  74   elim (IH … HV01 … HV02 … HL01 … HL02) //
  75   elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  76 | #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
  77   elim (cpss_inv_flat1 … H1) -H1 #V1 #T1 #HV01 #HT01 #H destruct
  78   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H destruct
  79   elim (IH … HV01 … HV02 … HL01 … HL02) //
  80   elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
  81 ]
  82 qed-.
  83
  84 theorem cpss_conf: ∀L. confluent … (cpss L).
  85 /2 width=6 by cpss_conf_lcpss/ qed-.
  86
  87 theorem cpss_trans_lcpss: ∀L1,T1,T. L1 ⊢ T1 ▶* T → ∀L2. L1 ⊢ ▶* L2 →
  88                           ∀T2. L2 ⊢ T ▶* T2 → L1 ⊢ T1 ▶* T2.
  89 #L1 #T1 @(f2_ind … fw … L1 T1) -L1 -T1 #n #IH #L1 * [|*]
  90 [ #I #Hn #T #H1 #L2 #HL12 #T2 #HT2 destruct
  91   elim (cpss_inv_atom1 … H1) -H1
  92   [ #H destruct
  93     elim (cpss_inv_atom1 … HT2) -HT2
  94     [ #H destruct //
  95     | * #K2 #V #V2 #i #HLK2 #HV2 #HVT2 #H destruct
  96       elim (lcpss_ldrop_trans_O1 … HL12 … HLK2) -L2 #X #HLK1 #H
  97       elim (lcpss_inv_pair2 … H) -H #K1 #V1 #HK12 #HV1 #H destruct
  98       lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
  99     ]
 100   | * #K1 #V1 #V #i #HLK1 #HV1 #HVT #H destruct
 101     elim (lcpss_ldrop_conf … HLK1 … HL12) -HL12 #X #H #HLK2
 102     elim (lcpss_inv_pair1 … H) -H #K2 #W2 #HK12 #_ #H destruct
 103     lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
 104     elim (cpss_inv_lift1 … HT2 … HLK2 … HVT) -L2 -T
 105     lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
 106   ]
 107 | #a #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 108   elim (cpss_inv_bind1 … H1) -H1 #V #T #HV1 #HT1 #H destruct
 109   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV2 #HT2 #H destruct /4 width=5/
 110 | #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 111   elim (cpss_inv_flat1 … H1) -H1 #V #T #HV1 #HT1 #H destruct
 112   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV2 #HT2 #H destruct /3 width=5/
 113 ]
 114 qed-.
 115
 116 theorem cpss_trans: ∀L. Transitive … (cpss L).
 117 /2 width=5 by cpss_trans_lcpss/ qed-.
 118
 119 (* Properties on context-sensitive parallel unfold for terms ****************)
 120
 121 lemma lcpss_cpss_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ▶* L1 →
 122                           ∃∃T. L1 ⊢ T0 ▶* T & L1 ⊢ T1 ▶* T.
 123 #L0 #T0 #T1 #HT01 #L1 #HL01
 124 elim (cpss_conf_lcpss … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 125 qed-.
 126
 127 lemma lcpss_cpss_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ▶* L1 →
 128                           ∃∃T. L1 ⊢ T0 ▶* T & L0 ⊢ T1 ▶* T.
 129 #L0 #T0 #T1 #HT01 #L1 #HL01
 130 elim (cpss_conf_lcpss … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 131 qed-.
 132
 133 lemma lcpss_cpss_trans: ∀L1,L2. L1 ⊢ ▶* L2 →
 134                         ∀T1,T2. L2 ⊢ T1 ▶* T2 → L1 ⊢ T1 ▶* T2.
 135 /2 width=5 by cpss_trans_lcpss/ qed-.
 136
 137 lemma fsup_cpss_trans: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ∀U2. L2 ⊢ T2 ▶* U2 →
 138                        ∃∃L,U1. L1 ⊢ ▶* L & L ⊢ T1 ▶* U1 & ⦃L, U1⦄ ⊃ ⦃L2, U2⦄.
 139 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 [1,2,3,4,5: /3 width=5/ ]
 140 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #U2 #HTU2
 141 elim (IHT12 … HTU2) -IHT12 -HTU2 #K #T #HK1 #HT1 #HT2
 142 elim (lift_total T d e) #U #HTU
 143 elim (ldrop_lcpss_trans … HLK1 … HK1) -HLK1 -HK1 #L2 #HL12 #HL2K
 144 lapply (cpss_lift … HT1 … HL2K … HTU1 … HTU) -HT1 -HTU1 /3 width=11/
 145 qed-.