matita/matita/contribs/lambdadelta/basic_2/unfold/lcpss_ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/cpss_lift.ma".
  16 include "basic_2/unfold/lcpss.ma".
  17
  18 (* SN PARALLEL UNFOLD FOR LOCAL ENVIRONMENTS ********************************)
  19
  20 (* Properies on local environment slicing ***********************************)
  21
  22 lemma lcpss_ldrop_conf: dropable_sn lcpss.
  23 #L1 #K1 #d #e #H elim H -L1 -K1 -d -e
  24 [ #d #e #X #H
  25   lapply (lcpss_inv_atom1 … H) -H #H destruct /2 width=3/
  26 | #L1 #I #V1 #X #H
  27   elim (lcpss_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct /3 width=3/
  28 | #L1 #K1 #I #V1 #e #_ #IHLK1 #X #H
  29   elim (lcpss_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct
  30   elim (IHLK1 … HL12) -IHLK1 -HL12 /3 width=3/
  31 | #L1 #K1 #I #V1 #W1 #d #e #HLK1 #HWV1 #IHLK1 #X #H
  32   elim (lcpss_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct
  33   elim (cpss_inv_lift1 … HV12 … HLK1 … HWV1) -HLK1 -V1
  34   elim (IHLK1 … HL12) -IHLK1 -HL12 /3 width=5/
  35 ]
  36 qed-.
  37
  38 lemma ldrop_lcpss_trans: dedropable_sn lcpss.
  39 #L1 #K1 #d #e #H elim H -L1 -K1 -d -e
  40 [ #d #e #X #H
  41   lapply (lcpss_inv_atom1 … H) -H #H destruct /2 width=3/
  42 | #L1 #I #V1 #X #H
  43   elim (lcpss_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct /3 width=3/
  44 | #L1 #K1 #I #V1 #e #_ #IHLK1 #K2 #HK12
  45   elim (IHLK1 … HK12) -IHLK1 -HK12 /3 width=5/
  46 | #L1 #K1 #I #V1 #W1 #d #e #HLK1 #HWV1 #IHLK1 #X #H
  47   elim (lcpss_inv_pair1 … H) -H #L2 #W2 #HL12 #HW12 #H destruct
  48   elim (lift_total W2 d e) #V2 #HWV2
  49   lapply (cpss_lift … HW12 … HLK1 … HWV1 … HWV2) -W1 -HLK1
  50   elim (IHLK1 … HL12) -IHLK1 -HL12 /3 width=5/
  51 ]
  52 qed-.
  53
  54 fact lcpss_ldrop_trans_O1_aux: ∀L2,K2,d,e. ⇩[d, e] L2 ≡ K2 → ∀L1. L1 ⊢ ▶* L2 →
  55                                d = 0 → ∃∃K1. ⇩[0, e] L1 ≡ K1 & K1 ⊢ ▶* K2.
  56 #L2 #K2 #d #e #H elim H -L2 -K2 -d -e
  57 [ #d #e #X #H >(lcpss_inv_atom2 … H) -H /2 width=3/
  58 | #K2 #I #V2 #X #H
  59   elim (lcpss_inv_pair2 … H) -H #K1 #V1 #HK12 #HV12 #H destruct /3 width=5/
  60 | #L2 #K2 #I #V2 #e #_ #IHLK2 #X #H #_
  61   elim (lcpss_inv_pair2 … H) -H #L1 #V1 #HL12 #HV12 #H destruct
  62   elim (IHLK2 … HL12 ?) -L2 // /3 width=3/
  63 | #L2 #K2 #I #V2 #W2 #d #e #_ #_ #_ #L1 #_
  64   >commutative_plus normalize #H destruct
  65 ]
  66 qed-.
  67
  68 lemma lcpss_ldrop_trans_O1: dropable_dx lcpss.
  69 /2 width=5 by lcpss_ldrop_trans_O1_aux/ qed-.