matita/matita/contribs/lambdadelta/basic_2/unfold/lpqs_cpqs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lpx_sn_lpx_sn.ma".
  16 include "basic_2/relocation/fsup.ma".
  17 include "basic_2/unfold/lpqs_ldrop.ma".
  18
  19 (* SN RESTRICTED PARALLEL COMPUTATION FOR LOCAL ENVIRONMENTS ****************)
  20
  21 (* Main properties on context-sensitive rest parallel computation for terms *)
  22
  23 fact cpqs_conf_lpqs_atom_atom:
  24    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ➤* T & L2 ⊢ ⓪{I} ➤* T.
  25 /2 width=3/ qed-.
  26
  27 fact cpqs_conf_lpqs_atom_delta:
  28    ∀L0,i. (
  29       ∀L,T.♯{L, T} < ♯{L0, #i} →
  30       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  31       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  32       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  33    ) →
  34    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  35    ∀V2. K0 ⊢ V0 ➤* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  36    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  37    ∃∃T. L1 ⊢ #i ➤* T & L2 ⊢ T2 ➤* T.
  38 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  39 elim (lpqs_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  40 elim (lpqs_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  41 elim (lpqs_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  42 elim (lpqs_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  43 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  44 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  45 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  46 elim (lift_total V 0 (i+1)) #T #HVT
  47 lapply (cpqs_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  48 qed-.
  49
  50 fact cpqs_conf_lpqs_delta_delta:
  51    ∀L0,i. (
  52       ∀L,T.♯{L, T} < ♯{L0, #i} →
  53       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  54       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  55       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  56    ) →
  57    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  58    ∀V1. K0 ⊢ V0 ➤* V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  59    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  60    ∀V2. KX ⊢ VX ➤* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  61    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  62    ∃∃T. L1 ⊢ T1 ➤* T & L2 ⊢ T2 ➤* T.
  63 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  64 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  65 lapply (ldrop_mono … H … HLK0) -H #H destruct
  66 elim (lpqs_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  67 elim (lpqs_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  68 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  69 elim (lpqs_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  70 elim (lpqs_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  71 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  72 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  73 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  74 elim (lift_total V 0 (i+1)) #T #HVT
  75 lapply (cpqs_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  76 lapply (cpqs_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  77 qed-.
  78
  79 fact cpqs_conf_lpqs_bind_bind:
  80    ∀a,I,L0,V0,T0. (
  81       ∀L,T.♯{L,T} < ♯{L0,ⓑ{a,I}V0.T0} →
  82       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  83       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  84       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  85    ) →
  86    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➤* T1 →
  87    ∀V2. L0 ⊢ V0 ➤* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ➤* T2 →
  88    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  89    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ➤* T & L2 ⊢ ⓑ{a,I}V2.T2 ➤* T.
  90 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  91 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  92 elim (IH … HV01 … HV02 … HL01 … HL02) //
  93 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  94 qed-.
  95
  96 fact cpqs_conf_lpqs_bind_zeta:
  97    ∀L0,V0,T0. (
  98       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
  99       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 100       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 101       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 102    ) →
 103    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0.ⓓV0 ⊢ T0 ➤* T1 →
 104    ∀T2. L0.ⓓV0 ⊢ T0 ➤* T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 105    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 106    ∃∃T. L1 ⊢ +ⓓV1.T1 ➤* T & L2 ⊢ X2 ➤* T.
 107 #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 108 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 109 elim (IH … HT01 … HT02 (L1.ⓓV1) … (L2.ⓓV1)) -IH -HT01 -HT02 // /2 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 110 elim (cpqs_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ /3 width=3/
 111 qed-.
 112
 113 fact cpqs_conf_lpqs_zeta_zeta:
 114    ∀L0,V0,T0. (
 115       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
 116       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 117       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 118       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 119    ) →
 120    ∀T1. L0.ⓓV0 ⊢ T0 ➤* T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 121    ∀T2. L0.ⓓV0 ⊢ T0 ➤* T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 122    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 123    ∃∃T. L1 ⊢ X1 ➤* T & L2 ⊢ X2 ➤* T.
 124 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 125 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 126 elim (IH … HT01 … HT02 (L1.ⓓV0) … (L2.ⓓV0)) -IH -HT01 -HT02 // /2 width=1/ -L0 -T0 #T #HT1 #HT2
 127 elim (cpqs_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ #T1 #HT1 #HXT1
 128 elim (cpqs_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ #T2 #HT2 #HXT2
 129 lapply (lift_inj … HT2 … HT1) -T #H destruct /2 width=3/
 130 qed-.
 131
 132 fact cpqs_conf_lpqs_flat_flat:
 133    ∀I,L0,V0,T0. (
 134       ∀L,T.♯{L,T} < ♯{L0,ⓕ{I}V0.T0} →
 135       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 136       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 137       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 138    ) →
 139    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0 ⊢ T0 ➤* T1 →
 140    ∀V2. L0 ⊢ V0 ➤* V2 → ∀T2. L0 ⊢ T0 ➤* T2 →
 141    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 142    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ➤* T & L2 ⊢ ⓕ{I}V2.T2 ➤* T.
 143 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 144 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 145 elim (IH … HV01 … HV02 … HL01 … HL02) //
 146 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 147 qed-.
 148
 149 fact cpqs_conf_lpqs_flat_tau:
 150    ∀L0,V0,T0. (
 151       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 152       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 153       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 154       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 155    ) →
 156    ∀V1,T1. L0 ⊢ T0 ➤* T1 → ∀T2. L0 ⊢ T0 ➤* T2 →
 157    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 158    ∃∃T. L1 ⊢ ⓝV1.T1 ➤* T & L2 ⊢ T2 ➤* T.
 159 #L0 #V0 #T0 #IH #V1 #T1 #HT01
 160 #T2 #HT02 #L1 #HL01 #L2 #HL02
 161 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 162 qed-.
 163
 164 fact cpqs_conf_lpqs_tau_tau:
 165    ∀L0,V0,T0. (
 166       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 167       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 168       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 169       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 170    ) →
 171    ∀T1. L0 ⊢ T0 ➤* T1 → ∀T2. L0 ⊢ T0 ➤* T2 →
 172    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 173    ∃∃T. L1 ⊢ T1 ➤* T & L2 ⊢ T2 ➤* T.
 174 #L0 #V0 #T0 #IH #T1 #HT01
 175 #T2 #HT02 #L1 #HL01 #L2 #HL02
 176 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /2 width=3/
 177 qed-.
 178
 179 theorem cpqs_conf_lpqs: lpx_sn_confluent cpqs cpqs.
 180 #L0 #T0 @(f2_ind … fw … L0 T0) -L0 -T0 #n #IH #L0 * [|*]
 181 [ #I0 #Hn #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 182   elim (cpqs_inv_atom1 … H1) -H1
 183   elim (cpqs_inv_atom1 … H2) -H2
 184   [ #H2 #H1 destruct
 185     /2 width=1 by cpqs_conf_lpqs_atom_atom/
 186   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 187     /3 width=10 by cpqs_conf_lpqs_atom_delta/
 188   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 189     /4 width=10 by ex2_commute, cpqs_conf_lpqs_atom_delta/
 190   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 191     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 192     /3 width=17 by cpqs_conf_lpqs_delta_delta/
 193   ]
 194 | #a #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 195   elim (cpqs_inv_bind1 … H1) -H1 *
 196   [ #V1 #T1 #HV01 #HT01 #H1
 197   | #T1 #HT01 #HXT1 #H11 #H12
 198   ]
 199   elim (cpqs_inv_bind1 … H2) -H2 *
 200   [1,3: #V2 #T2 #HV02 #HT02 #H2
 201   |2,4: #T2 #HT02 #HXT2 #H21 #H22
 202   ] destruct
 203   [ /3 width=10 by cpqs_conf_lpqs_bind_bind/
 204   | /4 width=11 by ex2_commute, cpqs_conf_lpqs_bind_zeta/
 205   | /3 width=11 by cpqs_conf_lpqs_bind_zeta/
 206   | /3 width=12 by cpqs_conf_lpqs_zeta_zeta/
 207   ]
 208 | #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 209   elim (cpqs_inv_flat1 … H1) -H1 *
 210   [ #V1 #T1 #HV01 #HT01 #H1
 211   | #HX1 #H1
 212   ]
 213   elim (cpqs_inv_flat1 … H2) -H2 *
 214   [1,3: #V2 #T2 #HV02 #HT02 #H2
 215   |2,4: #HX2 #H2
 216   ] destruct
 217   [ /3 width=10 by cpqs_conf_lpqs_flat_flat/
 218   | /4 width=8 by ex2_commute, cpqs_conf_lpqs_flat_tau/
 219   | /3 width=8 by cpqs_conf_lpqs_flat_tau/
 220   | /3 width=7 by cpqs_conf_lpqs_tau_tau/
 221   ]
 222 ]
 223 qed-.
 224
 225 theorem cpqs_conf: ∀L. confluent … (cpqs L).
 226 /2 width=6 by cpqs_conf_lpqs/ qed-.
 227
 228 theorem cpqs_trans_lpqs: lpx_sn_transitive cpqs cpqs.
 229 #L1 #T1 @(f2_ind … fw … L1 T1) -L1 -T1 #n #IH #L1 * [|*]
 230 [ #I #Hn #T #H1 #L2 #HL12 #T2 #HT2 destruct
 231   elim (cpqs_inv_atom1 … H1) -H1
 232   [ #H destruct
 233     elim (cpqs_inv_atom1 … HT2) -HT2
 234     [ #H destruct //
 235     | * #K2 #V #V2 #i #HLK2 #HV2 #HVT2 #H destruct
 236       elim (lpqs_ldrop_trans_O1 … HL12 … HLK2) -L2 #X #HLK1 #H
 237       elim (lpqs_inv_pair2 … H) -H #K1 #V1 #HK12 #HV1 #H destruct
 238       lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
 239     ]
 240   | * #K1 #V1 #V #i #HLK1 #HV1 #HVT #H destruct
 241     elim (lpqs_ldrop_conf … HLK1 … HL12) -HL12 #X #H #HLK2
 242     elim (lpqs_inv_pair1 … H) -H #K2 #W2 #HK12 #_ #H destruct
 243     lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
 244     elim (cpqs_inv_lift1 … HT2 … HLK2 … HVT) -L2 -T
 245     lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
 246   ]
 247 | #a #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 248   elim (cpqs_inv_bind1 … H1) -H1 *
 249   [ #V #T #HV1 #HT1 #H destruct
 250     elim (cpqs_inv_bind1 … H2) -H2 *
 251     [ #V2 #T2 #HV2 #HT2 #H destruct /4 width=5/
 252     | #T2 #HT2 #HXT2 #H1 #H2 destruct /4 width=5/
 253     ]
 254   | #Y1 #HTY1 #HXY1 #H11 #H12 destruct
 255     elim (lift_total X2 0 1) #Y2 #HXY2
 256     lapply (cpqs_lift … H2 (L2.ⓓV1) … HXY1 … HXY2) /2 width=1/ -X1 /4 width=5/
 257   ]
 258 | #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 259   elim (cpqs_inv_flat1 … H1) -H1 *
 260   [ #V #T #HV1 #HT1 #H destruct
 261     elim (cpqs_inv_flat1 … H2) -H2 *
 262     [ #V2 #T2 #HV2 #HT2 #H destruct /3 width=5/
 263     | #HX2 #H destruct /3 width=5/
 264     ]
 265   | #HX1 #H destruct /3 width=5/
 266 ]
 267 qed-.
 268
 269 theorem cpqs_trans: ∀L. Transitive … (cpqs L).
 270 /2 width=5 by cpqs_trans_lpqs/ qed-.
 271
 272 (* Properties on context-sensitive rest. parallel computation for terms *****)
 273
 274 lemma lpqs_cpqs_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➤* T1 → ∀L1. L0 ⊢ ➤* L1 →
 275                          ∃∃T. L1 ⊢ T0 ➤* T & L1 ⊢ T1 ➤* T.
 276 #L0 #T0 #T1 #HT01 #L1 #HL01
 277 elim (cpqs_conf_lpqs … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 278 qed-.
 279
 280 lemma lpqs_cpqs_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➤* T1 → ∀L1. L0 ⊢ ➤* L1 →
 281                          ∃∃T. L1 ⊢ T0 ➤* T & L0 ⊢ T1 ➤* T.
 282 #L0 #T0 #T1 #HT01 #L1 #HL01
 283 elim (cpqs_conf_lpqs … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 284 qed-.
 285
 286 lemma lpqs_cpqs_trans: ∀L1,L2. L1 ⊢ ➤* L2 →
 287                        ∀T1,T2. L2 ⊢ T1 ➤* T2 → L1 ⊢ T1 ➤* T2.
 288 /2 width=5 by cpqs_trans_lpqs/ qed-.
 289
 290 lemma fsup_cpqs_trans: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ∀U2. L2 ⊢ T2 ➤* U2 →
 291                        ∃∃L,U1. L1 ⊢ ➤* L & L ⊢ T1 ➤* U1 & ⦃L, U1⦄ ⊃ ⦃L2, U2⦄.
 292 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 [1,2,3,4,5: /3 width=5/ ]
 293 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #U2 #HTU2
 294 elim (IHT12 … HTU2) -IHT12 -HTU2 #K #T #HK1 #HT1 #HT2
 295 elim (lift_total T d e) #U #HTU
 296 elim (ldrop_lpqs_trans … HLK1 … HK1) -HLK1 -HK1 #L2 #HL12 #HL2K
 297 lapply (cpqs_lift … HT1 … HL2K … HTU1 … HTU) -HT1 -HTU1 /3 width=11/
 298 qed-.