matita/matita/contribs/lambdadelta/basic_2A/substitution/drop_lreq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/ynat/ynat_minus_sn.ma".
  16 include "basic_2A/grammar/lreq_lreq.ma".
  17 include "basic_2A/substitution/drop.ma".
  18
  19 (* BASIC SLICING FOR LOCAL ENVIRONMENTS *************************************)
  20
  21 definition dedropable_sn: predicate (relation lenv) ≝
  22                           λR. ∀L1,K1,s,l,m. ⬇[s, l, m] L1 ≡ K1 → ∀K2. R K1 K2 →
  23                           ∃∃L2. R L1 L2 & ⬇[s, l, m] L2 ≡ K2 & L1 ⩬[l, m] L2.
  24
  25 (* Properties on equivalence ************************************************)
  26
  27 lemma lreq_drop_trans_be: ∀L1,L2,l,m. L1 ⩬[l, m] L2 →
  28                           ∀I,K2,W,s,i. ⬇[s, 0, i] L2 ≡ K2.ⓑ{I}W →
  29                           l ≤ i → i < l + m →
  30                           ∃∃K1. K1 ⩬[0, ↓(l+m-i)] K2 & ⬇[s, 0, i] L1 ≡ K1.ⓑ{I}W.
  31 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m
  32 [ #l #m #J #K2 #W #s #i #H
  33   elim (drop_inv_atom1 … H) -H #H destruct
  34 | #I1 #I2 #L1 #L2 #V1 #V2 #_ #_ #J #K2 #W #s #i #_ #_ #H
  35   elim (ylt_yle_false … H) //
  36 | #I #L1 #L2 #V #m #HL12 #IHL12 #J #K2 #W #s #i #H #_ >yplus_O1
  37   elim (drop_inv_O1_pair1 … H) -H * #Hi #HLK1 [ -IHL12 | -HL12 ]
  38   [ #_ destruct >ypred_succ
  39     /2 width=3 by drop_pair, ex2_intro/
  40   | <(S_pred … Hi) <ysucc_inj #Him
  41     lapply (ylt_inv_succ … Him) -Him #Him
  42     elim (IHL12 … HLK1) -IHL12 -HLK1 // -Him
  43     >yminus_succ /3 width=3 by drop_drop_lt, ex2_intro/
  44   ]
  45 | #I1 #I2 #L1 #L2 #V1 #V2 #l #m #_ #IHL12 #J #K2 #W #s #i #HLK2 #Hli
  46   elim (yle_inv_succ_sn_lt … Hli) -Hli #Hli #Hi
  47   lapply (ylt_inv_inj … Hi) -Hi #Hi
  48   <(S_pred … Hi) >yplus_succ1 <ysucc_inj #H
  49   lapply (ylt_inv_succ … H) -H #Hilm
  50   lapply (drop_inv_drop1_lt … HLK2 Hi) -HLK2 #HLK1
  51   elim (IHL12 … HLK1) -IHL12 -HLK1 >minus_SO_dx
  52   /3 width=3 by drop_drop_lt, ex2_intro/
  53 ]
  54 qed-.
  55
  56 lemma lreq_drop_conf_be: ∀L1,L2,l,m. L1 ⩬[l, m] L2 →
  57                          ∀I,K1,W,s,i. ⬇[s, 0, i] L1 ≡ K1.ⓑ{I}W →
  58                          l ≤ i → i < l + m →
  59                          ∃∃K2. K1 ⩬[0, ↓(l+m-i)] K2 & ⬇[s, 0, i] L2 ≡ K2.ⓑ{I}W.
  60 #L1 #L2 #l #m #HL12 #I #K1 #W #s #i #HLK1 #Hli #Hilm
  61 elim (lreq_drop_trans_be … (lreq_sym … HL12) … HLK1) // -L1 -Hli -Hilm
  62 /3 width=3 by lreq_sym, ex2_intro/
  63 qed-.
  64
  65 lemma drop_O1_ex: ∀K2,i,L1. |L1| = |K2| + i →
  66                   ∃∃L2. L1 ⩬[0, i] L2 & ⬇[i] L2 ≡ K2.
  67 #K2 #i @(nat_ind_plus … i) -i
  68 [ /3 width=3 by lreq_O2, ex2_intro/
  69 | #i #IHi #Y #Hi elim (drop_O1_lt (Ⓕ) Y 0) //
  70   #I #L1 #V #H lapply (drop_inv_O2 … H) -H #H destruct
  71   normalize in Hi; elim (IHi L1) -IHi
  72   /3 width=5 by drop_drop, lreq_pair, injective_plus_l, ex2_intro/
  73 ]
  74 qed-.
  75
  76 lemma dedropable_sn_TC: ∀R. dedropable_sn R → dedropable_sn (TC … R).
  77 #R #HR #L1 #K1 #s #l #m #HLK1 #K2 #H elim H -K2
  78 [ #K2 #HK12 elim (HR … HLK1 … HK12) -HR -K1
  79   /3 width=4 by inj, ex3_intro/
  80 | #K #K2 #_ #HK2 * #L #H1L1 #HLK #H2L1 elim (HR … HLK … HK2) -HR -K
  81   /3 width=6 by lreq_trans, step, ex3_intro/
  82 ]
  83 qed-.
  84
  85 (* Inversion lemmas on equivalence ******************************************)
  86
  87 lemma drop_O1_inj: ∀i,L1,L2,K. ⬇[i] L1 ≡ K → ⬇[i] L2 ≡ K → L1 ⩬[i, ∞] L2.
  88 #i @(nat_ind_plus … i) -i
  89 [ #L1 #L2 #K #H <(drop_inv_O2 … H) -K #H <(drop_inv_O2 … H) -L1 //
  90 | #i #IHi * [2: #L1 #I1 #V1 ] * [2,4: #L2 #I2 #V2 ] #K #HLK1 #HLK2 //
  91   lapply (drop_fwd_length … HLK1)
  92   <(drop_fwd_length … HLK2) [ /4 width=5 by drop_inv_drop1, lreq_succ/ ]
  93   normalize <plus_n_Sm #H destruct
  94 ]
  95 qed-.