matita/matita/contribs/lambdadelta/delayed_updating/syntax/path_proper.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/syntax/path.ma".
  16 include "delayed_updating/notation/functions/class_p_0.ma".
  17 include "ground/lib/subset.ma".
  18 include "ground/xoa/ex_1_2.ma".
  19
  20 (* PROPER CONDITION FOR PATH ************************************************)
  21
  22 definition ppc: predicate path ≝
  23            λp. 𝐞 = p → ⊥
  24 .
  25
  26 interpretation
  27   "proper condition (path)"
  28   'ClassP = (ppc).
  29
  30 (* Basic constructions ******************************************************)
  31
  32 lemma ppc_rcons (p) (l):
  33       p◖l ϵ 𝐏.
  34 #p #l #H0 destruct
  35 qed.
  36
  37 lemma ppc_lcons (p) (l):
  38       l◗p ϵ 𝐏.
  39 #p #l #H0
  40 elim (eq_inv_list_empty_rcons ??? H0)
  41 qed.
  42
  43 (* Basic inversions ********************************************************)
  44
  45 lemma ppc_inv_empty:
  46       (𝐞) ϵ 𝐏 → ⊥.
  47 #H0 @H0 -H0 //
  48 qed-.
  49
  50 lemma ppc_inv_rcons (p):
  51       p ϵ 𝐏 → ∃∃q,l. q◖l = p.
  52 *
  53 [ #H0 elim (ppc_inv_empty … H0)
  54 | #l #q #_ /2 width=3 by ex1_2_intro/
  55 ]
  56 qed-.
  57
  58 lemma ppc_inv_lcons (p):
  59       p ϵ 𝐏 → ∃∃q,l. l◗q = p.
  60 #p @(list_ind_rcons … p) -p
  61 [ #H0 elim (ppc_inv_empty … H0)
  62 | #q #l #_ #_ /2 width=3 by ex1_2_intro/
  63 ]
  64 qed-.