matita/matita/contribs/lambdadelta/ground/arith/nat_lt_minus_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/nat_le_minus_plus.ma".
  16 include "ground/arith/nat_lt_minus.ma".
  17
  18 (* STRICT ORDER FOR NON-NEGATIVE INTEGERS ***********************************)
  19
  20 (* Constructions with nminus and nplus **************************************)
  21
  22 (*** lt_plus_to_minus *)
  23 lemma nlt_minus_sn (o) (m) (n): m ≤ n → n < o + m → n - m < o.
  24 #o #m #n #Hmn #Ho
  25 lapply (nle_minus_sn_sn … Ho) -Ho
  26 <nminus_succ_sn //
  27 qed.
  28
  29 (*** lt_plus_to_minus_r *)
  30 lemma nlt_minus_dx (o) (m) (n): m + o < n → m < n - o.
  31 /2 width=1 by nle_minus_dx_sn/ qed.
  32
  33 (*** lt_inv_plus_l *)
  34 lemma nlt_minus_dx_full (o) (m) (n): m + o < n → ∧∧ o < n & m < n - o.
  35 /3 width=3 by nlt_minus_dx, nle_nlt_trans, conj/ qed-.
  36
  37 (* Inversions with nminus and nplus *****************************************)
  38
  39 (*** lt_minus_to_plus *)
  40 lemma nlt_inv_minus_sn (o) (m) (n): m - o < n → m < n + o.
  41 #o #m #n #Ho
  42 @nle_inv_minus_sn
  43 @(nle_trans … Ho) -Ho //
  44 qed-.
  45
  46 (*** lt_minus_to_plus_r *)
  47 lemma nlt_inv_minus_dx (o) (m) (n): m < n - o → m + o < n.
  48 #o #m #n #Ho
  49 lapply (nle_inv_minus_dx ???? Ho) //
  50 /3 width=2 by nlt_des_minus_dx, nlt_des_le/
  51 qed-.