matita/matita/contribs/lambdadelta/ground/arith/nat_lt_pred.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/nat_le_pred.ma".
  16 include "ground/arith/nat_lt.ma".
  17
  18 (* STRICT ORDER FOR NON-NEGATIVE INTEGERS ***********************************)
  19
  20 (* Destructions with npred **************************************************)
  21
  22 (*** S_pred lt_succ_pred lt_inv_O1 *)
  23 lemma nlt_des_gen (m) (n): m < n → n = ↑↓n.
  24 #m #n @(nat_ind_succ … n) -n //
  25 #H elim (nlt_inv_zero_dx … H)
  26 qed-.
  27
  28 (* Inversions with npred ****************************************************)
  29
  30 (*** lt_inv_gen *)
  31 lemma nlt_inv_gen (m) (n): m < n → ∧∧ m ≤ ↓n & n = ↑↓n.
  32 /2 width=1 by nle_inv_succ_sn/ qed-.
  33
  34 (*** lt_inv_S1 *)
  35 lemma nlt_inv_succ_sn (m) (n): ↑m < n → ∧∧ m < ↓n & n = ↑↓n.
  36 /2 width=1 by nle_inv_succ_sn/ qed-.
  37
  38 lemma nlt_inv_pred_dx (m) (n): m < ↓n → ↑m < n.
  39 #m #n #H >(nlt_des_gen (𝟎) n)
  40 [ /2 width=1 by nlt_succ_bi/
  41 | /3 width=3 by nle_nlt_trans, nlt_nle_trans/
  42 ]
  43 qed-.
  44
  45 lemma nlt_inv_pred_bi (m) (n):
  46       ↓m < ↓n → m < n.
  47 /3 width=3 by nlt_inv_pred_dx, nle_nlt_trans/
  48 qed-.
  49
  50 (* Constructions with npred *************************************************)
  51
  52 lemma nlt_zero_sn (n): n = ↑↓n → 𝟎 < n.
  53 // qed.
  54
  55 (*** monotonic_lt_pred *)
  56 lemma nlt_pred_bi (m) (n): 𝟎 < m → m < n → ↓m < ↓n.
  57 #m #n #Hm #Hmn
  58 @nle_inv_succ_bi
  59 <(nlt_des_gen … Hm) -Hm
  60 <(nlt_des_gen … Hmn) //
  61 qed.