matita/matita/contribs/lambdadelta/ground/arith/pnat_lt_pred.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/pnat_le_pred.ma".
  16 include "ground/arith/pnat_lt.ma".
  17
  18 (* STRICT ORDER FOR POSITIVE INTEGERS ***************************************)
  19
  20 (* Destructions with ppred **************************************************)
  21
  22 lemma plt_des_gen (p) (q): p < q → q = ↑↓q.
  23 #p #q elim q -q //
  24 #H elim (plt_inv_unit_dx … H)
  25 qed-.
  26
  27 (* Inversions with ppred ****************************************************)
  28
  29 lemma plt_inv_gen (p) (q): p < q → ∧∧ p ≤ ↓q & q = ↑↓q.
  30 /2 width=1 by ple_inv_succ_sn/ qed-.
  31
  32 lemma plt_inv_succ_sn (p) (q): ↑p < q → ∧∧ p < ↓q & q = ↑↓q.
  33 /2 width=1 by ple_inv_succ_sn/ qed-.
  34
  35 lemma plt_inv_pred_dx (p) (q): p < ↓q → ↑p < q.
  36 #p #q #H >(plt_des_gen (𝟏) q)
  37 [ /2 width=1 by plt_succ_bi/
  38 | /3 width=3 by ple_plt_trans, plt_ple_trans/
  39 ]
  40 qed-.
  41
  42 lemma plt_inv_pred_bi (p) (q):
  43       ↓p < ↓q → p < q.
  44 /3 width=3 by plt_inv_pred_dx, ple_plt_trans/
  45 qed-.
  46
  47 (* Constructions with ppred *************************************************)
  48
  49 lemma plt_unit_sn (q): q = ↑↓q → 𝟏 < q.
  50 // qed.
  51
  52 lemma plt_pred_bi (p) (q): 𝟏 < p → p < q → ↓p < ↓q.
  53 #p #q #Hp #Hpq
  54 @ple_inv_succ_bi
  55 <(plt_des_gen … Hp) -Hp
  56 <(plt_des_gen … Hpq) //
  57 qed.