matita/matita/contribs/lambdadelta/ground/counters/rtc_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_6_8.ma".
  16 include "ground/arith/nat_plus.ma".
  17 include "ground/counters/rtc.ma".
  18
  19 (* ADDITION FOR RT-TRANSITION COUNTERS **************************************)
  20
  21 definition rtc_plus (c1:rtc) (c2:rtc): rtc ≝
  22 match c1 with
  23 [ mk_rtc ri1 rs1 ti1 ts1 ⇒
  24   match c2 with
  25   [ mk_rtc ri2 rs2 ti2 ts2 ⇒ 〈ri1+ri2,rs1+rs2,ti1+ti2,ts1+ts2〉
  26   ]
  27 ].
  28
  29 interpretation
  30   "addition (rt-transition counters)"
  31   'plus c1 c2 = (rtc_plus c1 c2).
  32
  33 (* Basic constructions ******************************************************)
  34
  35 (*** rtc_plus_rew *)
  36 lemma rtc_plus_unfold (ri1) (ri2) (rs1) (rs2) (ti1) (ti2) (ts1) (ts2):
  37       〈ri1+ri2,rs1+rs2,ti1+ti2,ts1+ts2〉 = 〈ri1,rs1,ti1,ts1〉+〈ri2,rs2,ti2,ts2〉.
  38 // qed.
  39
  40 lemma rtc_plus_zz_dx (c): c = c + 𝟘𝟘.
  41 * #ri #rs #ti #ts <rtc_plus_unfold //
  42 qed.
  43
  44 (* Basic inversions *********************************************************)
  45
  46 lemma rtc_plus_inv_dx (ri) (rs) (ti) (ts) (c1) (c2):
  47       〈ri,rs,ti,ts〉 = c1 + c2 →
  48       ∃∃ri1,rs1,ti1,ts1,ri2,rs2,ti2,ts2.
  49       ri1+ri2 = ri & rs1+rs2 = rs & ti1+ti2 = ti & ts1+ts2 = ts &
  50       〈ri1,rs1,ti1,ts1〉 = c1 & 〈ri2,rs2,ti2,ts2〉 = c2.
  51 #ri #rs #ti #ts * #ri1 #rs1 #ti1 #ts1 * #ri2 #rs2 #ti2 #ts2
  52 <rtc_plus_unfold #H destruct /2 width=14 by ex6_8_intro/
  53 qed-.
  54
  55 (* Main constructions *******************************************************)
  56
  57 theorem rtc_plus_assoc: associative … rtc_plus.
  58 * #ri1 #rs1 #ti1 #ts1 * #ri2 #rs2 #ti2 #ts2 * #ri3 #rs3 #ti3 #ts3
  59 <rtc_plus_unfold //
  60 qed.