matita/matita/contribs/lambdadelta/ground/relocation/pr_after_isi.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/pr_isi.ma".
  16 include "ground/relocation/pr_after_after.ma".
  17
  18 (* RELATIONAL COMPOSITION FOR PARTIAL RELOCATION MAPS ***********************)
  19
  20 (* Constructions with pr_isi ************************************************)
  21
  22 (*** after_isid_sn *)
  23 corec lemma pr_after_isi_sn:
  24             ∀f1. 𝐈❨f1❩ → ∀f2. f1 ⊚ f2 ≘ f2.
  25 #f1 * -f1
  26 #f1 #g1 #Hf1 #H1 #f2 cases (pr_map_split_tl f2) #H2
  27 /3 width=7 by pr_after_push, pr_after_refl/
  28 qed.
  29
  30 (*** after_isid_dx *)
  31 corec lemma pr_after_isi_dx:
  32             ∀f2. 𝐈❨f2❩ → ∀f1. f1 ⊚ f2 ≘ f1.
  33 #f2 * -f2
  34 #f2 #g2 #Hf2 #H2 #f1 cases (pr_map_split_tl f1) #H1
  35 [ /3 width=7 by pr_after_refl/
  36 | @(pr_after_next … H1 H1) /3 width=3 by pr_isi_push/
  37 ]
  38 qed.
  39
  40 (* Destructions with pr_isi *************************************************)
  41
  42 (*** after_isid_inv_sn *)
  43 lemma pr_after_isi_inv_sn:
  44       ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❨f1❩ → f2 ≡ f.
  45 /3 width=6 by pr_after_isi_sn, pr_after_mono/ qed-.
  46
  47 (*** after_isid_inv_dx *)
  48 lemma pr_after_isi_inv_dx:
  49       ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❨f2❩ → f1 ≡ f.
  50 /3 width=6 by pr_after_isi_dx, pr_after_mono/ qed-.
  51
  52 (*** after_fwd_isid1 *)
  53 corec lemma pr_after_des_isi_sn:
  54             ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❨f❩ → 𝐈❨f1❩.
  55 #f1 #f2 #f * -f1 -f2 -f
  56 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
  57 [ /4 width=6 by pr_isi_inv_push, pr_isi_push/ ]
  58 cases (pr_isi_inv_next … H … H0)
  59 qed-.
  60
  61 (*** after_fwd_isid2 *)
  62 corec lemma pr_after_des_isi_dx:
  63             ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❨f❩ → 𝐈❨f2❩.
  64 #f1 #f2 #f * -f1 -f2 -f
  65 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
  66 [ /4 width=6 by pr_isi_inv_push, pr_isi_push/ ]
  67 cases (pr_isi_inv_next … H … H0)
  68 qed-.
  69
  70 (*** after_inv_isid3 *)
  71 lemma pr_after_inv_isi:
  72       ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❨f❩ → 𝐈❨f1❩ ∧ 𝐈❨f2❩.
  73 /3 width=4 by pr_after_des_isi_dx, pr_after_des_isi_sn, conj/ qed-.